Refactor content/common/gpu into gpu/ipc/service

gpu/ipc/service/BUILD.gn

+# Copyright 2016 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//testing/test.gni")
+import("//build/config/ui.gni")
+if (is_mac) {
+  import("//build/config/mac/mac_sdk.gni")
+}
+
+group("service") {
+  if (is_component_build) {
+    public_deps = [
+      "//gpu",
+    ]
+  } else {
+    public_deps = [
+      ":ipc_service_sources",
+    ]
+  }
+}
+
+source_set("ipc_service_sources") {
+  visibility = [ "//gpu/*" ]
+  sources = [
+    "gpu_channel.cc",
+    "gpu_channel.h",
+    "gpu_channel_manager.cc",
+    "gpu_channel_manager.h",
+    "gpu_channel_manager_delegate.h",
+    "gpu_command_buffer_stub.cc",
+    "gpu_command_buffer_stub.h",
+    "gpu_config.h",
+    "gpu_memory_buffer_factory.cc",
+    "gpu_memory_buffer_factory.h",
+    "gpu_memory_manager.cc",
+    "gpu_memory_manager.h",
+    "gpu_memory_tracking.cc",
+    "gpu_memory_tracking.h",
+    "gpu_watchdog.h",
+    "image_transport_surface.h",
+    "pass_through_image_transport_surface.cc",
+    "pass_through_image_transport_surface.h",
+  ]
+  configs += [ "//gpu:gpu_implementation" ]
+  public_deps = [
+    "//base",
+    "//gpu/command_buffer/common:common_sources",
+    "//gpu/command_buffer/service:service_sources",
+    "//gpu/ipc/common:ipc_common_sources",
+    "//ipc",
+    "//ui/events:events_base",
+    "//ui/gfx",
+    "//ui/gfx/geometry",
+    "//ui/gl",
+    "//url",
+  ]
+  deps = []
+  libs = []
+  if (is_win) {
+    sources += [
+      "child_window_surface_win.cc",
+      "child_window_surface_win.h",
+      "image_transport_surface_win.cc",
+    ]
+  }
+  if (is_mac) {
+    sources += [
+      "ca_layer_partial_damage_tree_mac.h",
+      "ca_layer_partial_damage_tree_mac.mm",
+      "ca_layer_tree_mac.h",
+      "ca_layer_tree_mac.mm",
+      "gpu_memory_buffer_factory_io_surface.cc",
+      "gpu_memory_buffer_factory_io_surface.h",
+      "image_transport_surface_mac.mm",
+      "image_transport_surface_overlay_mac.h",
+      "image_transport_surface_overlay_mac.mm",
+    ]
+    deps += [ "//ui/accelerated_widget_mac" ]
+    lib_dirs = [ "$mac_sdk_path/usr/lib" ]
+    libs += [ "AVFoundation.framework" ]
+  }
+  if (is_android) {
+    sources += [
+      "gpu_memory_buffer_factory_surface_texture.cc",
+      "gpu_memory_buffer_factory_surface_texture.h",
+      "image_transport_surface_android.cc",
+      "stream_texture_android.cc",
+      "stream_texture_android.h",
+    ]
+    libs += [ "android" ]
+  }
+  if (is_linux) {
+    sources += [ "image_transport_surface_linux.cc" ]
+  }
+  if (use_x11) {
+    sources += [ "x_util.h" ]
+  }
+  if (use_ozone) {
+    sources += [
+      "gpu_memory_buffer_factory_ozone_native_pixmap.cc",
+      "gpu_memory_buffer_factory_ozone_native_pixmap.h",
+    ]
+    deps += [ "//ui/ozone" ]
+  }
+}
+
+source_set("test_support") {
+  testonly = true
+  sources = [
+    "gpu_memory_buffer_factory_test_template.h",
+  ]
+  public_deps = [
+    ":ipc_service_sources",
+    "//testing/gtest:gtest",
+  ]
+}
+
+test("gpu_ipc_service_unittests") {
+  configs += [ "//build/config:precompiled_headers" ]
+  sources = [
+    "gpu_channel_manager_unittest.cc",
+    "gpu_channel_test_common.cc",
+    "gpu_channel_test_common.h",
+    "gpu_channel_unittest.cc",
+  ]
+  deps = [
+    ":ipc_service_sources",
+    ":test_support",
+    "//base",
+    "//base/test:run_all_unittests",
+    "//base/test:test_support",
+    "//ipc:test_support",
+    "//testing/gtest",
+  ]
+  libs = []
+  if (is_android) {
+    sources += [ "gpu_memory_buffer_factory_surface_texture_unittest.cc" ]
+  }
+  if (is_mac) {
+    sources += [
+      "ca_layer_tree_unittest_mac.mm",
+      "gpu_memory_buffer_factory_io_surface_unittest.cc",
+    ]
+    deps += [ "//ui/accelerated_widget_mac" ]
+    libs += [ "AVFoundation.framework" ]
+  }
+  if (use_ozone) {
+    sources += [ "gpu_memory_buffer_factory_ozone_native_pixmap_unittest.cc" ]
+    deps += [ "//ui/ozone" ]
+  }
+}