Generate resource pak files for top chrome material design assets

chrome/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/chrome_build.gni")
 import("//build/config/features.gni")
 import("//build/config/locales.gni")
 import("//build/config/ui.gni")
 import("//chrome/chrome_repack_locales.gni")
 import("//chrome/version.gni")
@@ skipping 456 matching lines @@
     ":repack_chrome_100_percent",
   ]
 
   if (is_chrome_branded) {
     deps += [ ":default_apps" ]
   }
 
   if (enable_hidpi) {
     deps += [ ":repack_chrome_200_percent" ]
   }
+
+  if (enable_topchrome_md) {
+    deps += [ ":repack_chrome_material_100_percent" ]
+
+    if (enable_hidpi) {
+      deps += [ ":repack_chrome_material_200_percent" ]
+    }
+  }
 }
 
 repack("packed_extra_resources") {
   visibility = [ "./*" ]
   sources = [
     "$root_gen_dir/chrome/browser_resources.pak",
     "$root_gen_dir/chrome/chrome_unscaled_resources.pak",
     "$root_gen_dir/chrome/common_resources.pak",
     "$root_gen_dir/chrome/invalidations_resources.pak",
     "$root_gen_dir/chrome/memory_internals_resources.pak",
@@ skipping 206 matching lines @@
 chrome_repack_percent("repack_chrome_100_percent") {
   percent = "100"
 }
 
 if (enable_hidpi) {
   chrome_repack_percent("repack_chrome_200_percent") {
     percent = "200"
   }
 }
 
+# Generates a rule to repack a set of material design resources for the browser
+# top chrome, substituting a given string in for the percentage (e.g. "100",
+# "200").
+template("chrome_repack_material_percent") {
+  percent = invoker.percent
+
+  repack_name = "${target_name}_repack"
+  repack_output_file = "$root_gen_dir/repack/chrome_material_${percent}_percent.pak"
+
+  copy_name = target_name
+
+  repack(repack_name) {
+    visibility = [ ":$copy_name" ]
+
+    # All sources should also have deps for completeness.
+    sources = [
+      "$root_gen_dir/chrome/theme_resources_material_${percent}_percent.pak",
+    ]
+
+    deps = [
+      "//chrome/app/theme:theme_resources",
+    ]
+
+    output = repack_output_file
+  }
+
+  copy(copy_name) {
+    visibility = [ ":*" ]
+    deps = [
+      ":$repack_name",
+    ]
+    sources = [
+      repack_output_file,
+    ]
+    outputs = [
+      "$root_build_dir/chrome_material_${percent}_percent.pak",
+    ]
+  }
+}
+
+if (enable_topchrome_md) {
+  chrome_repack_material_percent("repack_chrome_material_100_percent") {
+    percent = "100"
+  }
+
+  if (enable_hidpi) {
+    chrome_repack_material_percent("repack_chrome_material_200_percent") {
+      percent = "200"
+    }
+  }
+}
+
 # GYP version: chrome/chrome_resources.gyp:chrome_strings
 group("strings") {
   deps = [
     "//chrome/app:chromium_strings",
     "//chrome/app:generated_resources",
     "//chrome/app:google_chrome_strings",
     "//chrome/app/resources:locale_settings",
   ]
 }
 
@@ skipping 122 matching lines @@
       rebase_path(chrome_binary, root_build_dir),
       rebase_path(symbol_file, root_build_dir),
     ]
 
     deps = [
       ":chrome",
       dump_syms_label,
     ]
   }
 }