Use target_cpu instead of cpu_arch in BUILD.gn

BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
+import("//build/config/android/config.gni")
+import("//build/config/arm.gni")
+import("//build/config/mips.gni")
+
 # Because standalone V8 builds are not supported, assume this is part of a
 # Chromium build.
 import("//build/module_args/v8.gni")
 
 # TODO(jochen): These will need to be user-settable to support standalone V8
 # builds.
 v8_deprecation_warnings = false
 v8_enable_disassembler = false
 v8_enable_gdbjit = false
 v8_enable_handle_zapping = true
 v8_enable_i18n_support = true
 v8_enable_verify_heap = false
 v8_interpreted_regexp = false
 v8_object_print = false
 v8_postmortem_support = false
 v8_use_snapshot = true
-
-# TODO(GYP): We should be just target_cpu and not need v8_target_arch.
-v8_target_arch = current_cpu
-
+v8_target_arch = target_cpu
 v8_random_seed = "314159265"
 v8_toolset_for_d8 = "host"
 
 # The snapshot needs to be compiled for the host, but compiled with
 # a toolchain that matches the bit-width of the target.
 #
-# TODO(GYP): For now we only support 32-bit little-endian target builds from
-# an x86/x64 Linux host. Eventually we need to support all of the
-# host/target configurations v8 runs on.
-if (target_os == "android" || target_os == "chromeos") {
-  assert(host_os == "linux" &&
-         (host_cpu == "x86" || host_cpu == "x64") &&
-         (target_cpu == "arm" || target_cpu == "mipsel" || target_cpu == "x86"))
+# TODO(GYP): For now we only support 32-bit little-endian target builds from an
+# x64 Linux host. Eventually we need to support all of the host/target
+# configurations v8 runs on.
+if (host_cpu == "x64" &&
+    (target_cpu == "arm" || target_cpu == "mipsel" || target_cpu == "x86")) {
+  assert(host_os == "linux")

[Dirk Pranke, 2015/03/12 17:53:03]

This is definitely simpler and an improvement.

   snapshot_toolchain = "//build/toolchain/linux:clang_x86"
 } else {
   snapshot_toolchain = default_toolchain
 }
 
 ###############################################################################
 # Configurations
 #
 config("internal_config") {
   visibility = [ ":*" ]  # Only targets in this file can depend on this.
@@ skipping 63 matching lines @@
 config("toolchain") {
   visibility = [ ":*" ]  # Only targets in this file can depend on this.
 
   defines = []
   cflags = []
 
   # TODO(jochen): Add support for arm subarchs, mips, mipsel.
 
   if (v8_target_arch == "arm") {
     defines += [ "V8_TARGET_ARCH_ARM" ]
-    if (arm_version == 7) {
-      defines += [ "CAN_USE_ARMV7_INSTRUCTIONS" ]
-    }
-    if (arm_fpu == "vfpv3-d16") {
-      defines += [ "CAN_USE_VFP3_INSTRUCTIONS" ]
-    }
-    if (arm_fpu == "vfpv3") {
+    if (current_cpu == "arm") {
+      if (arm_version == 7) {
+        defines += [ "CAN_USE_ARMV7_INSTRUCTIONS" ]
+      }
+      if (arm_fpu == "vfpv3-d16") {
+        defines += [ "CAN_USE_VFP3_INSTRUCTIONS" ]
+      }
+      if (arm_fpu == "vfpv3") {

[Dirk Pranke, 2015/03/12 17:53:03]

nit: I'd probably write lines 128 and 134 as 'else if' to make it a little more
obvious that these choices are mutually exclusive (though it's obviously not
actually necessary), and put a blank line between lines 124 and 125 to make it
clearer that these are two different sets of conditionals.

+        defines += [
+          "CAN_USE_VFP3_INSTRUCTIONS",
+          "CAN_USE_VFP32DREGS",
+        ]
+      }
+      if (arm_fpu == "neon") {
+        defines += [
+          "CAN_USE_VFP3_INSTRUCTIONS",
+          "CAN_USE_VFP32DREGS",
+          "CAN_USE_NEON",
+        ]
+      }
+    } else {
       defines += [

[Dirk Pranke, 2015/03/12 17:53:03]

We only get into this branch when building mksnapshot (and its deps) in the host
toolchain, right?

It might be helpful to put a comment to that effect in here, something like:

# these defines are used in the ARM snapshot_toolchain.

+        "CAN_USE_ARMV7_INSTRUCTIONS",
         "CAN_USE_VFP3_INSTRUCTIONS",
         "CAN_USE_VFP32DREGS",
-      ]
-    }
-    if (arm_fpu == "neon") {
-      defines += [
-        "CAN_USE_VFP3_INSTRUCTIONS",
-        "CAN_USE_VFP32DREGS",
-        "CAN_USE_NEON",
+        "USE_EABI_HARDFLOAT=0",
       ]
     }
 
     # TODO(jochen): Add support for arm_test_noprobe.
-
-    # TODO(jochen): Add support for cpu_arch != v8_target_arch/
   }
   if (v8_target_arch == "arm64") {
     defines += [ "V8_TARGET_ARCH_ARM64" ]
   }
   if (v8_target_arch == "x86") {
     defines += [ "V8_TARGET_ARCH_IA32" ]
   }
   if (v8_target_arch == "x64") {
     defines += [ "V8_TARGET_ARCH_X64" ]
   }
@@ skipping 1421 matching lines @@
       sources += [
         "src/d8-debug.cc",
         "$target_gen_dir/d8-js.cc",
       ]
     }
     if (v8_enable_i18n_support) {
       deps += [ "//third_party/icu" ]
     }
   }
 }