[Mac] Use a custom view to implement colored app windows.

chrome/browser/ui/cocoa/apps/native_app_window_cocoa.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/ui/cocoa/apps/native_app_window_cocoa.h"
 
 #include "base/command_line.h"
 #include "base/mac/foundation_util.h"
 #include "base/mac/mac_util.h"
 #include "base/mac/sdk_forward_declarations.h"
 #include "base/strings/sys_string_conversions.h"
 #include "chrome/browser/apps/app_shim/extension_app_shim_handler_mac.h"
 #include "chrome/browser/profiles/profile.h"
 #include "chrome/browser/ui/cocoa/browser_window_utils.h"
 #import "chrome/browser/ui/cocoa/chrome_event_processing_window.h"
-#import "chrome/browser/ui/cocoa/custom_frame_view.h"
 #include "chrome/browser/ui/cocoa/extensions/extension_keybinding_registry_cocoa.h"
 #include "chrome/browser/ui/cocoa/extensions/extension_view_mac.h"
 #include "chrome/common/chrome_switches.h"
 #include "content/public/browser/native_web_keyboard_event.h"
 #include "content/public/browser/render_widget_host_view.h"
 #include "content/public/browser/web_contents.h"
 #include "extensions/common/extension.h"
 #include "skia/ext/skia_utils_mac.h"
 #include "third_party/skia/include/core/SkRegion.h"
 #include "ui/gfx/skia_util.h"
@@ skipping 174 matching lines @@
 
 - (BOOL)handledByExtensionCommand:(NSEvent*)event
     priority:(ui::AcceleratorManager::HandlerPriority)priority {
   if (appWindow_)
     return appWindow_->HandledByExtensionCommand(event, priority);
   return NO;
 }
 
 @end
 
