gn: Add chromium_builder_asan target.

BUILD.gn

Index: BUILD.gn
diff --git a/BUILD.gn b/BUILD.gn
index 1d9c449e0b04fc563546df703b5b474977b2f8ee..63c488d3ef9a403a356941e9fa703d4753bfba42 100644
--- a/BUILD.gn
+++ b/BUILD.gn
@@ -14,6 +14,7 @@ import("//build/config/ui.gni")
 import("//build_overrides/v8.gni")
 import("//media/media_options.gni")
 import("//third_party/openh264/openh264_args.gni")
+import("//tools/ipc_fuzzer/ipc_fuzzer.gni")
 
 if (is_android) {
   import("//build/config/android/config.gni")
@@ -901,6 +902,45 @@ group("chromium_builder_perf") {
   }
 }
 
+if (!is_ios && !is_android && !is_chromecast) {
+  group("chromium_builder_asan") {
+    deps = [
+      "//chrome:chrome",
+      "//content/shell:content_shell",
+      "//v8:d8",
+    ]
+    if (!is_win) {
+      deps += [
+        "//net:dns_fuzz_stub",
+        "//net:hpack_fuzz_wrapper",
+        "//skia:filter_fuzz_stub",
+      ]
+    }
+    if (enable_ipc_fuzzer && !is_component_build) {
+      deps += [ "//tools/ipc_fuzzer:ipc_fuzzer_all" ]
+    }
+    if (!is_chromeos && current_toolchain == host_toolchain) {

[Dirk Pranke, 2016/06/10 17:47:09]

When you just run `ninja chromium_builder_asan`, that is saying that you want to
build the group target using the default_toolchain (which is the target
toolchain). We don't magically merge all of the different versions of the target
in different toolchains and build all of them.

So, the way to say that you want a dependency to be built using the host
toolchain is:

if (!is_chromeos) {
  deps += [
    "//third_party/pdfium/samples:pdfium_test($host_toolchain)",
    "//v8:v8_shell($host_toolchain)",
  ]
}

[Nico, 2016/06/10 17:50:45]

Ah, thanks, done. (gn_all has the pattern I added here; guess that target wants
something else.)

[Dirk Pranke, 2016/06/10 17:55:03]

You mean gn_only, right? Yeah, that usage is almost certainly wrong for the same
reason (and I suspect I reviewed that change and didn't catch it at the time).

+      deps += [
+        "//third_party/pdfium/samples:pdfium_test",
+        "//v8:v8_shell",
+      ]
+    }
+    if (is_clang) {
+      deps += [ "//build/sanitizers:copy_llvm_symbolizer" ]
+    }
+    if (is_win && symbol_level == 2 && target_cpu == "x86" && is_syzyasan) {
+      deps += [
+        "//chrome/tools/build/win/syzygy:chrome_dll_syzygy",
+        # TODO(GYP): Add this once it exists, https://crbug.com/619086
+        # "//content/shell:content_shell_syzyasan
+      ]
+      if (is_multi_dll_chrome) {
+        deps += [ "//chrome/tools/build/win/syzygy:chrome_child_dll_syzygy" ]
+      }
+    }
+  }
+}
+
 # For compatibility with GYP. The linux_chromium_chromeos_rel_ng and
 # linux_chromium_chromeos_compile_rel_ng bots reference this target as
 # something to build, but all targets for those bots to compile are set