Implement Material Design for Mac toolbar.

chrome/browser/ui/cocoa/omnibox/omnibox_view_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/ui/cocoa/omnibox/omnibox_view_mac.h"
 
 #include <Carbon/Carbon.h>  // kVK_Return
 
 #include "base/mac/foundation_util.h"
 #include "base/metrics/histogram.h"
 #include "base/strings/string_util.h"
 #include "base/strings/sys_string_conversions.h"
 #include "base/strings/utf_string_conversions.h"
 #include "chrome/browser/autocomplete/chrome_autocomplete_scheme_classifier.h"
 #include "chrome/browser/browser_process.h"
 #include "chrome/browser/search/search.h"
+#include "chrome/browser/themes/theme_service.h"
 #include "chrome/browser/ui/cocoa/location_bar/autocomplete_text_field_cell.h"
 #import "chrome/browser/ui/cocoa/location_bar/autocomplete_text_field_editor.h"
+#import "chrome/browser/ui/cocoa/browser_window_controller.h"
 #include "chrome/browser/ui/cocoa/omnibox/omnibox_popup_view_mac.h"
 #include "chrome/browser/ui/omnibox/chrome_omnibox_client.h"
 #include "chrome/browser/ui/omnibox/clipboard_utils.h"
 #include "chrome/grit/generated_resources.h"
 #include "components/omnibox/browser/autocomplete_input.h"
 #include "components/omnibox/browser/autocomplete_match.h"
 #include "components/omnibox/browser/omnibox_edit_controller.h"
 #include "components/omnibox/browser/omnibox_field_trial.h"
 #include "components/omnibox/browser/omnibox_popup_model.h"
 #include "components/security_state/security_state_model.h"
 #include "components/toolbar/toolbar_model.h"
 #include "content/public/browser/web_contents.h"
 #include "extensions/common/constants.h"
 #import "third_party/mozilla/NSPasteboard+Utils.h"
 #include "ui/base/clipboard/clipboard.h"
 #import "ui/base/cocoa/cocoa_base_utils.h"
+#include "ui/base/material_design/material_design_controller.h"
 #include "ui/base/resource/resource_bundle.h"
 #include "ui/gfx/font.h"
 #include "ui/gfx/font_list.h"
 #include "ui/gfx/geometry/rect.h"
 
 using content::WebContents;
 
 // Focus-handling between |field_| and model() is a bit subtle.
 // Other platforms detect change of focus, which is inconvenient
 // without subclassing NSTextField (even with a subclass, the use of a
@@ skipping 27 matching lines @@
 NSColor* ColorWithRGBBytes(int rr, int gg, int bb) {
   DCHECK_LE(rr, 255);
   DCHECK_LE(bb, 255);
   DCHECK_LE(gg, 255);
   return [NSColor colorWithCalibratedRed:static_cast<float>(rr)/255.0
                                    green:static_cast<float>(gg)/255.0
                                     blue:static_cast<float>(bb)/255.0
                                    alpha:1.0];
 }
 
