[Mac] Use a custom view to implement colored app windows.

chrome/browser/ui/cocoa/apps/native_app_window_cocoa.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "chrome/browser/ui/cocoa/apps/native_app_window_cocoa.h"
 
 #include "base/command_line.h"
 #include "base/mac/foundation_util.h"
 #include "base/mac/mac_util.h"
 #include "base/mac/sdk_forward_declarations.h"
@@ skipping 109 matching lines @@
     non_draggable->op(*draggable, SkRegion::kDifference_Op);
     for (SkRegion::Iterator it(*non_draggable); !it.done(); it.next()) {
       result.push_back(gfx::SkIRectToRect(it.rect()));
     }
   }
   return result;
 }
 
 }  // namespace
 
+@interface NativeAppWindowController (Private)

[tapted, 2015/02/12 05:56:04]

(Private) -> ()

[jackhou1, 2015/02/13 00:04:33]

Done.

+- (void)didChangeActive;
+@end
+
 @implementation NativeAppWindowController
 
 @synthesize appWindow = appWindow_;
 
+- (void)didChangeActive {
+  [base::mac::ObjCCastStrict<ShellNSWindow>([self window])
+      didChangeActive];
+}
+
 - (void)windowWillClose:(NSNotification*)notification {
   if (appWindow_)
     appWindow_->WindowWillClose();
 }
 
