[CRD iOS] Define template for the CRD iOS target

remoting/ios/app/remoting_ios_tmpl.gni

+# Copyright 2017 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/chrome_build.gni")
+import("//build/config/ios/rules.gni")
+import("//build/mac/tweak_info_plist.gni")
+import("//build/util/process_version.gni")
+import("//remoting/build/config/remoting_build.gni")
+
+remoting_ios_app_source_dir = get_path_info("./", "abspath")
+
+template("ios_remoting_source_set") {
+  source_set(target_name) {
+    _sources = [
+      "app_delegate.h",
+      "app_delegate.mm",
+      "client_connection_view_controller.h",
+      "client_connection_view_controller.mm",
+      "host_collection_header_view.h",
+      "host_collection_header_view.mm",
+      "host_collection_view_cell.h",
+      "host_collection_view_cell.mm",
+      "host_collection_view_controller.h",
+      "host_collection_view_controller.mm",
+      "host_view_controller.h",
+      "host_view_controller.mm",
+      "main.mm",
+      "pin_entry_view.h",
+      "pin_entry_view.mm",
+      "remoting_settings_view_controller.h",
+      "remoting_settings_view_controller.mm",
+      "remoting_theme.h",
+      "remoting_theme.mm",
+      "remoting_view_controller.h",
+      "remoting_view_controller.mm",
+    ]
+    sources = rebase_path(_sources, ".", remoting_ios_app_source_dir)
+
+    if (defined(invoker.sources)) {
+      sources += invoker.sources
+    }
+
+    deps = [
+      "//base",
+      "//google_apis",
+      "//remoting/base",
+      "//remoting/client",
+      "//remoting/client/input",
+      "//remoting/ios:ios_core",
+      "//remoting/protocol",
+      "//ui/base",
+      "//ui/gfx",
+      "//ui/resources",
+    ]
+
+    if (defined(invoker.deps)) {
+      deps += invoker.deps
+    }
+
+    public_deps = [
+      "//ios/third_party/material_components_ios",
+    ]
+
+    configs += [ "//build/config/compiler:enable_arc" ]
+  }
+}
+
+template("ios_remoting_app_tmpl") {
+  info_plist_target_name = "${target_name}_tweak_info_plist"
+  tweak_info_plist(info_plist_target_name) {
+    info_plist = "//remoting/ios/app/resources/Info.plist"
+    args = [ "--platform=ios" ]
+  }
+
+  launchscreen_storyboard_target_name = "${target_name}_launchscreen_storyboard"
+  bundle_data_ib_file(launchscreen_storyboard_target_name) {
+    # TODO(yuweih): Need different launch screen for official build?

[nicholss, 2017/06/09 21:36:54]

The launch screens stays the same and the images included in the build should
change.

[Yuwei, 2017/06/09 21:53:19]

Okay... Removed it for now.

+    source = rebase_path("resources/LaunchScreen.storyboard",
+                         ".",
+                         remoting_ios_app_source_dir)
+  }
+
+  ios_app_bundle(target_name) {
+    output_name = invoker.output_name
+
+    entitlements_path = invoker.entitlements_path
+    info_plist_target = ":$info_plist_target_name"
+
+    extra_substitutions = [
+      "BUNDLE_IDENTIFIER=$remoting_ios_bundle_id",
+      "DISPLAY_NAME=$remoting_ios_display_name",
+      "EXECUTABLE_NAME=$remoting_ios_executable_name",
+      "MINIMUM_OS_VERSION=7.0",
+      "PRODUCT_NAME=$remoting_ios_product_name",
+      "VERSION_FULL=$remoting_version_full",
+      "VERSION_SHORT=$remoting_version_short",
+    ]
+
+    libs = [
+      "Accelerate.framework",
+      "AudioToolbox.framework",
+      "CoreAudio.framework",
+      "CoreData.framework",
+      "CoreMIDI.framework",
+      "CoreVideo.framework",
+      "GLKit.framework",
+      "OpenGLES.framework",
+      "Webkit.framework",
+      "SafariServices.framework",
+      "SystemConfiguration.framework",
+    ]
+
+    deps = [
+      "//base",
+      "//remoting/ios/app/resources:assets",
+      "//remoting/ios/app/resources:launchscreen_assets",
+      "//remoting/ios/app/resources:remoting_icons",
+      "//remoting/ios/display",
+    ]
+
+    deps += [ invoker.remoting_source_set ]
+
+    bundle_deps = [ ":$launchscreen_storyboard_target_name" ]
+  }
+}