[mojo] Make HTML viewer load the blink resources from the generated pak file.

mojo/services/html_viewer/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//mojo/public/mojo.gni")
 import("//mojo/public/mojo_application.gni")
 
+copy("copy_blink_resources") {

[jamesr, 2015/01/09 19:11:49]

why do you need this copy?

+  sources = [
+    "$root_out_dir/gen/blink/public/resources/blink_resources.pak",
+  ]
+  outputs = [
+    "$root_out_dir/blink_resources.pak",
+  ]
+  public_deps = [
+    "//third_party/WebKit/public:resources",
+  ]
+}
+
+action("generate_blink_resource_map") {
+  script = "//mojo/services/html_viewer/generate_blink_resource_map.py"
+  args = [
+    "--pak-file",
+    rebase_path("$root_out_dir/blink_resources.pak"),

[jamesr, 2015/01/09 19:11:49]

can't you just point this at the existing blink_resources.pak instead of another
copy?

+    "--header",
+    rebase_path("$target_gen_dir/blink_resource_map.h"),
+    "--cpp",
+    rebase_path("$target_gen_dir/blink_resource_map.cc"),
+  ]
+  outputs = [
+    "$target_gen_dir/blink_resource_map.cc",
+    "$target_gen_dir/blink_resource_map.h",
+  ]
+  public_deps = [
+    ":copy_blink_resources",
+  ]
+}
+
 source_set("lib") {
   sources = [
+    "$target_gen_dir/blink_resource_map.cc",
+    "$target_gen_dir/blink_resource_map.h",
     "ax_provider_impl.cc",
     "ax_provider_impl.h",
     "blink_basic_type_converters.cc",
     "blink_basic_type_converters.h",
     "blink_input_events_type_converters.cc",
     "blink_input_events_type_converters.h",
     "blink_platform_impl.cc",
     "blink_platform_impl.h",
     "blink_url_request_type_converters.cc",
     "blink_url_request_type_converters.h",
@@ skipping 54 matching lines @@
     "//mojo/services/surfaces/public/interfaces",
     "//net",
     "//skia",
     "//ui/native_theme",
     "//url",
   ]
 
   public_deps = [
     "//mojo/public/cpp/bindings",
     "//third_party/WebKit/public:blink",
+    ":generate_blink_resource_map",
   ]
 }
 
 mojo_native_application("html_viewer") {
   sources = [
     "html_viewer.cc",
   ]
   deps = [
     ":lib",
   ]
 }
 
 test("tests") {
   output_name = "html_viewer_unittests"
   sources = [
     "ax_provider_impl_unittest.cc",
   ]
   deps = [
     ":lib",
     "//base/test:run_all_unittests",
   ]
 }