MacViews: Intercept events for Menus (after AppKit has interpreted keystrokes)

ui/views/cocoa/bridged_content_view.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "ui/views/cocoa/bridged_content_view.h"
 
 #include "base/logging.h"
 #import "base/mac/scoped_nsobject.h"
 #include "base/strings/sys_string_conversions.h"
 #include "ui/base/ime/text_input_client.h"
+#import "ui/events/cocoa/cocoa_event_utils.h"
+#include "ui/events/keycodes/dom3/dom_code.h"
+#import "ui/events/keycodes/keyboard_code_conversion_mac.h"
 #include "ui/gfx/canvas_paint_mac.h"
 #include "ui/gfx/geometry/rect.h"
 #include "ui/strings/grit/ui_strings.h"
+#include "ui/views/controls/menu/menu_controller.h"
 #include "ui/views/view.h"
 #include "ui/views/widget/widget.h"
 
+using views::MenuController;
+
 namespace {
 
 // Convert a |point| in |source_window|'s AppKit coordinate system (origin at
 // the bottom left of the window) to |target_window|'s content rect, with the
 // origin at the top left of the content area.
 // If |source_window| is nil, |point| will be treated as screen coordinates.
 gfx::Point MovePointToWindow(const NSPoint& point,
                              NSWindow* source_window,
                              NSWindow* target_window) {
   NSPoint point_in_screen = source_window
       ? [source_window convertBaseToScreen:point]
       : point;
 
   NSPoint point_in_window = [target_window convertScreenToBase:point_in_screen];
   NSRect content_rect =
       [target_window contentRectForFrameRect:[target_window frame]];
   return gfx::Point(point_in_window.x,
                     NSHeight(content_rect) - point_in_window.y);
 }
 
 }
 
 @interface BridgedContentView ()
 
 // Translates the location of |theEvent| to toolkit-views coordinates and passes
 // the event to NativeWidgetMac for handling.
 - (void)handleMouseEvent:(NSEvent*)theEvent;
 
+// Handles an NSResponder Action Message by mapping it to the keyCode that
+// toolkit-views expects internally. E.g. moveToBeginningOfLine: would pass
+// ui::VKEY_HOME even though the Home key on Mac defaults to
+// moveToBeginningOfDocument:. This approach also allows action messages a user
+// may have remapped in ~/Library/KeyBindings/DefaultKeyBinding.dict to be
+// catered for.
+- (void)handleActionAsKey:(ui::KeyboardCode)keyCode
+                  domCode:(ui::DomCode)domCode;
+
 // Execute a command on the currently focused TextInputClient.
 // |commandId| should be a resource ID from ui_strings.grd.
 - (void)doCommandByID:(int)commandId;
 
 @end
 
 @implementation BridgedContentView
 
 @synthesize hostedView = hostedView_;
 @synthesize textInputClient = textInputClient_;
@@ skipping 49 matching lines @@
 // BridgedContentView private implementation.
 
 - (void)handleMouseEvent:(NSEvent*)theEvent {
   if (!hostedView_)
     return;
 
   ui::MouseEvent event(theEvent);
   hostedView_->GetWidget()->OnMouseEvent(&event);
 }
 
+- (void)handleActionAsKey:(ui::KeyboardCode)keyCode
+                  domCode:(ui::DomCode)domCode {
+  if (!hostedView_)
+    return;
+
+  ui::KeyEvent event(ui::ET_KEY_PRESSED, keyCode, domCode,
+                     ui::EventFlagsFromModifiers([NSEvent modifierFlags]));
+
+  MenuController* menuController = MenuController::GetActiveInstance();
+  if (menuController &&
+      menuController->owner() == hostedView_->GetWidget() &&
+      menuController->OnWillDispatchEvent(event) == ui::POST_DISPATCH_NONE)
+    return;
+
+  hostedView_->GetWidget()->OnKeyEvent(&event);
+}
+
 - (void)doCommandByID:(int)commandId {
   if (textInputClient_ && textInputClient_->IsEditingCommandEnabled(commandId))
     textInputClient_->ExecuteEditingCommand(commandId);
 }
 
 // NSView implementation.
 
 - (BOOL)acceptsFirstResponder {
   return YES;
 }
@@ skipping 16 matching lines @@
   if (hostedView_->GetWidget()->GetLayer())
     return;
 
   gfx::CanvasSkiaPaint canvas(dirtyRect, false /* opaque */);
   hostedView_->GetWidget()->OnNativeWidgetPaint(&canvas);
 }
 
 // NSResponder implementation.
 
 - (void)keyDown:(NSEvent*)theEvent {
-  if (textInputClient_)
-    [self interpretKeyEvents:@[ theEvent ]];
-  else
-    [super keyDown:theEvent];
+  [self interpretKeyEvents:@[ theEvent ]];

[Andre, 2014/12/19 06:41:57]

How about when BridgedContentView is not first responder?
For example, in a browser window, RenderWidgetHostViewMac might be first
responder.
Does the key event get forwarded here?

[tapted, 2015/01/28 11:18:06]

So this was an excellent point :)

it crossed my mind, but I naively thought that it wouldn't matter. Thinking
went: ~"it won't come up since to show a drop-down menu in Views the
RenderWidgetHostViewMac wouldn't have focus anyway". But that's not the case. We
would still want the web content showing focus/firstResponder status, so can't
take it away.

