Deconstructed APK prototyping

apk/BUILD.gn

+import("//build/config/android/rules.gni")
+
+shared_library("simple") {
+  sources = [
+    "simple_jni.cc",
+    "simple.cc",
+    "simple.h",
+  ]
+  deps = [
+    "//base",
+    ":simple_jni",
+  ]
+}
+
+generate_jni("simple_jni") {
+  sources = [
+    "java/org/chromium/simple/MainActivity.java",
+  ]
+  jni_package = "simple"
+}
+
+android_resources("simple_resources") {
+  v14_verify_only = true
+  resource_dirs = [ "res" ]
+  custom_package = "org.chromium.simple"
+}
+
+android_library("simple_java") {
+  DEPRECATED_java_in_dir = "java"
+  deps = [
+    "//base:base_java",
+    ":simple_resources",
+  ]
+}
+
+android_apk("simple_apk") {
+  deps = [
+    ":simple",
+    ":simple_java",
+    ":simple_resources",
+    "//base:base_java",
+  ]
+  apk_name = "SimpleApk"
+  android_manifest = "AndroidManifest.xml"
+  native_libs = [ "libsimple.so" ]
+  asset_location = "assets"
+}
+
+deconstructed_manifest = "$root_build_dir/deconstructed/AndroidManifest.xml"
+deconstructed_assets = "$root_build_dir/assets"
+
+action("deconstruct_manifest") {
+  script = "//build/android/gyp/rewrite_deconstruct_manifest.py"
+  inputs = [
+    "AndroidManifest.xml"
+  ]
+  data_file = "$deconstructed_assets/data.txt"
+  outputs = [
+    deconstructed_manifest,
+    data_file,
+  ]
+  args = [
+    "--in-manifest", rebase_path("AndroidManifest.xml", root_build_dir),
+    "--out-manifest", rebase_path(deconstructed_manifest, root_build_dir),
+    "--out-data", rebase_path(data_file, root_build_dir),
+  ]
+}
+
+android_library("deconstructed_java") {
+  DEPRECATED_java_in_dir = "hijack"
+}
+
+android_apk("deconstructed_apk") {
+  deps = [
+    ":deconstructed_java",
+    ":deconstruct_manifest",
+    ":simple_resources",
+  ]
+  apk_name = "DeconstructedSimpleApk"
+  android_manifest = deconstructed_manifest
+  asset_location = deconstructed_assets
+}