(re-land) Move ui/gfx/codec/ into its own component.

ui/gfx/codec/BUILD.gn

Index: ui/gfx/codec/BUILD.gn
diff --git a/ui/gfx/codec/BUILD.gn b/ui/gfx/codec/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..6cdc8a7c0fef326d35e077cfea78063ea94605f7
--- /dev/null
+++ b/ui/gfx/codec/BUILD.gn
@@ -0,0 +1,51 @@
+# Copyright 2017 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//build/config/ui.gni")
+
+component("codec") {
+  sources = [
+    "codec_export.h",
+    "jpeg_codec.cc",
+    "jpeg_codec.h",
+    "png_codec.cc",
+    "png_codec.h",
+    "skia_image_encoder_adapter.cc",
+    "skia_image_encoder_adapter.h",
+  ]
+
+  deps = [
+    "//base",
+    "//skia",
+    "//third_party/libpng",
+    "//ui/gfx:geometry_skia",
+    "//ui/gfx:gfx_export",
+    "//ui/gfx/geometry",
+  ]
+
+  if (is_ios) {
+    sources -= [
+      "jpeg_codec.cc",
+      "jpeg_codec.h",
+    ]
+  } else {
+    deps += [ "//third_party:jpeg" ]
+  }
+
+  if (is_chromeos) {
+    # Robust JPEG decoding for the login screen.
+    sources += [
+      "chromeos/jpeg_codec_robust_slow.cc",
+      "chromeos/jpeg_codec_robust_slow.h",
+    ]
+    deps += [ "//third_party/libjpeg" ]
+  }
+
+  if (is_win) {
+    cflags = [ "/wd4324" ]  # Structure was padded due to __declspec(align()),
+                            # which is uninteresting.
+  }
+
+  defines = [ "CODEC_IMPLEMENTATION" ]
+}