Move net::FormatUrl and friends outside of //net and into //components

components/url_formatter/BUILD.gn

Index: components/url_formatter/BUILD.gn
diff --git a/components/url_formatter/BUILD.gn b/components/url_formatter/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..6a35fb3d0dcbe75080b0cc11a63d1d4d8d980b1a
--- /dev/null
+++ b/components/url_formatter/BUILD.gn
@@ -0,0 +1,51 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+static_library("url_formatter") {

[brettw, 2015/08/06 22:25:50]

This should be a source_set too.

+  sources = [
+    "elide_url.cc",
+    "elide_url.h",
+    "url_fixer.cc",
+    "url_fixer.h",
+    "url_formatter.cc",
+    "url_formatter.h",
+  ]
+
+  # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
+  configs += [ "//build/config/compiler:no_size_t_to_int_warning" ]
+
+  deps = [
+    "//base",
+    "//third_party/icu",
+    "//net",
+    "//ui/gfx",
+    "//url",
+  ]
+
+  if (is_android) {
+    deps -= [ "//ui/gfx" ]

[brettw, 2015/08/06 22:25:50]

In GYP this is how you would do it, but in GN I prefer the opposite:
  if (!is_android) {
    deps += [ "//ui/gfx" ]
  }
and then don't add it to the list above. Same below.

+  }
+}
+
+source_set("unit_tests") {
+  testonly = true
+  sources = [
+    "elide_url_unittest.cc",
+    "url_fixer_unittest.cc",
+    "url_formatter_unittest.cc",
+  ]
+
+  deps = [
+    "//base",
+    "//net",
+    "//testing/gtest",
+    "//ui/gfx",
+    "//url",
+    ":url_formatter",

[brettw, 2015/08/06 22:25:50]

This goes first.

+  ]
+
+  if (is_android) {
+    deps -= [ "//ui/gfx" ]
+  }
+}