-// This is really a method on NSGrayFrame, so it should only be called on the
-// view passed into -[NSWindow drawCustomFrameRect:forView:].
-@interface NSView (PrivateMethods)
-- (CGFloat)roundedCornerRadius;
-@end
-
-// TODO(jamescook): Should these be AppNSWindow to match AppWindow?
-// http://crbug.com/344082
-@interface ShellNSWindow : ChromeEventProcessingWindow
-@end
-@implementation ShellNSWindow
-
-// Similar to ChromeBrowserWindow, don't draw the title, but allow it to be seen
-// in menus, Expose, etc.
-- (BOOL)_isTitleHidden {
-  return YES;
-}
-
-- (void)drawCustomFrameRect:(NSRect)frameRect forView:(NSView*)view {
-  // Make the background color of the content area white. We can't just call
-  // -setBackgroundColor as that causes the title bar to be drawn in a solid
-  // color.
-  NSRect rect = [self contentRectForFrameRect:frameRect];
-  [[NSColor whiteColor] set];
-  NSRectFill(rect);
-
-  // Draw the native title bar. We remove the content area since the native
-  // implementation draws a gray background.
-  rect.origin.y = NSMaxY(rect);
-  rect.size.height = CGFLOAT_MAX;
-  rect = NSIntersectionRect(rect, frameRect);
-
-  [NSBezierPath clipRect:rect];
-  [super drawCustomFrameRect:frameRect
-                     forView:view];
-}
-
-@end
-
-@interface ShellCustomFrameNSWindow : ShellNSWindow {
+// A view that paints a solid color. Used to change the title bar background.
+@interface TitlebarBackgroundView : NSView {
  @private
   base::scoped_nsobject<NSColor> color_;
   base::scoped_nsobject<NSColor> inactiveColor_;
 }
-
 - (void)setColor:(NSColor*)color
     inactiveColor:(NSColor*)inactiveColor;
-
 @end
 
-@implementation ShellCustomFrameNSWindow
+@implementation TitlebarBackgroundView
 
-- (void)drawCustomFrameRect:(NSRect)rect forView:(NSView*)view {
-  [[NSBezierPath bezierPathWithRect:rect] addClip];
-  [[NSColor clearColor] set];
-  NSRectFill(rect);
-
-  // Set up our clip.
+- (void)drawRect:(NSRect)rect {
+  // Only the top corners are rounded. For simplicity, round all 4 corners but
+  // draw the bottom corners outside of the visible bounds.
   CGFloat cornerRadius = 4.0;
-  if ([view respondsToSelector:@selector(roundedCornerRadius)])
-    cornerRadius = [view roundedCornerRadius];
-  [[NSBezierPath bezierPathWithRoundedRect:[view bounds]
+  NSRect roundedRect = [self bounds];
+  roundedRect.origin.y -= cornerRadius;
+  roundedRect.size.height += cornerRadius;
+  [[NSBezierPath bezierPathWithRoundedRect:roundedRect
                                    xRadius:cornerRadius
                                    yRadius:cornerRadius] addClip];
-  if ([self isMainWindow] || [self isKeyWindow])
+  if ([[self window] isMainWindow] || [[self window] isKeyWindow])
     [color_ set];
   else
     [inactiveColor_ set];
   NSRectFill(rect);
 }
 
 - (void)setColor:(NSColor*)color
     inactiveColor:(NSColor*)inactiveColor {
   color_.reset([color retain]);
   inactiveColor_.reset([inactiveColor retain]);
 }
 
 @end
 
+// TODO(jamescook): Should these be AppNSWindow to match AppWindow?
+// http://crbug.com/344082
+@interface ShellNSWindow : ChromeEventProcessingWindow
+@end
+
+@implementation ShellNSWindow
+
+// Similar to ChromeBrowserWindow, don't draw the title, but allow it to be seen
+// in menus, Expose, etc.
+- (BOOL)_isTitleHidden {
+  return YES;
+}
+
+@end
+
 @interface ShellFramelessNSWindow : ShellNSWindow
 @end
 
 @implementation ShellFramelessNSWindow
 
-- (void)drawCustomFrameRect:(NSRect)rect forView:(NSView*)view {}
-
 + (NSRect)frameRectForContentRect:(NSRect)contentRect
                         styleMask:(NSUInteger)mask {
   return contentRect;
 }
 
 + (NSRect)contentRectForFrameRect:(NSRect)frameRect
                         styleMask:(NSUInteger)mask {
   return frameRect;
 }
 
@@ skipping 36 matching lines @@
       is_fullscreen_(false),
       is_resizable_(params.resizable),
       shows_resize_controls_(true),
       shows_fullscreen_controls_(true),
       has_frame_color_(params.has_frame_color),
       active_frame_color_(params.active_frame_color),
       inactive_frame_color_(params.inactive_frame_color) {
   Observe(WebContents());
 
   base::scoped_nsobject<NSWindow> window;
-  Class window_class;
-  if (has_frame_) {
-    window_class = has_frame_color_ ?
-        [ShellCustomFrameNSWindow class] : [ShellNSWindow class];
-  } else {
-    window_class = [ShellFramelessNSWindow class];
-  }
+  Class window_class = has_frame_ ?
+      [ShellNSWindow class] : [ShellFramelessNSWindow class];
 
   // Estimate the initial bounds of the window. Once the frame insets are known,
   // the window bounds and constraints can be set precisely.
   NSRect cocoa_bounds = GfxToCocoaBounds(
       params.GetInitialWindowBounds(gfx::Insets()));
   window.reset([[window_class alloc]
       initWithContentRect:cocoa_bounds
                 styleMask:GetWindowStyleMask()
                   backing:NSBackingStoreBuffered
                     defer:NO]);
 
   std::string name;
   const extensions::Extension* extension = app_window_->GetExtension();
   if (extension)
     name = extension->name();
   [window setTitle:base::SysUTF8ToNSString(name)];
   [[window contentView] setWantsLayer:YES];
   if (has_frame_ && has_frame_color_) {
-    [base::mac::ObjCCastStrict<ShellCustomFrameNSWindow>(window)
+    // AppKit only officially supports adding subviews to the window's
+    // contentView and not its superview (an NSNextStepFrame). The 10.10 SDK
+    // allows adding an NSTitlebarAccessoryViewController to a window, but the
+    // view can only be placed above the window control buttons, so we'd have to
+    // replicate those.
+    NSView* window_view = [[window contentView] superview];
+    CGFloat height = NSHeight([window_view bounds]) -
+                     NSHeight([[window contentView] bounds]);
+    titlebar_background_view_.reset([[TitlebarBackgroundView alloc]
+        initWithFrame:NSMakeRect(0, NSMaxY([window_view bounds]) - height,
+                                 NSWidth([window_view bounds]), height)]);
+    [titlebar_background_view_
+        setAutoresizingMask:NSViewWidthSizable | NSViewMinYMargin];
+    [window_view addSubview:titlebar_background_view_
+                 positioned:NSWindowBelow
+                 relativeTo:nil];
+    [titlebar_background_view_
              setColor:gfx::SkColorToSRGBNSColor(active_frame_color_)
         inactiveColor:gfx::SkColorToSRGBNSColor(inactive_frame_color_)];
   }
 
   if (base::mac::IsOSSnowLeopard() &&
       [window respondsToSelector:@selector(setBottomCornerRounded:)])
     [window setBottomCornerRounded:NO];
 
   if (params.always_on_top)
     [window setLevel:AlwaysOnTopWindowLevel()];
@@ skipping 424 matching lines @@
   NOTIMPLEMENTED();
 }
 
 void NativeAppWindowCocoa::WindowWillClose() {
   [window_controller_ setAppWindow:NULL];
   app_window_->OnNativeWindowChanged();
   app_window_->OnNativeClose();
 }
 
 void NativeAppWindowCocoa::WindowDidBecomeKey() {
+  [titlebar_background_view_ setNeedsDisplay:YES];
   content::RenderWidgetHostView* rwhv =
       WebContents()->GetRenderWidgetHostView();
   if (rwhv)
     rwhv->SetActive(true);
   app_window_->OnNativeWindowActivated();
 
   WebContents()->RestoreFocus();
 }
 
 void NativeAppWindowCocoa::WindowDidResignKey() {
   // If our app is still active and we're still the key window, ignore this
   // message, since it just means that a menu extra (on the "system status bar")
   // was activated; we'll get another |-windowDidResignKey| if we ever really
   // lose key window status.
   if ([NSApp isActive] && ([NSApp keyWindow] == window()))
     return;
 
+  [titlebar_background_view_ setNeedsDisplay:YES];
+
   WebContents()->StoreFocus();
 
   content::RenderWidgetHostView* rwhv =
       WebContents()->GetRenderWidgetHostView();
   if (rwhv)
     rwhv->SetActive(false);
 }
 
 void NativeAppWindowCocoa::WindowDidFinishResize() {
   // Update |is_maximized_| if needed:
@@ skipping 151 matching lines @@
 }
 
 void NativeAppWindowCocoa::UpdateRestoredBounds() {
   if (IsRestored(*this))
     restored_bounds_ = [window() frame];
 }
 
 void NativeAppWindowCocoa::HideWithoutMarkingHidden() {
   [window() orderOut:window_controller_];
 }