Add build targets for Opus tests.

third_party/opus/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/arm.gni")
 import("//build/config/mips.gni")
 
 # If fixed point implementation shall be used (otherwise float).
 # TODO(wtc): change "mipselx" to "mipsel" in this file when the compilation
 # errors in the MIPS optimizations are fixed.
 use_opus_fixed_point =
     cpu_arch == "arm" || cpu_arch == "arm64" || cpu_arch == "mipselx"
 
 # If ARM optimizations shall be used to accelerate performance.
 use_opus_arm_optimization = cpu_arch == "arm"
 
 # If MIPS optimizations shall be used to accelerate performance.
 use_opus_mips_optimization = cpu_arch == "mipselx"
 
 # If OPUS Run Time CPU Detections (RTCD) shall be used.
 # Based on the conditions in celt/arm/armcpu.c:
 # defined(_MSC_VER) || defined(__linux__).
 use_opus_rtcd = cpu_arch == "arm" && (is_win || is_android || is_linux)
 
 config("opus_config") {
   include_dirs = [ "src/include" ]
 }
 
+config("opus_test_config") {
+  include_dirs = [
+    "src/celt",
+    "src/silk",
+  ]
+
+  if (is_win) {
+    defines = [ "inline=__inline" ]
+  }
+  if (is_android) {
+    libs = [ "log" ]
+  }
+  if (is_clang) {
+    cflags = [ "-Wno-absolute-value" ]
+  }
+}
+
 if (use_opus_rtcd) {
   action("convert_rtcd_assembler") {
     script = "convert_rtcd_assembler.py"
     outputs = [
       "$target_gen_dir/celt_pitch_xcorr_arm_gnu.S",
     ]
     args = [
       rebase_path("//third_party/opus/src/celt/arm/arm2gnu.pl", root_build_dir),
       rebase_path("//third_party/opus/src/celt/arm/celt_pitch_xcorr_arm.s",
                   root_build_dir),
@@ skipping 127 matching lines @@
     ]
   }
 }
 
 executable("opus_compare") {
   sources = [
     "src/src/opus_compare.c",
   ]
 
   configs -= [ "//build/config/compiler:chromium_code" ]
-  configs += [ "//build/config/compiler:no_chromium_code" ]
-
-  include_dirs = [
-    "src/celt",
-    "src/silk",
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    ":opus_test_config",
   ]
 
-  if (is_win) {
-    defines = [ "inline=__inline" ]
-  }
-  if (is_android) {
-    libs = [ "log" ]
-  }
-  if (is_clang) {
-    cflags = [ "-Wno-absolute-value" ]
-  }
-
   deps = [
     ":opus",
   ]
 }
 
 executable("opus_demo") {
   sources = [
     "src/src/opus_demo.c",
   ]
 
   configs -= [ "//build/config/compiler:chromium_code" ]
-  configs += [ "//build/config/compiler:no_chromium_code" ]
-
-  include_dirs = [
-    "src/celt",
-    "src/silk",
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    ":opus_test_config",
   ]
 
-  if (is_win) {
-    defines = [ "inline=__inline" ]
-  }
-  if (is_android) {
-    libs = [ "log" ]
-  }
-  if (is_clang) {
-    cflags = [ "-Wno-absolute-value" ]
-  }
-
   deps = [
     ":opus",
+  ]
+}
+
+executable("test_opus_api") {

[brettw, 2015/01/29 20:25:30]

Can you do "test" instead of "executable"? You will have to add
  import("//testing/test.gni")
to the top of this file. This will set some testing-related defaults and make it
work on Android.

[wtc, 2015/01/29 21:11:33]

Done. I have two questions.

1. I didn't make this change to the opus_compare and opus_demo targets because
they are more like utility programs. Is that OK?

2. These Opus test programs don't use gtest. Using "test" won't make them depend
on gtest, right?

[brettw, 2015/01/30 19:02:30]

Right.

+  sources = [
+    "src/tests/test_opus_api.c",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    ":opus_test_config",
+  ]
+
+  deps = [
+    ":opus",
+  ]
+}
+
+executable("test_opus_encode") {
+  sources = [
+    "src/tests/test_opus_encode.c",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    ":opus_test_config",
+  ]
+
+  deps = [
+    ":opus",
+  ]
+}
+
+executable("test_opus_decode") {
+  sources = [
+    "src/tests/test_opus_decode.c",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    ":opus_test_config",
+  ]
+
+  deps = [
+    ":opus",
+  ]
+}
+
+executable("test_opus_padding") {
+  sources = [
+    "src/tests/test_opus_padding.c",
+  ]
+
+  configs -= [ "//build/config/compiler:chromium_code" ]
+  configs += [
+    "//build/config/compiler:no_chromium_code",
+    ":opus_test_config",
+  ]
+
+  deps = [
+    ":opus",
   ]
 }