I tried a *lot* of things and eventually got to something that seems to work
pretty nice with a combination of an override of -[NSWindow sendEvent] and an
override of -[NSView inputContext].

But then while adding tests it all got a bit unwieldy, so I've split this up
into 4 CLs:

http://crrev.com/856313003 Mac: Refine ui_controls_mac's SynthesizeKeyEvent()
[landed]
http://crrev.com/882053002 MacViews: Move some key-event utility functions out
of anon namespaces
http://crrev.com/879253002 MacViews: Convert Cocoa action messages into editing
comands for text fields
http://crrev.com/866983006 MacViews: Intercept events for Menus (after AppKit
has turned them into action messages).



the last one has the "interesting" stuff for the event interception (and
highlights the approach I eventually got to), but the textfields one should land
first since it's more mechanical - I'll send it out for your review now.

 }
 
 - (void)mouseDown:(NSEvent*)theEvent {
   [self handleMouseEvent:theEvent];
 }
 
 - (void)rightMouseDown:(NSEvent*)theEvent {
   [self handleMouseEvent:theEvent];
 }
 
@@ skipping 50 matching lines @@
 
 - (void)moveLeft:(id)sender {
   [self doCommandByID:IDS_MOVE_LEFT];
 }
 
 - (void)moveRight:(id)sender {
   [self doCommandByID:IDS_MOVE_RIGHT];
 }
 
 - (void)insertText:(id)text {
-  if (textInputClient_)
-    textInputClient_->InsertText(base::SysNSStringToUTF16(text));
+  [self insertText:text replacementRange:NSMakeRange(NSNotFound, 0)];
+}
+
+- (void)moveUp:(id)sender {
+  [self handleActionAsKey:ui::VKEY_UP domCode:ui::DomCode::ARROW_UP];
+}
+
+- (void)moveDown:(id)sender {
+  [self handleActionAsKey:ui::VKEY_DOWN domCode:ui::DomCode::ARROW_DOWN];
+}
+
+- (void)cancelOperation:(id)sender {
+  [self handleActionAsKey:ui::VKEY_ESCAPE domCode:ui::DomCode::ESCAPE];
 }
 
 // Support for Services in context menus.
 // Currently we only support reading and writing plain strings.
 - (id)validRequestorForSendType:(NSString*)sendType
                      returnType:(NSString*)returnType {
   BOOL canWrite = [sendType isEqualToString:NSStringPboardType] &&
                   [self selectedRange].length > 0;
   BOOL canRead = [returnType isEqualToString:NSStringPboardType];
   // Valid if (sendType, returnType) is either (string, nil), (nil, string),
@@ skipping 45 matching lines @@
   return [[[NSAttributedString alloc]
       initWithString:base::SysUTF16ToNSString(substring)] autorelease];
 }
 
 - (NSUInteger)characterIndexForPoint:(NSPoint)aPoint {
   NOTIMPLEMENTED();
   return 0;
 }
 
 - (void)doCommandBySelector:(SEL)selector {
-  if ([self respondsToSelector:selector])
+  if ([self respondsToSelector:selector]) {
     [self performSelector:selector withObject:nil];
-  else
+  } else {
+    NSLog(@"Unmatched selector: %@\n", NSStringFromSelector(selector));
     [[self nextResponder] doCommandBySelector:selector];
+  }
 }
 
 - (NSRect)firstRectForCharacterRange:(NSRange)range
                          actualRange:(NSRangePointer)actualRange {
   NOTIMPLEMENTED();
   return NSZeroRect;
 }
 
 - (BOOL)hasMarkedText {
   return textInputClient_ && textInputClient_->HasCompositionText();
 }
 
 - (void)insertText:(id)text replacementRange:(NSRange)replacementRange {
-  if (!textInputClient_)
+  if (!hostedView_)
     return;
 
   if ([text isKindOfClass:[NSAttributedString class]])
     text = [text string];
+
+  MenuController* menuController = MenuController::GetActiveInstance();
+  if (menuController && menuController->owner() == hostedView_->GetWidget()) {
+    DCHECK([text length] > 0);
+    ui::KeyEvent event(ui::ET_KEY_PRESSED,
+                       ui::KeyboardCodeFromCharCode([text characterAtIndex:0]),
+                       ui::DomCode::NONE,
+                       ui::EventFlagsFromModifiers([NSEvent modifierFlags]));
+    if (menuController->OnWillDispatchEvent(event) == ui::POST_DISPATCH_NONE)
+      return;
+  }
+
+  if (!textInputClient_)
+    return;
+
   textInputClient_->DeleteRange(gfx::Range(replacementRange));
   textInputClient_->InsertText(base::SysNSStringToUTF16(text));
 }
 
 - (NSRange)markedRange {
   if (!textInputClient_)
     return NSMakeRange(NSNotFound, 0);
 
   gfx::Range range;
   textInputClient_->GetCompositionTextRange(&range);
@@ skipping 40 matching lines @@
   }
 
   return [super accessibilityAttributeValue:attribute];
 }
 
 - (id)accessibilityHitTest:(NSPoint)point {
   return [hostedView_->GetNativeViewAccessible() accessibilityHitTest:point];
 }
 
 @end