[ObjC ARC] Converts ios/web:ios_web_web_state_ui_unittests to ARC.

ios/web/web_state/ui/crw_web_controller_unittest.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/web/web_state/ui/crw_web_controller.h"
 
 #import <WebKit/WebKit.h>
 
 #include <utility>
 
 #include "base/ios/ios_util.h"
-#import "base/ios/weak_nsobject.h"
-#import "base/mac/scoped_nsobject.h"
+#include "base/mac/foundation_util.h"
 #include "base/strings/utf_string_conversions.h"
 #import "base/test/ios/wait_util.h"
 #import "ios/testing/ocmock_complex_type_helper.h"
 #import "ios/web/navigation/crw_session_controller.h"
 #import "ios/web/navigation/navigation_item_impl.h"
 #import "ios/web/navigation/navigation_manager_impl.h"
 #include "ios/web/public/referrer.h"
 #import "ios/web/public/test/fakes/test_native_content.h"
 #import "ios/web/public/test/fakes/test_native_content_provider.h"
 #import "ios/web/public/test/fakes/test_web_client.h"
@@ skipping 18 matching lines @@
 #include "net/ssl/ssl_info.h"
 #include "net/test/cert_test_util.h"
 #include "net/test/test_data_directory.h"
 #include "testing/gtest/include/gtest/gtest.h"
 #import "testing/gtest_mac.h"
 #include "third_party/ocmock/OCMock/OCMock.h"
 #include "third_party/ocmock/gtest_support.h"
 #include "third_party/ocmock/ocmock_extensions.h"
 #import "ui/base/test/ios/ui_view_test_utils.h"
 
+#if !defined(__has_feature) || !__has_feature(objc_arc)
+#error "This file requires ARC support."
+#endif
+
 using web::NavigationManagerImpl;
 
 @interface CRWWebController (PrivateAPI)
 @property(nonatomic, readwrite) web::PageDisplayState pageDisplayState;
 @end
 
 @interface CountingObserver : NSObject<CRWWebControllerObserver>
 
 @property(nonatomic, readonly) int pageLoadedCount;
 @end
@@ skipping 50 matching lines @@
   base::test::ios::WaitUntilCondition(^bool() {
     return webController.pageDisplayState.zoom_state() == zoom_state;
   });
 }
 
 // Test fixture for testing CRWWebController. Stubs out web view.
 class CRWWebControllerTest : public web::WebTestWithWebController {
  protected:
   void SetUp() override {
     web::WebTestWithWebController::SetUp();
-    mock_web_view_.reset([CreateMockWebView() retain]);
-    scroll_view_.reset([[UIScrollView alloc] init]);
-    [[[mock_web_view_ stub] andReturn:scroll_view_.get()] scrollView];
+    mock_web_view_ = CreateMockWebView();
+    scroll_view_ = [[UIScrollView alloc] init];
+    [[[mock_web_view_ stub] andReturn:scroll_view_] scrollView];
 
-    base::scoped_nsobject<TestWebViewContentView> webViewContentView(
+    TestWebViewContentView* web_view_content_view =
         [[TestWebViewContentView alloc] initWithMockWebView:mock_web_view_
-                                                 scrollView:scroll_view_]);
-    [web_controller() injectWebViewContentView:webViewContentView];
+                                                 scrollView:scroll_view_];
+    [web_controller() injectWebViewContentView:web_view_content_view];
   }
 
   void TearDown() override {
     EXPECT_OCMOCK_VERIFY(mock_web_view_);
     [web_controller() resetInjectedWebViewContentView];
     web::WebTestWithWebController::TearDown();
   }
 
   // The value for web view OCMock objects to expect for |-setFrame:|.
   CGRect GetExpectedWebViewFrame() const {
     CGSize container_view_size = [UIScreen mainScreen].bounds.size;
     container_view_size.height -=
         CGRectGetHeight([UIApplication sharedApplication].statusBarFrame);
     return {CGPointZero, container_view_size};
   }
 
   // Creates WebView mock.
   UIView* CreateMockWebView() {
     id result = [OCMockObject mockForClass:[WKWebView class]];
 
     if (base::ios::IsRunningOnIOS10OrLater()) {
       [[result stub] serverTrust];
     } else {
       [[result stub] certificateChain];
     }
 
     [[result stub] backForwardList];
     [[[result stub] andReturn:[NSURL URLWithString:@(kTestURLString)]] URL];
     [[result stub] setNavigationDelegate:[OCMArg checkWithBlock:^(id delegate) {
-                     navigation_delegate_.reset(delegate);
+                     navigation_delegate_ = delegate;
                      return YES;
                    }]];
     [[result stub] setUIDelegate:OCMOCK_ANY];
     [[result stub] setFrame:GetExpectedWebViewFrame()];
     [[result stub] addObserver:web_controller()
                     forKeyPath:OCMOCK_ANY
                        options:0
                        context:nullptr];
     [[result stub] removeObserver:web_controller() forKeyPath:OCMOCK_ANY];
 
     return result;
   }
 