-NSColor* HostTextColor() {
-  return [NSColor blackColor];
+NSColor* HostTextColor(bool inDarkMode) {
+  if (!ui::MaterialDesignController::IsModeMaterial()) {
+    return [NSColor blackColor];
+  }
+  return inDarkMode ? [NSColor whiteColor] : [NSColor blackColor];
 }
-NSColor* BaseTextColor() {
-  return [NSColor darkGrayColor];
+NSColor* BaseTextColor(bool inDarkMode) {
+  if (!ui::MaterialDesignController::IsModeMaterial()) {
+    return [NSColor darkGrayColor];
+  }
+  return inDarkMode ? [NSColor colorWithCalibratedWhite:1 alpha:0.5] :
+                      [NSColor colorWithCalibratedWhite:0 alpha:0.5];
 }
-NSColor* SecureSchemeColor() {
-  return ColorWithRGBBytes(0x07, 0x95, 0x00);
+NSColor* SecureSchemeColor(bool inDarkMode) {
+  if (!ui::MaterialDesignController::IsModeMaterial()) {
+    return ColorWithRGBBytes(0x07, 0x95, 0x00);
+  }
+  return inDarkMode ? [NSColor colorWithCalibratedWhite:1 alpha:0.5] :
+                      ColorWithRGBBytes(0x0B, 0x80, 0x43);
 }
-NSColor* SecurityErrorSchemeColor() {
-  return ColorWithRGBBytes(0xa2, 0x00, 0x00);
+NSColor* SecurityWarningSchemeColor(bool inDarkMode) {
+  return inDarkMode ? [NSColor colorWithCalibratedWhite:1 alpha:0.5] :
+                      ColorWithRGBBytes(0xF0, 0x93, 0x00);
+}
+NSColor* SecurityErrorSchemeColor(bool inDarkMode) {
+  if (!ui::MaterialDesignController::IsModeMaterial()) {
+    return ColorWithRGBBytes(0xa2, 0x00, 0x00);
+  }
+  return inDarkMode ? [NSColor colorWithCalibratedWhite:1 alpha:0.5] :
+                      ColorWithRGBBytes(0xC5, 0x39, 0x29);
 }
 
 const char kOmniboxViewMacStateKey[] = "OmniboxViewMacState";
 
 // Store's the model and view state across tab switches.
 struct OmniboxViewMacState : public base::SupportsUserData::Data {
   OmniboxViewMacState(const OmniboxEditModel::State model_state,
                       const bool has_focus,
                       const NSRange& selection)
       : model_state(model_state),
@@ skipping 402 matching lines @@
   [attributedString addAttribute:NSParagraphStyleAttributeName
                            value:paragraph_style
                            range:NSMakeRange(0, [attributedString length])];
 }
 
 void OmniboxViewMac::ApplyTextAttributes(
     const base::string16& display_text,
     NSMutableAttributedString* attributedString) {
   NSUInteger as_length = [attributedString length];
   NSRange as_entire_string = NSMakeRange(0, as_length);
+  bool inDarkMode = [[field_ window] inIncognitoModeWithSystemTheme];
 
   ApplyTextStyle(attributedString);
 
   // A kinda hacky way to add breaking at periods. This is what Safari does.
   // This works for IDNs too, despite the "en_US".
   [attributedString addAttribute:@"NSLanguage"
                            value:@"en_US_POSIX"
                            range:as_entire_string];
 
   url::Component scheme, host;
   AutocompleteInput::ParseForEmphasizeComponents(
       display_text, ChromeAutocompleteSchemeClassifier(profile_), &scheme,
       &host);
   bool grey_out_url = display_text.substr(scheme.begin, scheme.len) ==
       base::UTF8ToUTF16(extensions::kExtensionScheme);
   if (model()->CurrentTextIsURL() &&
       (host.is_nonempty() || grey_out_url)) {
     [attributedString addAttribute:NSForegroundColorAttributeName
-                             value:BaseTextColor()
+                             value:BaseTextColor(inDarkMode)
                              range:as_entire_string];
 
     if (!grey_out_url) {
       [attributedString addAttribute:NSForegroundColorAttributeName
-                               value:HostTextColor()
+                               value:HostTextColor(inDarkMode)
                                range:ComponentToNSRange(host)];
     }
   }
 
   // TODO(shess): GTK has this as a member var, figure out why.
   // [Could it be to not change if no change?  If so, I'm guessing
   // AppKit may already handle that.]
   const security_state::SecurityStateModel::SecurityLevel security_level =
       controller()->GetToolbarModel()->GetSecurityLevel(false);
 
   // Emphasize the scheme for security UI display purposes (if necessary).
   if (!model()->user_input_in_progress() && model()->CurrentTextIsURL() &&
       scheme.is_nonempty() &&
       (security_level != security_state::SecurityStateModel::NONE)) {
     NSColor* color;
     if (security_level == security_state::SecurityStateModel::EV_SECURE ||
         security_level == security_state::SecurityStateModel::SECURE) {
-      color = SecureSchemeColor();
+      color = SecureSchemeColor(inDarkMode);
     } else if (security_level ==
                security_state::SecurityStateModel::SECURITY_ERROR) {
-      color = SecurityErrorSchemeColor();
+      color = SecurityErrorSchemeColor(inDarkMode);
       // Add a strikethrough through the scheme.
       [attributedString addAttribute:NSStrikethroughStyleAttributeName
                  value:[NSNumber numberWithInt:NSUnderlineStyleSingle]
                  range:ComponentToNSRange(scheme)];
     } else if (security_level ==
                security_state::SecurityStateModel::SECURITY_WARNING) {
-      color = BaseTextColor();
+      color = SecurityWarningSchemeColor(inDarkMode);
     } else {
       NOTREACHED();
-      color = BaseTextColor();
+      color = BaseTextColor(inDarkMode);
     }
     [attributedString addAttribute:NSForegroundColorAttributeName
                              value:color
                              range:ComponentToNSRange(scheme)];
+  } else if (as_length) {
+    [attributedString addAttribute:NSForegroundColorAttributeName
+                             value:BaseTextColor(inDarkMode)
+                             range:as_entire_string];
   }
 }
 
 void OmniboxViewMac::OnTemporaryTextMaybeChanged(
     const base::string16& display_text,
     bool save_original_selection,
     bool notify_text_changed) {
   if (save_original_selection)
     saved_temporary_selection_ = GetSelectedRange();
 
@@ skipping 490 matching lines @@
 
 NSUInteger OmniboxViewMac::GetTextLength() const {
   return [field_ currentEditor] ?  [[[field_ currentEditor] string] length] :
                                    [[field_ stringValue] length];
 }
 
 bool OmniboxViewMac::IsCaretAtEnd() const {
   const NSRange selection = GetSelectedRange();
   return NSMaxRange(selection) == GetTextLength();
 }