MacViews: Implement Force Touch/Mac dictionary lookup for Textfields.

ui/views/cocoa/bridged_content_view.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/views/cocoa/bridged_content_view.h"
 
 #include "base/logging.h"
 #import "base/mac/mac_util.h"
 #import "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "skia/ext/skia_utils_mac.h"
 #include "ui/base/cocoa/cocoa_base_utils.h"
 #include "ui/base/dragdrop/drag_drop_types.h"
 #include "ui/base/dragdrop/os_exchange_data_provider_mac.h"
 #include "ui/base/ime/input_method.h"
 #include "ui/base/ime/text_edit_commands.h"
 #include "ui/base/ime/text_input_client.h"
 #include "ui/compositor/canvas_painter.h"
 #import "ui/events/cocoa/cocoa_event_utils.h"
+#include "ui/events/event_utils.h"
 #include "ui/events/keycodes/dom/dom_code.h"
 #import "ui/events/keycodes/keyboard_code_conversion_mac.h"
 #include "ui/gfx/canvas_paint_mac.h"
+#include "ui/gfx/decorated_text.h"
 #include "ui/gfx/geometry/rect.h"
 #import "ui/gfx/mac/coordinate_conversion.h"
 #include "ui/gfx/path.h"
 #import "ui/gfx/path_mac.h"
+#include "ui/gfx/render_text.h"
 #include "ui/gfx/scoped_ns_graphics_context_save_gstate_mac.h"
 #import "ui/views/cocoa/bridged_native_widget.h"
 #import "ui/views/cocoa/drag_drop_client_mac.h"
 #include "ui/views/controls/menu/menu_config.h"
 #include "ui/views/controls/menu/menu_controller.h"
 #include "ui/views/view.h"
 #include "ui/views/widget/native_widget_mac.h"
 #include "ui/views/widget/widget.h"
 
 using views::MenuController;
@@ skipping 163 matching lines @@
   DCHECK([event type] == NSKeyDown || [event type] == NSKeyUp);
   DCHECK_EQ(1u, [[event characters] length]);
 
   // [NSEvent characters] already considers the pressed key modifiers. Hence
   // send ui::EF_NONE as the key modifier to the KeyEvent constructor.
   // E.g. For Alt+S, [NSEvent characters] is 'ß' and not 'S'.
   return ui::KeyEvent([[event characters] characterAtIndex:0],
                       ui::KeyboardCodeFromNSEvent(event), ui::EF_NONE);
 }
 
+NSAttributedString* GetAttributedString(
+    const gfx::DecoratedText& decorated_text) {
+  NSMutableAttributedString* str = [[NSMutableAttributedString alloc] init];
+  NSMutableDictionary* attrs = [NSMutableDictionary dictionary];
+  [str beginEditing];
+  [[str mutableString] setString:base::SysUTF16ToNSString(decorated_text.text)];
+
+  for (const auto& attribute : decorated_text.attributes) {
+    DCHECK(!attribute.range.is_reversed());
+    DCHECK(attribute.range.end() <= [str length]);
+
+    NSRange range = attribute.range.ToNSRange();
+
+    if (attribute.font.GetNativeFont()) {
+      [attrs setObject:attribute.font.GetNativeFont()
+                forKey:NSFontAttributeName];
+    } else {
+      [attrs removeObjectForKey:NSFontAttributeName];
+    }
+
+    if (attribute.underline) {

[karandeepb, 2016/09/22 08:17:40]

FYI: Cocoa seems to ignore the underline and strike attributes while showing the
popup. But I think we should still keep it to make the function generic.

+      [attrs setObject:@(NSUnderlineStyleSingle | NSUnderlinePatternSolid)
+                forKey:NSUnderlineStyleAttributeName];
+    } else {
+      [attrs removeObjectForKey:NSUnderlineStyleAttributeName];
+    }
+
+    if (attribute.strike) {
+      [attrs setObject:@(NSUnderlineStyleSingle | NSUnderlinePatternSolid)
+                forKey:NSStrikethroughStyleAttributeName];
+    } else {
+      [attrs removeObjectForKey:NSStrikethroughStyleAttributeName];
+    }
+
+    [str setAttributes:attrs range:range];
+
+    NSFontTraitMask mask = 0;
+    if (attribute.weight >= gfx::Font::Weight::BOLD)
+      mask |= NSBoldFontMask;
+    if (attribute.italic)
+      mask |= NSItalicFontMask;
+
+    if (mask)
+      [str applyFontTraits:mask range:range];
+  }
+
+  [str endEditing];
+  return [str autorelease];
+}
+
 }  // namespace
 
 @interface BridgedContentView ()
 
 // Returns the active menu controller corresponding to |hostedView_|,
 // nil otherwise.
 - (MenuController*)activeMenuController;
 
 // Passes |event| to the InputMethod for dispatch.
 - (void)handleKeyEvent:(ui::KeyEvent*)event;
