Enable Update Password UI on iOS behind a flag

ios/chrome/browser/passwords/password_controller.mm

 // Copyright 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ios/chrome/browser/passwords/password_controller.h"
 
 #include <stddef.h>
 
 #include <algorithm>
 #include <memory>
@@ skipping 16 matching lines @@
 #include "components/password_manager/core/browser/password_bubble_experiment.h"
 #include "components/password_manager/core/browser/password_generation_manager.h"
 #include "components/password_manager/core/browser/password_manager.h"
 #include "components/password_manager/core/browser/password_manager_client.h"
 #include "components/password_manager/core/browser/password_manager_driver.h"
 #include "components/sync_driver/sync_service.h"
 #include "ios/chrome/browser/browser_state/chrome_browser_state.h"
 #include "ios/chrome/browser/experimental_flags.h"
 #include "ios/chrome/browser/infobars/infobar_manager_impl.h"
 #import "ios/chrome/browser/passwords/ios_chrome_save_password_infobar_delegate.h"
+#import "ios/chrome/browser/passwords/ios_chrome_update_password_infobar_delegate.h"

[sdefresne, 2016/07/05 13:29:55]

I don't see this file in this CL nor in the repository nor in any of the
dependent CL. Missing file?

[Jackie Quinn, 2016/07/05 13:52:35]

It just landed earlier today: https://codereview.chromium.org/2108643002

 #import "ios/chrome/browser/passwords/js_password_manager.h"
 #import "ios/chrome/browser/passwords/password_generation_agent.h"
 #include "ios/chrome/browser/sync/ios_chrome_profile_sync_service_factory.h"
 #include "ios/web/public/url_scheme_util.h"
 #import "ios/web/public/web_state/js/crw_js_injection_receiver.h"
 #import "ios/web/public/web_state/web_state.h"
 #include "url/gurl.h"
 
+namespace {

[sdefresne, 2016/07/05 13:29:55]

Please move this after the "using" statements, and separated with a new line.

[Jackie Quinn, 2016/07/05 13:52:35]

Done.

+// Types of password infobars to display.
+typedef NS_ENUM(BOOL, PasswordInfoBarType) { SAVE, UPDATE };

[sdefresne, 2016/07/05 13:29:55]

Since this is internal only and in an anonymous namespace, I would prefer to use
a C++ enum here.

In addition, the enum value should be namespaced (as they are in the global
namespace) but naming them PASSWORD_INFO_BAR_{SAVE,UPDATE}. An alternative is to
use "enum class".

namespace {
// Types of password infobars to display.
enum class PasswordInfoBarType {
  SAVE,
  UPDATE,
};
}

Then you use it as "PasswordInfoBarType::SAVE" or "PasswordInfoBarType::UPDATE".

[Jackie Quinn, 2016/07/05 13:52:34]

Done.

+}
 using password_manager::PasswordFormManager;
 using password_manager::PasswordGenerationManager;
 using password_manager::PasswordManager;
 using password_manager::PasswordManagerClient;
 using password_manager::PasswordManagerDriver;
 
 @interface PasswordController ()
 
 // This is set to YES as soon as the associated WebState is destroyed.
 @property(readonly) BOOL isWebStateDestroyed;
@@ skipping 44 matching lines @@
                                  const autofill::PasswordForm& form))
                            completionHandler;
 
 // Takes values from a JSON |dictionary| and populates the |form|.
 // The |pageLocation| is the URL of the current page.
 // Returns YES if the form was correctly populated, NO otherwise.
 - (BOOL)getPasswordForm:(autofill::PasswordForm*)form
          fromDictionary:(const base::DictionaryValue*)dictionary
                 pageURL:(const GURL&)pageLocation;
 
+// Displays infobar for |form| with |type|. If |type| is UPDATE, the user
+// is prompted to update the password. If |type| is SAVE, the user is prompted
+// to save the password.
+- (void)showInfoBarForForm:(std::unique_ptr<PasswordFormManager>)form
+               infoBarType:(PasswordInfoBarType)type;
+
 @end
 
 namespace {
 
 // Constructs an array of FormSuggestions, each corresponding to a username/
 // password pair in |formFillData|, such that |prefix| is a prefix of the
 // username of each suggestion.
 NSArray* BuildSuggestions(const autofill::PasswordFormFillData& formFillData,
                           NSString* prefix) {
   NSMutableArray* suggestions = [NSMutableArray array];
@@ skipping 490 matching lines @@
               withUsername:username
                   password:password
          completionHandler:^(BOOL success) {
            completion();
          }];
   } else {
     completion();
   }
 }
 