-  base::WeakNSProtocol<id<WKNavigationDelegate>> navigation_delegate_;
-  base::scoped_nsobject<UIScrollView> scroll_view_;
-  base::scoped_nsobject<id> mock_web_view_;
+  __weak id<WKNavigationDelegate> navigation_delegate_;
+  UIScrollView* scroll_view_;
+  id mock_web_view_;
 };
 
 // Tests that AllowCertificateError is called with correct arguments if
 // WKWebView fails to load a page with bad SSL cert.
 TEST_F(CRWWebControllerTest, SslCertError) {
   web::TestWebStateObserver observer(web_state());
   ASSERT_FALSE(observer.did_change_visible_security_state_info());
 
   // Last arguments passed to AllowCertificateError must be in default state.
   ASSERT_FALSE(GetWebClient()->last_cert_error_code());
   ASSERT_FALSE(GetWebClient()->last_cert_error_ssl_info().is_valid());
   ASSERT_FALSE(GetWebClient()->last_cert_error_ssl_info().cert_status);
   ASSERT_FALSE(GetWebClient()->last_cert_error_request_url().is_valid());
   ASSERT_TRUE(GetWebClient()->last_cert_error_overridable());
 
   scoped_refptr<net::X509Certificate> cert =
       net::ImportCertFromFile(net::GetTestCertsDirectory(), "ok_cert.pem");
   ASSERT_TRUE(cert);
   base::ScopedCFTypeRef<CFMutableArrayRef> chain(
       net::x509_util::CreateSecCertificateArrayForX509Certificate(cert.get()));
   ASSERT_TRUE(chain);
 
   GURL url("https://chromium.test");
   NSError* error =
       [NSError errorWithDomain:NSURLErrorDomain
                           code:NSURLErrorServerCertificateHasUnknownRoot
                       userInfo:@{
                         web::kNSErrorPeerCertificateChainKey :
-                            static_cast<NSArray*>(chain.get()),
+                            base::mac::CFToNSCast(chain.get()),
                         web::kNSErrorFailingURLKey : net::NSURLWithGURL(url),
                       }];
-  base::scoped_nsobject<NSObject> navigation([[NSObject alloc] init]);
+  NSObject* navigation = [[NSObject alloc] init];
   [navigation_delegate_ webView:mock_web_view_
       didStartProvisionalNavigation:static_cast<WKNavigation*>(navigation)];
   [navigation_delegate_ webView:mock_web_view_
       didFailProvisionalNavigation:static_cast<WKNavigation*>(navigation)
                          withError:error];
 
   // Verify correctness of AllowCertificateError method call.
   EXPECT_EQ(net::ERR_CERT_INVALID, GetWebClient()->last_cert_error_code());
   EXPECT_TRUE(GetWebClient()->last_cert_error_ssl_info().is_valid());
   EXPECT_EQ(net::CERT_STATUS_INVALID,
@@ skipping 424 matching lines @@
 
   EXPECT_EQ(GURL(kTestURLString), url);
   EXPECT_EQ(web::kAbsolute, trust_level);
 }
 
 // Test fixture for testing CRWWebController presenting native content.
 class CRWWebControllerNativeContentTest : public web::WebTestWithWebController {
  protected:
   void SetUp() override {
     web::WebTestWithWebController::SetUp();
-    mock_native_provider_.reset([[TestNativeContentProvider alloc] init]);
+    mock_native_provider_ = [[TestNativeContentProvider alloc] init];
     [web_controller() setNativeProvider:mock_native_provider_];
   }
 
   void Load(const GURL& URL) {
     NavigationManagerImpl& navigation_manager =
         [web_controller() webStateImpl]->GetNavigationManagerImpl();
     navigation_manager.AddPendingItem(
         URL, web::Referrer(), ui::PAGE_TRANSITION_TYPED,
         web::NavigationInitiationType::USER_INITIATED,
         web::NavigationManager::UserAgentOverrideOption::INHERIT);
     [web_controller() loadCurrentURL];
   }
 
-  base::scoped_nsobject<TestNativeContentProvider> mock_native_provider_;
+  TestNativeContentProvider* mock_native_provider_;
 };
 
 // Tests WebState and NavigationManager correctly return native content URL.
 TEST_F(CRWWebControllerNativeContentTest, NativeContentURL) {
   GURL url_to_load(kTestAppSpecificURL);
-  base::scoped_nsobject<TestNativeContent> content(
-      [[TestNativeContent alloc] initWithURL:url_to_load virtualURL:GURL()]);
+  TestNativeContent* content =
+      [[TestNativeContent alloc] initWithURL:url_to_load virtualURL:GURL()];
   [mock_native_provider_ setController:content forURL:url_to_load];
   Load(url_to_load);
   web::URLVerificationTrustLevel trust_level = web::kNone;
   GURL gurl = [web_controller() currentURLWithTrustLevel:&trust_level];
   EXPECT_EQ(gurl, url_to_load);
   EXPECT_EQ(web::kAbsolute, trust_level);
   EXPECT_EQ([web_controller() webState]->GetVisibleURL(), url_to_load);
   NavigationManagerImpl& navigationManager =
       [web_controller() webStateImpl]->GetNavigationManagerImpl();
   EXPECT_EQ(navigationManager.GetVisibleItem()->GetURL(), url_to_load);
   EXPECT_EQ(navigationManager.GetVisibleItem()->GetVirtualURL(), url_to_load);
   EXPECT_EQ(navigationManager.GetLastCommittedItem()->GetURL(), url_to_load);
   EXPECT_EQ(navigationManager.GetLastCommittedItem()->GetVirtualURL(),
             url_to_load);
 }
 
 // Tests WebState and NavigationManager correctly return native content URL and
 // VirtualURL
 TEST_F(CRWWebControllerNativeContentTest, NativeContentVirtualURL) {
   GURL url_to_load(kTestAppSpecificURL);
   GURL virtual_url(kTestURLString);
-  base::scoped_nsobject<TestNativeContent> content([[TestNativeContent alloc]
-      initWithURL:virtual_url
-       virtualURL:virtual_url]);
+  TestNativeContent* content =
+      [[TestNativeContent alloc] initWithURL:virtual_url
+                                  virtualURL:virtual_url];
   [mock_native_provider_ setController:content forURL:url_to_load];
   Load(url_to_load);
   web::URLVerificationTrustLevel trust_level = web::kNone;
   GURL gurl = [web_controller() currentURLWithTrustLevel:&trust_level];
   EXPECT_EQ(gurl, virtual_url);
   EXPECT_EQ(web::kAbsolute, trust_level);
   EXPECT_EQ([web_controller() webState]->GetVisibleURL(), virtual_url);
   NavigationManagerImpl& navigationManager =
       [web_controller() webStateImpl]->GetNavigationManagerImpl();
   EXPECT_EQ(navigationManager.GetVisibleItem()->GetURL(), url_to_load);
   EXPECT_EQ(navigationManager.GetVisibleItem()->GetVirtualURL(), virtual_url);
   EXPECT_EQ(navigationManager.GetLastCommittedItem()->GetURL(), url_to_load);
   EXPECT_EQ(navigationManager.GetLastCommittedItem()->GetVirtualURL(),
             virtual_url);
 }
 
 // A separate test class, as none of the |CRWUIWebViewWebControllerTest| setup
 // is needed;
 typedef web::WebTestWithWebController CRWWebControllerObserversTest;
 
 // Tests that CRWWebControllerObservers are called.
 TEST_F(CRWWebControllerObserversTest, Observers) {
-  base::scoped_nsobject<CountingObserver> observer(
-      [[CountingObserver alloc] init]);
+  CountingObserver* observer = [[CountingObserver alloc] init];
   EXPECT_EQ(0u, [web_controller() observerCount]);
   [web_controller() addObserver:observer];
   EXPECT_EQ(1u, [web_controller() observerCount]);
 
   EXPECT_EQ(0, [observer pageLoadedCount]);
   [web_controller() webStateImpl]->OnPageLoaded(GURL("http://test"), false);
   EXPECT_EQ(0, [observer pageLoadedCount]);
   [web_controller() webStateImpl]->OnPageLoaded(GURL("http://test"), true);
   EXPECT_EQ(1, [observer pageLoadedCount]);
 
@@ skipping 137 matching lines @@
  protected:
   // Calls |executeUserJavaScript:completionHandler:|, waits for script
   // execution completion, and synchronously returns the result.
   id ExecuteUserJavaScript(NSString* java_script, NSError** error) {
     __block id script_result = nil;
     __block NSError* script_error = nil;
     __block bool script_executed = false;
     [web_controller()
         executeUserJavaScript:java_script
             completionHandler:^(id local_result, NSError* local_error) {
-              script_result = [local_result retain];
-              script_error = [local_error retain];
+              script_result = local_result;
+              script_error = local_error;
               script_executed = true;
             }];
 
     WaitForCondition(^{
       return script_executed;
     });
 
     if (error) {
       *error = script_error;
     }
-    [script_error autorelease];
-    return [script_result autorelease];
+    return script_result;
   }
 };
 
 // Tests evaluating user script on an http page.
 TEST_F(ScriptExecutionTest, UserScriptOnHttpPage) {
   LoadHtml(@"<html></html>", GURL(kTestURLString));
   NSError* error = nil;
   EXPECT_NSEQ(@0, ExecuteUserJavaScript(@"window.w = 0;", &error));
   EXPECT_FALSE(error);
 
@@ skipping 22 matching lines @@
   EXPECT_EQ(web::JS_EVALUATION_ERROR_CODE_NO_WEB_VIEW, error.code);
 
   EXPECT_FALSE(ExecuteJavaScript(@"window.w"));
 };
 
 // Fixture class to test WKWebView crashes.
 class CRWWebControllerWebProcessTest : public web::WebTestWithWebController {
  protected:
   void SetUp() override {
     web::WebTestWithWebController::SetUp();
-    webView_.reset([web::BuildTerminatedWKWebView() retain]);
-    base::scoped_nsobject<TestWebViewContentView> webViewContentView(
-        [[TestWebViewContentView alloc]
-            initWithMockWebView:webView_
-                     scrollView:[webView_ scrollView]]);
+    webView_ = web::BuildTerminatedWKWebView();
+    TestWebViewContentView* webViewContentView = [[TestWebViewContentView alloc]
+        initWithMockWebView:webView_
+                 scrollView:[webView_ scrollView]];
     [web_controller() injectWebViewContentView:webViewContentView];
 
     // This test intentionally crashes the render process.
     SetIgnoreRenderProcessCrashesDuringTesting(true);
   }
-  base::scoped_nsobject<WKWebView> webView_;
+  WKWebView* webView_;
 };
 
 // Tests that WebStateDelegate::RenderProcessGone is called when WKWebView web
 // process has crashed.
 TEST_F(CRWWebControllerWebProcessTest, Crash) {
   web::TestWebStateObserver observer(web_state());
   web::TestWebStateObserver* observer_ptr = &observer;
   web::SimulateWKWebViewCrash(webView_);
   base::test::ios::WaitUntilCondition(^bool() {
     return observer_ptr->render_process_gone_info();
   });
   EXPECT_EQ(web_state(), observer.render_process_gone_info()->web_state);
   EXPECT_FALSE([web_controller() isViewAlive]);
 };
 
 }  // namespace