@@ skipping 513 matching lines @@
 }
 
 - (void)scrollWheel:(NSEvent*)theEvent {
   if (!hostedView_)
     return;
 
   ui::MouseWheelEvent event(theEvent);
   hostedView_->GetWidget()->OnMouseEvent(&event);
 }
 
+- (void)quickLookWithEvent:(NSEvent*)theEvent {
+  if (!hostedView_)
+    return;
+
+  const gfx::Point locationInContent = ui::EventLocationFromNative(theEvent);
+  views::View* target = hostedView_->GetEventHandlerForPoint(locationInContent);
+  if (!target)
+    return;
+
+  gfx::RenderText* renderText = target->GetRenderText();
+  if (!renderText)
+    return;
+
+  gfx::Point locationInTarget = locationInContent;
+  views::View::ConvertPointToTarget(hostedView_, target, &locationInTarget);

[karandeepb, 2016/09/22 08:17:39]

Saw https://codereview.chromium.org/2148893003. So basically
hostedView_->GetTooltipHandlerForPoint can return a view not in the hierarchy of
the hostedView_.  If this is the case, I think the documentation of
View::GetTooltipHandlerForPoint should be updated since it seems to suggest that
a descendent will be returned. Can this also happen for GetEventHandlerForPoint
or is the ConvertPointToTarget call here safe?

+  gfx::DecoratedText decorated_word;
+  gfx::Point baselinePoint;
+  if (!renderText->GetDecoratedWordAtPoint(locationInTarget, &decorated_word,
+                                           &baselinePoint)) {
+    return;
+  }
+
+  // Convert |baselinePoint| to the coordinate system of |hostedView_|.
+  views::View::ConvertPointToTarget(target, hostedView_, &baselinePoint);
+  NSPoint baselinePointAppKit = NSMakePoint(
+      baselinePoint.x(), NSHeight([self frame]) - baselinePoint.y());
+  [self showDefinitionForAttributedString:GetAttributedString(decorated_word)
+                                  atPoint:baselinePointAppKit];
+}
+
 ////////////////////////////////////////////////////////////////////////////////
 // NSResponder Action Messages. Keep sorted according NSResponder.h (from the
 // 10.9 SDK). The list should eventually be complete. Anything not defined will
 // beep when interpretKeyEvents: would otherwise call it.
 // TODO(tapted): Make this list complete, except for insert* methods which are
 // dispatched as regular key events in doCommandBySelector:.
 
 // views::Textfields are single-line only, map Paragraph and Document commands
 // to Line. Also, Up/Down commands correspond to beginning/end of line.
 
@@ skipping 603 matching lines @@
   }
 
   return [super accessibilityAttributeValue:attribute];
 }
 
 - (id)accessibilityHitTest:(NSPoint)point {
   return [hostedView_->GetNativeViewAccessible() accessibilityHitTest:point];
 }
 
 @end