+#pragma mark - PasswordManagerClientDelegate
+
+- (void)showSavePasswordInfoBar:
+    (std::unique_ptr<PasswordFormManager>)formToSave {
+  [self showInfoBarForForm:std::move(formToSave) infoBarType:SAVE];
+}
+
+- (void)showUpdatePasswordInfoBar:
+    (std::unique_ptr<PasswordFormManager>)formToUpdate {
+  [self showInfoBarForForm:std::move(formToUpdate) infoBarType:UPDATE];
+}
+
 #pragma mark -
 #pragma mark WebPasswordFormData Adaptation
 
 - (BOOL)getPasswordForm:(autofill::PasswordForm*)form
          fromDictionary:(const base::DictionaryValue*)dictionary
                 pageURL:(const GURL&)pageLocation {
   DCHECK(form);
   DCHECK(dictionary);
   DCHECK(pageLocation.is_valid());
 
@@ skipping 118 matching lines @@
     }
     autofill::FormFieldData field;
     field.name = std::move(element);
     field.form_control_type = base::UTF16ToUTF8(type);
     form->form_data.fields.push_back(field);
   }
 
   return YES;
 }
 
-- (void)showSavePasswordInfoBar:
-    (std::unique_ptr<PasswordFormManager>)formToSave {
-  if (!webStateObserverBridge_ || !webStateObserverBridge_->web_state())
-    return;
-
-  bool isSmartLockBrandingEnabled = false;
-  if (self.browserState) {
-    sync_driver::SyncService* sync_service =
-        IOSChromeProfileSyncServiceFactory::GetForBrowserState(
-            self.browserState);
-    isSmartLockBrandingEnabled =
-        password_bubble_experiment::IsSmartLockBrandingSavePromptEnabled(
-            sync_service);
-  }
-  infobars::InfoBarManager* infoBarManager =
-      InfoBarManagerImpl::FromWebState(webStateObserverBridge_->web_state());
-  IOSChromeSavePasswordInfoBarDelegate::Create(
-      isSmartLockBrandingEnabled, infoBarManager, std::move(formToSave));
-}
-
 - (void)fillPasswordForm:(const autofill::PasswordFormFillData&)formData
             withUsername:(const base::string16&)username
                 password:(const base::string16&)password
        completionHandler:(void (^)(BOOL))completionHandler {
   // Send JSON over to the web view.
   [passwordJsManager_ fillPasswordForm:SerializePasswordFormFillData(formData)
                           withUsername:base::SysUTF16ToNSString(username)
                               password:base::SysUTF16ToNSString(password)
                      completionHandler:^(BOOL result) {
                        if (completionHandler)
@@ skipping 35 matching lines @@
 }
 
 - (PasswordManager*)passwordManager {
   return passwordManager_.get();
 }
 
 - (JsPasswordManager*)passwordJsManager {
   return passwordJsManager_;
 }
 
+#pragma mark - Private methods
+
+- (void)showInfoBarForForm:(std::unique_ptr<PasswordFormManager>)form
+               infoBarType:(PasswordInfoBarType)type {
+  if (!webStateObserverBridge_ || !webStateObserverBridge_->web_state())
+    return;
+
+  bool isSmartLockBrandingEnabled = false;
+  if (self.browserState) {
+    sync_driver::SyncService* sync_service =
+        IOSChromeProfileSyncServiceFactory::GetForBrowserState(
+            self.browserState);
+    isSmartLockBrandingEnabled =
+        password_bubble_experiment::IsSmartLockBrandingSavePromptEnabled(
+            sync_service);
+  }
+  infobars::InfoBarManager* infoBarManager =
+      InfoBarManagerImpl::FromWebState(webStateObserverBridge_->web_state());
+
+  switch (type) {
+    case SAVE:
+      IOSChromeSavePasswordInfoBarDelegate::Create(
+          isSmartLockBrandingEnabled, infoBarManager, std::move(form));
+      break;
+
+    case UPDATE:
+      IOSChromeUpdatePasswordInfoBarDelegate::Create(
+          isSmartLockBrandingEnabled, infoBarManager, std::move(form));
+      break;
+
+    default:

[sdefresne, 2016/07/05 13:29:55]

If you use C++ enum or enum class, then you should be able to remove this
default case and the compiler will error if you forget to deal with same values.

[Jackie Quinn, 2016/07/05 13:52:34]

Done.

+      NOTREACHED();
+      break;
+  }
+}
+
 @end