Upstream //ios/chrome/browser/snapshots

base/test/ios/wait_util.mm

+// Copyright 2014 The Chromium Authors. All rights reserved.

[Paweł Hajdan Jr., 2015/01/30 12:24:29]

nit: 2015

+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "base/test/ios/wait_util.h"
+
+#include "base/logging.h"
+#include "base/mac/scoped_nsobject.h"
+#include "base/message_loop/message_loop.h"
+
+namespace {
+// Constants for UI wait loop and timing calculation.
+const NSTimeInterval kSpinDelaySeconds = 0.01;
+const NSTimeInterval kDefaultDelaySeconds = 10.0;
+}  // namespace
+
+namespace base {
+
+TimeDelta TimeUntilCondition(ProceduralBlock action,
+                             ConditionBlock condition,
+                             MessageLoop* message_loop,
+                             TimeDelta timeout) {
+  NSDate* startTime = [NSDate date];
+  if (action)
+    action();
+  const NSTimeInterval timeout_in_seconds = timeout.InSecondsF();
+  while ((-[startTime timeIntervalSinceNow]) < timeout_in_seconds &&

[Paweł Hajdan Jr., 2015/01/30 12:24:29]

I strongly second Nico's comment about waiting properly for events.

Could you explain why this code was written in this way (as opposed to waiting
for an event)?

+         (!condition || !condition())) {
+    SpinRunLoopWithMaxDelay(TimeDelta::FromSecondsD(kSpinDelaySeconds));
+    if (message_loop) {
+      message_loop->RunUntilIdle();
+    }
+  }
+  NSTimeInterval elapsed = -[startTime timeIntervalSinceNow];
+  // If DCHECK is ever hit, check if |action| is doing something that is
+  // taking an unreasonably long time, or if |condition| does not come
+  // true quickly enough. Increase |timeout| only if necessary.
+  DCHECK(!condition || condition());
+  return TimeDelta::FromSecondsD(elapsed);
+}
+
+TimeDelta TimeUntilCondition(ProceduralBlock action, ConditionBlock condition) {
+  return TimeUntilCondition(action, condition, nullptr,
+                            TimeDelta::FromSecondsD(kDefaultDelaySeconds));
+}
+
+void WaitUntilCondition(ConditionBlock condition,
+                        MessageLoop* message_loop,
+                        TimeDelta timeout) {
+  TimeUntilCondition(nil, condition, message_loop, timeout);
+}
+
+void WaitUntilCondition(ConditionBlock condition, MessageLoop* message_loop) {
+  WaitUntilCondition(condition, message_loop,
+                     TimeDelta::FromSecondsD(kDefaultDelaySeconds));
+}
+
+void WaitUntilCondition(ConditionBlock condition) {
+  WaitUntilCondition(condition, nullptr);
+}
+
+void Wait(TimeDelta timeout) {
+  return WaitUntilCondition(nil, nullptr, timeout);
+}
+
+void SpinRunLoopWithMaxDelay(TimeDelta max_delay) {
+  scoped_nsobject<NSDate> beforeDate(
+      [[NSDate alloc] initWithTimeIntervalSinceNow:max_delay.InSecondsF()]);
+  [[NSRunLoop currentRunLoop] runMode:NSDefaultRunLoopMode
+                           beforeDate:beforeDate];
+}
+
+}  // namespace base