+- (void)windowDidBecomeMain:(NSNotification*)notification {

[tapted, 2015/02/12 05:56:04]

the FooMain methods should be able to be removed -- we only care about key
status (app windows can't have non-main child windows, which is the only time
we'd have to worry about this)

[jackhou1, 2015/02/13 00:04:33]

Done.

+  [self didChangeActive];
+}
+
+- (void)windowDidResignMain:(NSNotification*)notification {
+  [self didChangeActive];
+}
+
 - (void)windowDidBecomeKey:(NSNotification*)notification {
+  [self didChangeActive];
   if (appWindow_)
     appWindow_->WindowDidBecomeKey();
 }
 
 - (void)windowDidResignKey:(NSNotification*)notification {
+  [self didChangeActive];
   if (appWindow_)
     appWindow_->WindowDidResignKey();
 }
 
 - (void)windowDidResize:(NSNotification*)notification {
   if (appWindow_)
     appWindow_->WindowDidResize();
 }
 
 - (void)windowDidEndLiveResize:(NSNotification*)notification {
@@ skipping 46 matching lines @@
 
 - (BOOL)handledByExtensionCommand:(NSEvent*)event
     priority:(ui::AcceleratorManager::HandlerPriority)priority {
   if (appWindow_)
     return appWindow_->HandledByExtensionCommand(event, priority);
   return NO;
 }
 
 @end
 
-// This is really a method on NSGrayFrame, so it should only be called on the
-// view passed into -[NSWindow drawCustomFrameRect:forView:].
-@interface NSView (PrivateMethods)
-- (CGFloat)roundedCornerRadius;
-@end
-
-// TODO(jamescook): Should these be AppNSWindow to match AppWindow?
-// http://crbug.com/344082
-@interface ShellNSWindow : ChromeEventProcessingWindow
-@end
-@implementation ShellNSWindow
-
-// Similar to ChromeBrowserWindow, don't draw the title, but allow it to be seen
-// in menus, Expose, etc.
-- (BOOL)_isTitleHidden {
-  return YES;
-}
-
-- (void)drawCustomFrameRect:(NSRect)frameRect forView:(NSView*)view {
-  // Make the background color of the content area white. We can't just call
-  // -setBackgroundColor as that causes the title bar to be drawn in a solid
-  // color.
-  NSRect rect = [self contentRectForFrameRect:frameRect];
-  [[NSColor whiteColor] set];
-  NSRectFill(rect);
-
-  // Draw the native title bar. We remove the content area since the native
-  // implementation draws a gray background.
-  rect.origin.y = NSMaxY(rect);
-  rect.size.height = CGFLOAT_MAX;
-  rect = NSIntersectionRect(rect, frameRect);
-
-  [NSBezierPath clipRect:rect];
-  [super drawCustomFrameRect:frameRect
-                     forView:view];
-}
-
-@end
-
-@interface ShellCustomFrameNSWindow : ShellNSWindow {
+@interface TitleBarBackgroundView : NSView {
  @private
   base::scoped_nsobject<NSColor> color_;
   base::scoped_nsobject<NSColor> inactiveColor_;
 }
-
 - (void)setColor:(NSColor*)color
     inactiveColor:(NSColor*)inactiveColor;
-
 @end
 
-@implementation ShellCustomFrameNSWindow
+@implementation TitleBarBackgroundView
 
-- (void)drawCustomFrameRect:(NSRect)rect forView:(NSView*)view {
+- (void)drawRect:(NSRect)rect {
   [[NSBezierPath bezierPathWithRect:rect] addClip];
   [[NSColor clearColor] set];
   NSRectFill(rect);
 
   // Set up our clip.
   CGFloat cornerRadius = 4.0;
-  if ([view respondsToSelector:@selector(roundedCornerRadius)])
-    cornerRadius = [view roundedCornerRadius];
-  [[NSBezierPath bezierPathWithRoundedRect:[view bounds]
+  [[NSBezierPath bezierPathWithRoundedRect:[self bounds]
                                    xRadius:cornerRadius
                                    yRadius:cornerRadius] addClip];
-  if ([self isMainWindow] || [self isKeyWindow])
+  if ([[self window] isMainWindow] || [[self window] isKeyWindow])
     [color_ set];
   else
     [inactiveColor_ set];
   NSRectFill(rect);
 }
 
 - (void)setColor:(NSColor*)color
     inactiveColor:(NSColor*)inactiveColor {
   color_.reset([color retain]);
   inactiveColor_.reset([inactiveColor retain]);
 }
 
 @end
 
+// TODO(jamescook): Should these be AppNSWindow to match AppWindow?
+// http://crbug.com/344082
+@interface ShellNSWindow : ChromeEventProcessingWindow {
+ @private
+  base::scoped_nsobject<TitleBarBackgroundView> titleBarBackgroundView_;
+}
+- (void)didChangeActive;
+- (void)setColor:(NSColor*)color
+    inactiveColor:(NSColor*)inactiveColor;
+@end
+
+@implementation ShellNSWindow
+
+// Similar to ChromeBrowserWindow, don't draw the title, but allow it to be seen
+// in menus, Expose, etc.
+- (BOOL)_isTitleHidden {
+  return YES;
+}
+
+- (void)didChangeActive {
+  [titleBarBackgroundView_ setNeedsDisplay:YES];
+}
+
+- (void)setColor:(NSColor*)color
+    inactiveColor:(NSColor*)inactiveColor {
+  if (!titleBarBackgroundView_) {
+    NSView* windowView = [[self contentView] superview];

[tapted, 2015/02/12 05:56:04]

Mavericks has (officially) banned the practice of manipulating the window's
contentview superview.

https://developer.apple.com/library/mac/releasenotes/AppKit/RN-AppKit/#10_10W...

Should we try using NSTitlebarAccessoryViewController?

[jackhou1, 2015/02/13 00:04:33]

Yes, and looking around forums it seems like adding to contentview.superview may
cause rendering bugs in 10.10.
That API is only available on 10.10 though, so we'd still need the current
method for <=10.9.

[jackhou1, 2015/02/18 04:35:09]

Tested this out on 10.10 linking with both 10.6 and 10.9 SDKs, both work.
Behavior is the same as it is currently. I think we should commit this CL first.

I looked into NSTitlebarAccessoryViewController. It doesn't do quite what we
want, and there might need to be more hackery to get the behavior right. I'll
upload another CL to show what it looks like. 

+    titleBarBackgroundView_.reset([[TitleBarBackgroundView alloc]
+        initWithFrame:NSMakeRect(0,
+                                 NSMaxY([windowView bounds]) -
+                                     60.0,
+                                 NSWidth([windowView bounds]),
+                                 60.0)]);
+    [titleBarBackgroundView_
+        setAutoresizingMask:NSViewWidthSizable | NSViewMinYMargin];
+    [windowView addSubview:titleBarBackgroundView_
+                            positioned:NSWindowBelow
+                            relativeTo:nil];
+  }
+
+  [titleBarBackgroundView_ setColor:color
+                      inactiveColor:inactiveColor];
+}
+
+@end
+
 @interface ShellFramelessNSWindow : ShellNSWindow
 @end
 
 @implementation ShellFramelessNSWindow
 
-- (void)drawCustomFrameRect:(NSRect)rect forView:(NSView*)view {}
-
 + (NSRect)frameRectForContentRect:(NSRect)contentRect
                         styleMask:(NSUInteger)mask {
   return contentRect;
 }
 
 + (NSRect)contentRectForFrameRect:(NSRect)frameRect
                         styleMask:(NSUInteger)mask {
   return frameRect;
 }
 
@@ skipping 36 matching lines @@
       is_fullscreen_(false),
       is_resizable_(params.resizable),
       shows_resize_controls_(true),
       shows_fullscreen_controls_(true),
       has_frame_color_(params.has_frame_color),
       active_frame_color_(params.active_frame_color),
       inactive_frame_color_(params.inactive_frame_color) {
   Observe(WebContents());
 
   base::scoped_nsobject<NSWindow> window;
-  Class window_class;
-  if (has_frame_) {
-    window_class = has_frame_color_ ?
-        [ShellCustomFrameNSWindow class] : [ShellNSWindow class];
-  } else {
-    window_class = [ShellFramelessNSWindow class];
-  }
+  Class window_class = has_frame_ ?
+      [ShellNSWindow class] : [ShellFramelessNSWindow class];
 
   // Estimate the initial bounds of the window. Once the frame insets are known,
   // the window bounds and constraints can be set precisely.
   NSRect cocoa_bounds = GfxToCocoaBounds(
       params.GetInitialWindowBounds(gfx::Insets()));
   window.reset([[window_class alloc]
       initWithContentRect:cocoa_bounds
                 styleMask:GetWindowStyleMask()
                   backing:NSBackingStoreBuffered
                     defer:NO]);
 
   std::string name;
   const extensions::Extension* extension = app_window_->GetExtension();
   if (extension)
     name = extension->name();
   [window setTitle:base::SysUTF8ToNSString(name)];
   [[window contentView] setWantsLayer:YES];
   if (has_frame_ && has_frame_color_) {
-    [base::mac::ObjCCastStrict<ShellCustomFrameNSWindow>(window)
+    [base::mac::ObjCCastStrict<ShellNSWindow>(window)
              setColor:gfx::SkColorToSRGBNSColor(active_frame_color_)
         inactiveColor:gfx::SkColorToSRGBNSColor(inactive_frame_color_)];
   }
 
   if (base::mac::IsOSSnowLeopard() &&
       [window respondsToSelector:@selector(setBottomCornerRounded:)])
     [window setBottomCornerRounded:NO];
 
   if (params.always_on_top)
     [window setLevel:AlwaysOnTopWindowLevel()];
@@ skipping 612 matching lines @@
 }
 
 void NativeAppWindowCocoa::UpdateRestoredBounds() {
   if (IsRestored(*this))
     restored_bounds_ = [window() frame];
 }
 
 void NativeAppWindowCocoa::HideWithoutMarkingHidden() {
   [window() orderOut:window_controller_];
 }