Add fuzzers for import of WebCrypto DER-encoded keys.

components/webcrypto/BUILD.gn

 # Copyright 2015 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//testing/test.gni")
+import("//testing/libfuzzer/fuzzer_test.gni")
 
 source_set("webcrypto") {
   sources = [
     "algorithm_dispatch.cc",
     "algorithm_dispatch.h",
     "algorithm_implementation.cc",
     "algorithm_implementation.h",
     "algorithm_implementations.h",
     "algorithm_registry.cc",
     "algorithm_registry.h",
@@ skipping 70 matching lines @@
     "//base/test:test_support",
     "//components/test_runner:test_runner",
     "//crypto",
     "//crypto:platform",
     "//testing/gtest",
     "//testing/perf",
     "//third_party/WebKit/public:blink",
     "//third_party/re2",
   ]
 }
+
+# Shared functionality for writing WebCrypto fuzzers at this layer (several
+# things need to be done to initialize Blink and pull in the right
+# dependencies).
+source_set("fuzzer_support") {
+  testonly = true
+
+  sources = [
+    "fuzzer_support.cc",
+    "fuzzer_support.h",
+  ]
+  deps = [
+    ":webcrypto",
+    "//crypto",
+    "//crypto:platform",
+
+    # The "blink_for_unittests" includes a dependency on Mojo, which otherwise
+    # public:blink lacks and would result in a linker error.
+    "//third_party/WebKit/public:blink_for_unittests",
+
+    # This contains a helper function for initializing Blink (needed for
+    # PartitionAlloc initialization).
+    "//components/test_runner:test_runner",
+  ]
+}
+
+# Tests the import of PKCS8 formatted EC keys.
+fuzzer_test("ec_import_key_pkcs8_fuzzer") {
+  sources = [
+    "ec_import_key_pkcs8_fuzzer.cc",
+  ]
+  deps = [
+    ":fuzzer_support",
+    ":webcrypto",
+    "//third_party/WebKit/public:blink_headers",
+  ]
+}
+
+# Tests the import of SPKI formatted EC keys.
+fuzzer_test("ec_import_key_spki_fuzzer") {
+  sources = [
+    "ec_import_key_spki_fuzzer.cc",
+  ]
+  deps = [
+    ":fuzzer_support",
+    ":webcrypto",
+    "//third_party/WebKit/public:blink_headers",
+  ]
+}
+
+# Tests the import of PKCS8 formatted RSA keys.
+fuzzer_test("rsa_import_key_pkcs8_fuzzer") {
+  sources = [
+    "rsa_import_key_pkcs8_fuzzer.cc",
+  ]
+  deps = [
+    ":fuzzer_support",
+    ":webcrypto",
+    "//third_party/WebKit/public:blink_headers",
+  ]
+}
+
+# Tests the import of SPKI formatted RSA keys.
+fuzzer_test("rsa_import_key_spki_fuzzer") {
+  sources = [
+    "rsa_import_key_pkcs8_fuzzer.cc",

[Nico, 2017/03/26 03:14:39]

You copied rsa_import_key_pkcs8_fuzzer here and forgot to change the sources
line. None of your fuzzers uses rsa_import_key_spki_fuzzer.cc but two use
rsa_import_key_pkcs8_fuzzer.cc. Whoops! :-)

[eroman, 2017/03/30 17:02:56]

Ugh, I am terrible :(

Thanks for pointing this out!

+  ]
+  deps = [
+    ":fuzzer_support",
+    ":webcrypto",
+    "//third_party/WebKit/public:blink_headers",
+  ]
+}