Build nacl_helper_nonsfi with GN

components/nacl/BUILD.gn

Index: components/nacl/BUILD.gn
diff --git a/components/nacl/BUILD.gn b/components/nacl/BUILD.gn
index ceb79717289caa4a54264bf5f3a8adc01a723eaf..d76450782b4270e59a1b0ef464f7823c51b8fed7 100644
--- a/components/nacl/BUILD.gn
+++ b/components/nacl/BUILD.gn
@@ -234,11 +234,82 @@ if (enable_nacl) {
       }
     }
   }
+
+  if (is_nacl) {

[brettw, 2015/10/25 08:45:33]

Do we want these for all nacl variants? It seems like we would want to wrap this
in a nonsfi conditional so we don't compile it in other cases.

[Petr Hosek, 2015/10/25 22:50:48]

Done.

+    executable("nacl_helper_nonsfi_nexe") {
+      output_name = "nacl_helper_nonsfi"
+      set_sources_assignment_filter([])
+      sources = [
+        "common/nacl_messages.cc",
+        "common/nacl_messages.h",
+        "common/nacl_types.cc",
+        "common/nacl_types.h",
+        "common/nacl_types_param_traits.cc",
+        "common/nacl_types_param_traits.h",
+        "loader/nacl_helper_linux.cc",
+        "loader/nacl_helper_linux.h",
+        "loader/nacl_trusted_listener.cc",
+        "loader/nacl_trusted_listener.h",
+        "loader/nonsfi/nonsfi_listener.cc",
+        "loader/nonsfi/nonsfi_listener.h",
+        "loader/nonsfi/nonsfi_main.cc",
+        "loader/nonsfi/nonsfi_main.h",
+      ]
+      deps = [
+        ":nacl_switches",
+        ":nacl_helper_nonsfi_sandbox",
+        "//base",
+        "//components/tracing",
+        "//content",
+        "//ipc",
+        "//native_client/src/nonsfi/irt:nacl_sys_private",
+        "//native_client/src/nonsfi/loader:elf_loader",
+        "//native_client/src/untrusted/nacl:nacl",
+        "//ppapi/proxy",
+        "//sandbox/linux:sandbox_linux_nacl_nonsfi",
+      ]
+    }
+
+    source_set("nacl_helper_nonsfi_sandbox") {
+      set_sources_assignment_filter([])
+      sources = [
+        "loader/nonsfi/nonsfi_sandbox.cc",
+        "loader/nonsfi/nonsfi_sandbox.h",
+        "loader/sandbox_linux/nacl_sandbox_linux.cc",
+        "loader/sandbox_linux/nacl_sandbox_linux.h",
+      ]
+      deps = [
+        "//base",
+        "//content",
+        "//sandbox/linux:sandbox_linux_nacl_nonsfi",
+      ]
+    }
+
+    copy("nacl_helper_nonsfi_copy") {
+      sources = [
+        "${root_out_dir}/nacl_helper_nonsfi",
+      ]
+      outputs = [
+        "${root_build_dir}/{{source_file_part}}",
+      ]
+      deps = [
+        ":nacl_helper_nonsfi_nexe",
+      ]
+    }
+
+    group("nacl_helper_nonsfi") {

[brettw, 2015/10/25 08:45:33]

The way this is set up is a bit confused. There are two ways I could see doing
this, and the way it's done is kind of half of both.

Way #1 is to have one nacl_helper_nonsfi target that's compiled only in the
nonsfi toolchain. In that case, the copy step above would be renamed
nacl_helper_nonsfi.

Way #2 is to have a "nacl_helper_nonsfi" trampoline in all toolchains that then
link to the nacl_helper_nonsfi_copy step in the nonsfi toolchain. In that case,
this group should be brought out of the is_nacl conditional, and then all
references to it can have the explicit toolchain reference removed.

I'm partial to way #2 since it centralizes knowledge of the nonsfi toolchain.

[Petr Hosek, 2015/10/25 22:50:48]

Done; I went with the option #2.

+      deps = [
+        ":nacl_helper_nonsfi_copy(//build/toolchain/nacl:newlib_pnacl_nonsfi)",
+      ]
+    }
+  }
 } else {
   group("nacl") {

[brettw, 2015/10/25 08:58:08]

Also, in either case I mentioned above, you can delete the contents of this
else. The nacl_helper targets (except the trampoline in #2 that is run in all
cases complete outside of this conditional) will be referenced only in the
correct toolchain.

[Petr Hosek, 2015/10/25 22:50:48]

Done.

   }
   group("nacl_helper") {
   }
+  group("nacl_helper_nonsfi") {
+  }
 }
 
 source_set("nacl_switches") {