MacViews: Add native drop shadow to dialogs on OSX < 10.10.

ui/gfx/path_mac.mm

+// Copyright (c) 2016 The Chromium Authors. All rights reserved.

[tapted, 2016/01/28 05:59:21]

nit: no (c)

[karandeepb, 2016/02/04 03:39:27]

Done.

+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "ui/gfx/path_mac.h"
+
+#import <Cocoa/Cocoa.h>
+
+#include "third_party/skia/include/core/SkRegion.h"
+#include "ui/gfx/path.h"
+
+namespace {
+
+// Convert an SkPoint to an NSPoint.
+NSPoint GetNSPointFromSkPoint(const SkPoint& point) {
+  return NSMakePoint(point.x(), point.y());
+}
+
+}  // namespace
+
+namespace gfx {
+
+NSBezierPath* CreateNSBezierPathFromSkRegion(const SkRegion& region) {
+  NSBezierPath* result = [NSBezierPath bezierPath];
+  for (SkRegion::Iterator i(region); !i.done(); i.next()) {
+    const SkIRect& rect = i.rect();
+    [result appendBezierPathWithRect:NSMakeRect(rect.x(), rect.y(),
+                                                rect.width(), rect.height())];
+  }
+  return result;
+}
+
+NSBezierPath* CreateNSBezierPathFromSkPath(const SkPath& path) {

[karandeepb, 2016/01/27 23:25:03]

A simpler implementation like that in path_win.cc also works, but it's not
entirely accurate especially if we use this function for stroking (and not just
filling) purposes later on.

+  NSBezierPath* result = [NSBezierPath bezierPath];
+  SkPath::RawIter iter(path);
+  SkPoint points[4];
+  SkPath::Verb verb;
+  while ((verb = iter.next(points)) != SkPath::kDone_Verb) {
+    switch (verb) {
+      case SkPath::kMove_Verb:
+        [result moveToPoint:GetNSPointFromSkPoint(points[0])];
+        break;
+      case SkPath::kLine_Verb:
+        DCHECK(NSEqualPoints([result currentPoint],
+                             GetNSPointFromSkPoint(points[0])));
+        [result lineToPoint:GetNSPointFromSkPoint(points[1])];
+        break;
+      case SkPath::kQuad_Verb: {

[tapted, 2016/01/28 05:59:21]

typically if any `case` has curlies in Chrome, all the cases should get them

[karandeepb, 2016/02/04 03:39:27]

Done.

+        DCHECK(NSEqualPoints([result currentPoint],
+                             GetNSPointFromSkPoint(points[0])));
+        SkPoint quad[] = {points[0], points[1], points[2]};
+        // NSBezierPath does not support quadratic bezier curves. Hence convert
+        // to cubic bezier curve.
+        SkPath::ConvertQuadToCubic(quad, points);

[tapted, 2016/01/28 05:59:21]

Does this function exist? Maybe you modified SkPath.h to export the internal
skia function. Is it needed to implement the window shape stuff? Could we
instead do:

// NSBezierPath does not support quadratic bezier curves. It is straightforward
// to convert to cubic using (e.g. with SkConvertQuadToCubic from SkGeometry.h)
// but that's not required yet.
NOTREACHED();

[karandeepb, 2016/02/04 03:39:27]

Yeah I did modify SkPath to expose the internal skia function. Here's the CL -
https://codereview.chromium.org/1639143002/. There's precedent of exposing
functionality in SkPath like  https://codereview.chromium.org/1484373002, which
was just added 2 months ago. I don't think that quadratic bezier curves are
needed currently, but conic curves are needed, and currently my approach is to
convert them to quadratic bezier curves.

Also, converting quadratic to cubic bezier curves is straight-forward, so if
needed, it can be implemented here itself.

+        [result curveToPoint:GetNSPointFromSkPoint(points[3])
+               controlPoint1:GetNSPointFromSkPoint(points[1])
+               controlPoint2:GetNSPointFromSkPoint(points[2])];
+        break;
+      }
+      case SkPath::kCubic_Verb:
+        DCHECK(NSEqualPoints([result currentPoint],
+                             GetNSPointFromSkPoint(points[0])));
+        [result curveToPoint:GetNSPointFromSkPoint(points[3])
+               controlPoint1:GetNSPointFromSkPoint(points[1])
+               controlPoint2:GetNSPointFromSkPoint(points[2])];
+        break;
+      case SkPath::kConic_Verb: {
+        DCHECK(NSEqualPoints([result currentPoint],
+                             GetNSPointFromSkPoint(points[0])));
+        // Approximate with quads. Use two for now, increase if more precision

[tapted, 2016/01/28 05:59:21]

I think we can avoid this with [NSBezierPath
appendBezierPathWithArcFromPoint:...]

except NSBezierPath wants a radius and SkPath gives a "weight". so we probably
need to assume that abs(p0.x - p1.x) == (p0.y - p1.y). Then `radius = abs(p0.x -
p1.x) / SK_ScalarRoot2Over2` (I think).

[karandeepb, 2016/02/04 03:39:27]

I don't think we can approximate a kConicVerb(which I think is a rational
quadratic bezier curve) by a single arc, since it is used to represent conic
sections. It may be possible to do for just the rounded rectangle case though.
Will discuss.

+        // is needed.
+        const size_t kPow2 = 1;
+        const size_t quadCount = 1 << kPow2;
+        SkPoint quads[1 + 2 * quadCount];
+        SkPath::ConvertConicToQuads(points[0], points[1], points[2],
+                                    iter.conicWeight(), quads, kPow2);
+        for (size_t i = 0; i < quadCount; i++) {
+          SkPoint quad[] = {quads[2 * i], quads[2 * i + 1], quads[2 * i + 2]};
+          SkPath::ConvertQuadToCubic(quad, points);
+          [result curveToPoint:GetNSPointFromSkPoint(points[3])
+                 controlPoint1:GetNSPointFromSkPoint(points[1])
+                 controlPoint2:GetNSPointFromSkPoint(points[2])];
+        }
+        break;
+      }
+      case SkPath::kClose_Verb:
+        [result closePath];
+        break;
+      default:
+        NOTREACHED();
+    }
+  }
+
+  // Set up the fill type. NSBezierCurve does not have inverse fill types.
+  if (!path.isInverseFillType()) {

[tapted, 2016/01/28 05:59:21]

instead can we DCHECK(!path.isInverseFillType()); ?

or perhaps replace the `default` case with

case kInverseWinding_FillType:
case kInverseEvenOdd_FillType:
  NOTREACHED() << "NSBezierCurve does not support inverse fill types."

[karandeepb, 2016/02/04 03:39:27]

Done.

+    switch (path.getFillType()) {
+      case SkPath::kWinding_FillType:
+        [result setWindingRule:NSNonZeroWindingRule];
+        break;
+      case SkPath::kEvenOdd_FillType:
+        [result setWindingRule:NSEvenOddWindingRule];
+        break;
+      default:
+        NOTREACHED();
+    }
+  }
+
+  return result;
+}
+
+}  // namespace gfx