Added 'Find'/'Paste and Match Style' menu items for hosted apps on Mac.

chrome/browser/ui/cocoa/apps/app_shim_menu_controller_mac_browsertest.mm

 // Copyright 2013 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/apps/app_shim_menu_controller_mac.h"
 
 #import <Cocoa/Cocoa.h>
 
 #include "base/command_line.h"
 #include "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
+#include "chrome/app/chrome_command_ids.h"
 #include "chrome/browser/apps/app_browsertest_util.h"
+#include "chrome/browser/apps/app_shim/extension_app_shim_handler_mac.h"
 #include "chrome/browser/extensions/extension_service.h"
+#include "chrome/browser/extensions/launch_util.h"
 #include "chrome/browser/profiles/profile.h"
 #include "chrome/browser/ui/browser_iterator.h"
 #include "chrome/browser/ui/browser_window.h"
 #include "chrome/common/chrome_switches.h"
 #include "extensions/browser/app_window/app_window_registry.h"
 #include "extensions/browser/app_window/native_app_window.h"
 #include "extensions/browser/uninstall_reason.h"
 #include "extensions/common/extension.h"
 #include "extensions/test/extension_test_message_listener.h"
 
 namespace {
 
 class AppShimMenuControllerBrowserTest
     : public extensions::PlatformAppBrowserTest {
  protected:
   AppShimMenuControllerBrowserTest()
       : app_1_(NULL),
         app_2_(NULL),
+        hosted_app_(NULL),

[tapted, 2015/01/30 00:52:48]

nit: NULL -> nullptr. You can change those nearby too.

[mitchellj, 2015/01/30 02:53:38]

Done.

         initial_menu_item_count_(0) {}
 
   void SetUpCommandLine(base::CommandLine* command_line) override {
     PlatformAppBrowserTest::SetUpCommandLine(command_line);
   }
 
   // Start two apps and wait for them to be launched.
   void SetUpApps() {
     ExtensionTestMessageListener listener_1("Launched", false);
     app_1_ = InstallAndLaunchPlatformApp("minimal_id");
     ASSERT_TRUE(listener_1.WaitUntilSatisfied());
     ExtensionTestMessageListener listener_2("Launched", false);
     app_2_ = InstallAndLaunchPlatformApp("minimal");
     ASSERT_TRUE(listener_2.WaitUntilSatisfied());
+    hosted_app_ = InstallHostedApp();
+
+    // Explicitly set the launch type to open in a new window.
+    extensions::SetLaunchType(
+        extensions::ExtensionSystem::Get(profile())->extension_service(),
+        hosted_app_->id(), extensions::LAUNCH_TYPE_WINDOW);
+    LaunchHostedApp(hosted_app_);
 
     initial_menu_item_count_ = [[[NSApp mainMenu] itemArray] count];
   }
 
   void CheckHasAppMenus(const extensions::Extension* app) const {
     const int kExtraTopLevelItems = 4;
     NSArray* item_array = [[NSApp mainMenu] itemArray];
     EXPECT_EQ(initial_menu_item_count_ + kExtraTopLevelItems,
               [item_array count]);
     for (NSUInteger i = 0; i < initial_menu_item_count_; ++i)
@@ skipping 11 matching lines @@
     }
   }
 
   void CheckNoAppMenus() const {
     NSArray* item_array = [[NSApp mainMenu] itemArray];
     EXPECT_EQ(initial_menu_item_count_, [item_array count]);
     for (NSUInteger i = 0; i < initial_menu_item_count_; ++i)
       EXPECT_FALSE([[item_array objectAtIndex:i] isHidden]);
   }
 
+  void CheckEditMenu(const extensions::Extension* app) const {
+    const int kEditMenuIndex = initial_menu_item_count_ + 2;

[tapted, 2015/01/30 00:52:49]

nit: for function-local consts, we're meant to use hacker_style (i.e. as if it
were not const)

[mitchellj, 2015/01/30 02:53:39]

Done.

+
+    NSMenuItem* editMenu =

[tapted, 2015/01/30 00:52:48]

editMenu -> edit_menu, more below

(camelCase only between @interface/@implementation Foo -> @end)

[mitchellj, 2015/01/30 02:53:39]

Done.

+        [[[NSApp mainMenu] itemArray] objectAtIndex:kEditMenuIndex];
+    NSMenu* editSubmenu = [editMenu submenu];
+    NSMenuItem* pasteAndMatchStyleMenuItem =
+        [editSubmenu itemWithTag:IDC_CONTENT_CONTEXT_PASTE_AND_MATCH_STYLE];
+    NSMenuItem* findMenuItem = [editSubmenu itemWithTag:IDC_FIND_MENU];
+    if (app->is_hosted_app()) {
+      EXPECT_FALSE([pasteAndMatchStyleMenuItem isHidden]);
+      EXPECT_FALSE([findMenuItem isHidden]);
+    } else {
+      EXPECT_TRUE([pasteAndMatchStyleMenuItem isHidden]);
+      EXPECT_TRUE([findMenuItem isHidden]);
+    }
+  }
+
   const extensions::Extension* app_1_;
   const extensions::Extension* app_2_;
