[iOS] Fix ios_web_shell to build with gn.

build/config/ios/rules.gni

Index: build/config/ios/rules.gni
diff --git a/build/config/ios/rules.gni b/build/config/ios/rules.gni
index 6aef64aa42b0fef1dce9eb0bf5dd87837be99f01..0b41d5d4145ecb2ca5ae808da501cb66effdebf0 100644
--- a/build/config/ios/rules.gni
+++ b/build/config/ios/rules.gni
@@ -186,3 +186,63 @@ template("app") {
   #   an alias to "ninja -C out/Default base_unittests" (for convenience
   #   and compatibility with gyp),
 }
+
+# Compile a xib or storyboard file and add it to a bundle_data so that it is
+# available at runtime in the bundle.
+#
+# Arguments
+#
+#   source:
+#       string, path of the xib or storyboard to compile.
+#
+# Forwards all variables to the bundle_data target.
+template("bundle_data_xib") {
+  assert(defined(invoker.source), "source needs to be defined for $target_name")
+
+  _source_extension = get_path_info(invoker.source, "extension")
+  assert(_source_extension == "xib" || _source_extension == "storyboard",
+         "source must be a .xib or .storyboard for $target_name")
+
+  _target_name = target_name

[Dirk Pranke, 2016/03/16 22:00:17]

why bother with _target_name here?

[sdefresne, 2016/03/17 17:53:14]

I want the following:

  ${target_name} -> ${target_name}_compile_xib

And limit the dependencies so that only ${target_name} can depends on
${target_name}_compile_xib. Since "target_name" is a "magic" variable in gn, I
have to make a copy, as it is overwritten by the name of the target when
resolving any target scope. The alternative is to not limit visibility, but I'm
a partisan of always using the most restricted visibility possible.

See tools/gn/functions.cc, in particular the function FillTargetBlockScope,
you'll see this at the bottom of the function:

  // Set the target name variable to the current target, and mark it used
  // because we don't want to issue an error if the script ignores it.
  const base::StringPiece target_name("target_name");
  block_scope->SetValue(target_name, Value(function, args[0].string_value()),
                        function);
  block_scope->MarkUsed(target_name);

This is the magic I was referring to.

[Dirk Pranke, 2016/03/18 02:19:59]

Ah, right. I forgot about this. Sorry!

+  _compile_xib = target_name + "_compile_xib"
+
+  _nib_basename = get_path_info(invoker.source, "name")
+  _nib_filename = "$_nib_basename.nib"
+
+  action(_compile_xib) {
+    visibility = [ ":$_target_name" ]
+    script = "//build/config/ios/ios_compile_xib.py"
+    sources = [
+      invoker.source,
+    ]
+    outputs = [
+      "$target_gen_dir/$_nib_filename/objects.nib",
+      "$target_gen_dir/$_nib_filename/runtime.nib",
+    ]
+    args = [
+      "--minimum-deployment-target",
+      ios_deployment_target,
+      "--output",
+      rebase_path("$target_gen_dir/$_nib_filename"),
+      "--input",
+      rebase_path(invoker.source, root_build_dir),
+    ]
+  }
+
+  bundle_data(_target_name) {
+    forward_variables_from(invoker, "*", [ "source" ])
+
+    if (!defined(public_deps)) {
+      public_deps = []
+    }
+    public_deps += [ ":$_compile_xib" ]
+
+    sources = [
+      "$target_gen_dir/$_nib_filename/objects.nib",
+      "$target_gen_dir/$_nib_filename/runtime.nib",
+    ]
+    outputs = [
+      "{{bundle_resources_dir}}/$_nib_filename/{{source_file_part}}",
+    ]
+  }
+}