Add GN files for chrome_elf

chrome_elf/BUILD.gn

Index: chrome_elf/BUILD.gn
diff --git a/chrome_elf/BUILD.gn b/chrome_elf/BUILD.gn
new file mode 100644
index 0000000000000000000000000000000000000000..87f4fc376481200838ee54894bcf3fa68068f99f
--- /dev/null
+++ b/chrome_elf/BUILD.gn
@@ -0,0 +1,211 @@
+# Copyright 2015 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+import("//chrome/version.gni")
+
+process_version("chrome_elf_resources") {
+  source = "//chrome/app/chrome_version.rc.version"
+  output = "$target_gen_dir/chrome_elf_version.rc"
+  extra_args = [
+    "-f",
+    rebase_path("chrome_elf.ver"),
+  ]
+}
+
+shared_library("chrome_elf") {
+  sources = [
+    "chrome_elf_main.cc",
+    "chrome_elf_main.h",
+    "$target_gen_dir/chrome_elf_version.rc",
+  ]
+  deps = [
+    ":blacklist",
+    ":chrome_elf_breakpad",
+    ":chrome_elf_lib",
+    ":chrome_elf_resources",
+  ]
+  configs += [ "//build/config/win:windowed" ]
+  ldflags = [
+    "/NODEFAULTLIB:user32.lib",
+    "/DEF:" + rebase_path("chrome_elf.def"),
+  ]
+  if (cpu_arch == "x86") {
+    # Don"t set an x64 base address (to avoid breaking HE-ASLR).
+    ldflags += [ "/BASE:0x01c20000" ]
+  }
+}
+
+source_set("chrome_elf_lib") {
+  sources = [
+    "create_file/chrome_create_file.cc",
+    "create_file/chrome_create_file.h",
+    "ntdll_cache.cc",
+    "ntdll_cache.h",
+  ]
+  deps = [
+    ":chrome_elf_common",
+    "//base:base_static",
+    "//sandbox",
+  ]
+}
+
+source_set("chrome_elf_constants") {
+  sources = [
+    "chrome_elf_constants.cc",
+    "chrome_elf_constants.h",
+  ]
+}
+
+source_set("chrome_elf_common") {
+  deps = [
+    ":chrome_elf_constants",
+  ]
+  sources = [
+    "chrome_elf_types.h",
+    "chrome_elf_util.cc",
+    "chrome_elf_util.h",
+    "thunk_getter.cc",
+    "thunk_getter.h",
+  ]
+}
+
+source_set("chrome_elf_breakpad") {
+  include_dirs = [ "$target_gen_dir" ]
+  sources = [
+    "breakpad.cc",
+    "breakpad.h",
+  ]
+  deps = [
+    ":chrome_elf_common",
+    "//breakpad:breakpad_handler",
+    "//chrome:version_header",
+  ]
+}
+
+if (is_component_build) {
+  shared_library("chrome_redirects") {
+    sources = [
+      "chrome_redirects_main.cc",
+    ]
+    deps = [
+      ":chrome_elf_lib",
+    ]
+    configs += [ "//build/config/win:windowed" ]
+    ldflags = [ "/DEF:" + rebase_path("chrome_redirects.def") ]
+
+    if (cpu_arch == "x86") {
+      # Don't set an x64 base address (to avoid breaking HE-ASLR).
+      ldflags += [ "/BASE:0x01c20000" ]
+    }
+  }
+}
+
+source_set("dll_hash") {
+  deps = [
+    "//base",
+  ]
+  sources = [
+    "dll_hash/dll_hash.cc",
+    "dll_hash/dll_hash.h",
+  ]
+}
+
+executable("dll_hash_main") {
+  deps = [
+    ":dll_hash",
+  ]
+  sources = [
+    "dll_hash/dll_hash_main.cc",
+  ]
+}
+
+static_library("blacklist") {
+  sources = [
+    "blacklist/blacklist.cc",
+    "blacklist/blacklist.h",
+    "blacklist/blacklist_interceptions.cc",
+    "blacklist/blacklist_interceptions.h",
+  ]
+  deps = [
+    # Depend on base_static, but do NOT take a dependency on base.gyp:base
+    # as that would risk pulling in base's link-time dependencies which
+    # chrome_elf cannot do.
+    "//base:base_static",
+    ":chrome_elf_breakpad",
+    ":chrome_elf_constants",
+    "//sandbox:sandbox",
+  ]
+}
+
+test("chrome_elf_unittests_exe") {
+  output_name = "chrome_elf_unittests"
+  sources = [
+    "blacklist/test/blacklist_test.cc",
+    "chrome_elf_util_unittest.cc",
+    "create_file/chrome_create_file_unittest.cc",
+    "elf_imports_unittest.cc",
+    "ntdll_cache_unittest.cc",
+  ]
+  include_dirs = [ "$target_gen_dir" ]
+  deps = [
+    ":chrome_elf_lib",
+    "//base",
+    "//base/test:run_all_unittests",
+    "//base/test:test_support",
+    "//sandbox",
+    "//testing/gtest",
+    ":blacklist",
+    ":blacklist_test_main_dll",
+  ]
+  data_deps = [
+    ":blacklist_test_dll_1",
+    ":blacklist_test_dll_2",
+    ":blacklist_test_dll_3",
+  ]
+}
+
+group("chrome_elf_unittests") {
+  testonly = true
+
+  # A dummy target to ensure that chrome_elf.dll and chrome.exe gets built
+  # when building chrome_elf_unittests.exe without introducing an
+  # explicit runtime dependency.
+  deps = [
+    "//chrome",
+    ":chrome_elf",
+    ":chrome_elf_unittests_exe",
+  ]
+}
+
+shared_library("blacklist_test_main_dll") {
+  sources = [
+    "blacklist/test/blacklist_test_main_dll.cc",
+  ]
+  deps = [
+    "//base",
+    ":blacklist",
+  ]
+  ldflags =
+      [ "/DEF:" + rebase_path("blacklist/test/blacklist_test_main_dll.def") ]
+}
+
+shared_library("blacklist_test_dll_1") {

[Slava Chigrin, 2015/01/18 21:27:06]

Not sure, whether this is correct equivalent for GYP loadable_module. Could
anybody help, what difference between loadable_module and shared_library in GYP?
I search GYP documentation but did not found mentions of loadable_module....

Thank you in advance!

[robertshield, 2015/01/19 01:24:17]

Ack, there was a difference between shared_library and loadable_module,
hopefully this is expressable in gn. I *believe* that a loadable_module target
means generate a dll without an import lib and also modifies gyp's dependency
calculation (my memory here is fuzzy).

This was important to some of the blacklist tests iirc.

[Slava Chigrin, 2015/01/19 12:41:22]

Ah, understand, hope, placing blacklist_test_dll_1 in data_deps rather then in
deps solves this problem. At least all unit tests of chrome_elf passes.

+  sources = [
+    "blacklist/test/blacklist_test_dll_1.cc",
+  ]
+  ldflags = [ "/DEF:" + rebase_path("blacklist/test/blacklist_test_dll_1.def") ]
+}
+
+shared_library("blacklist_test_dll_2") {
+  sources = [
+    "blacklist/test/blacklist_test_dll_2.cc",
+  ]
+  ldflags = [ "/DEF:" + rebase_path("blacklist/test/blacklist_test_dll_2.def") ]
+}
+
+shared_library("blacklist_test_dll_3") {
+  sources = [
+    "blacklist/test/blacklist_test_dll_3.cc",
+  ]
+}