+  const extensions::Extension* hosted_app_;
   NSUInteger initial_menu_item_count_;
 
  private:
   DISALLOW_COPY_AND_ASSIGN(AppShimMenuControllerBrowserTest);
 };
 
 // Test that focusing an app window changes the menu bar.
 IN_PROC_BROWSER_TEST_F(AppShimMenuControllerBrowserTest,
                        PlatformAppFocusUpdatesMenuBar) {
   SetUpApps();
@@ skipping 27 matching lines @@
   // When an app window is closed and there are no other app windows, the menu
   // items for the app should be removed.
   app_1_app_window->GetBaseWindow()->Close();
   chrome_window->Close();
   [[NSNotificationCenter defaultCenter]
       postNotificationName:NSWindowWillCloseNotification
                     object:app_2_app_window->GetNativeWindow()];
   CheckNoAppMenus();
 }
 
+// Test to check that hosted apps have "Find" and "Paste and Match Style" menu
+// items under the "Edit" menu.
+IN_PROC_BROWSER_TEST_F(AppShimMenuControllerBrowserTest,
+                       HostedAppHasAdditionalEditMenuItems) {
+  SetUpApps();
+
+  // Find the first hosted app window.
+  Browser* browser;

[tapted, 2015/01/30 00:52:48]

 = nullptr; And perhaps a better name, like hosted_app_browser (it's weird to
call a hosted app `browser` even though it's a Browser*)

[mitchellj, 2015/01/30 02:53:38]

Done.

+  BrowserList* browsers =
+      BrowserList::GetInstance(chrome::HOST_DESKTOP_TYPE_NATIVE);
+  for (Browser* b : *browsers) {

[tapted, 2015/01/30 00:52:48]

`b` isn't really a common abbreviation. Maybe

for (Browser* browser: *browser_list) {

[mitchellj, 2015/01/30 02:53:38]

Done.

+    const extensions::Extension* extension =
+        apps::ExtensionAppShimHandler::GetAppForBrowser(b);
+    if (extension && extension->is_hosted_app()) {
+      browser = b;
+      break;
+    }
+  }
+  EXPECT_TRUE(browser);
+
+  // Focus the hosted app.
+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:NSWindowDidBecomeMainNotification
+                    object:browser->window()->GetNativeWindow()];
+  CheckEditMenu(hosted_app_);
+
+  // Now focus a platform app, the Edit menu should not have the additional
+  // options.
+  extensions::AppWindow* app_1_app_window =
+      extensions::AppWindowRegistry::Get(profile())
+          ->GetAppWindowsForApp(app_1_->id()).front();

[tapted, 2015/01/30 00:52:48]

Calling .front() is a bit spooky... and this is repeated in the other tests. Can
you make helper function in AppShimMenuControllerBrowserTest like

NSWindow* FirstWindowForApp(Extension* app) {
  AppWindowRegistry::AppWindowList window_list =
      extensions::AppWindowRegistry::Get(profile())
          ->GetAppWindowsForApp(app->id())
  EXPECT_FALSE(window_list.empty());
  return window_list.front();
}

then refactor PlatformAppFocusUpdatesMenuBar to use it as well

[mitchellj, 2015/01/30 02:53:39]

Done.

+  [[NSNotificationCenter defaultCenter]
+      postNotificationName:NSWindowDidBecomeMainNotification
+                    object:app_1_app_window->GetNativeWindow()];
+  CheckEditMenu(app_1_);
+}
+
 IN_PROC_BROWSER_TEST_F(AppShimMenuControllerBrowserTest,
                        ExtensionUninstallUpdatesMenuBar) {
   SetUpApps();
 
   // This essentially tests that a NSWindowWillCloseNotification gets fired when
   // an app is uninstalled. We need to close the other windows first since the
   // menu only changes on a NSWindowWillCloseNotification if there are no other
   // windows.
   extensions::AppWindow* app_2_app_window =
       extensions::AppWindowRegistry::Get(profile())
@@ skipping 11 matching lines @@
 
   CheckHasAppMenus(app_1_);
   ExtensionService::UninstallExtensionHelper(
       extension_service(),
       app_1_->id(),
       extensions::UNINSTALL_REASON_FOR_TESTING);
   CheckNoAppMenus();
 }
 
 }  // namespace