Added bluetooth LE support on Mac platform

device/bluetooth/bluetooth_low_energy_discovery_manager_mac.mm

+// Copyright 2015 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "device/bluetooth/bluetooth_low_energy_discovery_manager_mac.h"
+
+#include "base/mac/mac_util.h"
+

[Avi (use Gerrit), 2015/01/29 05:25:03]

no blank space

[dvh, 2015/01/30 22:45:46]

Done.

+#include "device/bluetooth/bluetooth_low_energy_device_mac.h"
+
+using namespace device;

[Avi (use Gerrit), 2015/01/29 05:25:02]

this doesn't look necessary

[dvh, 2015/01/30 22:45:46]

It will let me refer BluetoothLowEnergyDiscoveryManagerMac with
BluetoothLowEnergyDiscoveryManagerMac instead of device::
BluetoothLowEnergyDiscoveryManagerMac.

[Avi (use Gerrit), 2015/01/30 23:18:31]

If you want to access the class without the device::, use a using-declaration,
like

using device::BluetoothLowEnergyDiscoveryManagerMac;

You are never allowed to use a using-directive, such as you do here. (That's
prohibited by the style guide, as mentioned earlier.)

+
+namespace device {
+
+// This class is a helper to call some protected methods in
+// BluetoothLowEnergyDiscoveryManagerMac.
+class BluetoothLowEnergyDiscoveryManagerMacDelegate {
+ public:
+  BluetoothLowEnergyDiscoveryManagerMacDelegate(
+      BluetoothLowEnergyDiscoveryManagerMac* manager)
+      : manager_(manager) {}
+
+  virtual ~BluetoothLowEnergyDiscoveryManagerMacDelegate() {}
+
+  virtual void DiscoveredPeripheral(CBPeripheral* peripheral,
+                                    NSDictionary* advertisementData,
+                                    int rssi) {
+    manager_->DiscoveredPeripheral(peripheral, advertisementData, rssi);
+  }
+
+  virtual void TryStartDiscovery() { manager_->TryStartDiscovery(); }
+
+ private:
+  BluetoothLowEnergyDiscoveryManagerMac* manager_;
+};
+
+}  // namespace device
+
+// This class will serve as the Objective-C delegate of CBCentralManager.
+@interface BluetoothLowEnergyDiscoveryManagerMacBridge
+    : NSObject<CBCentralManagerDelegate>
+
+- (id)initWithManager:(BluetoothLowEnergyDiscoveryManagerMac*)manager;
+
+@end
+
+@implementation BluetoothLowEnergyDiscoveryManagerMacBridge {
+  BluetoothLowEnergyDiscoveryManagerMac* manager_;
+  BluetoothLowEnergyDiscoveryManagerMacDelegate* delegate_;
+}
+
+- (id)initWithManager:(BluetoothLowEnergyDiscoveryManagerMac*)manager {
+  if ((self = [super init])) {
+    manager_ = manager;
+    delegate_ = new BluetoothLowEnergyDiscoveryManagerMacDelegate(manager_);
+  }
+  return self;
+}
+
+- (void)dealloc {
+  delete delegate_;

[Avi (use Gerrit), 2015/01/29 05:25:03]

nonono

Use a scoped_ptr for the ivar. _Never_ manually delete; if you need to manually
delete, you are doing things wrong.

[dvh, 2015/01/30 22:45:46]

Done.

+  [super dealloc];
+}
+
+- (void)centralManager:(CBCentralManager*)central
+    didDiscoverPeripheral:(CBPeripheral*)peripheral
+        advertisementData:(NSDictionary*)advertisementData
+                     RSSI:(NSNumber*)RSSI {
+  // Notifies the discovery of a device.
+  delegate_->DiscoveredPeripheral(peripheral, advertisementData,
+                                  [RSSI intValue]);
+}
+
+- (void)centralManagerDidUpdateState:(CBCentralManager*)central {
+  // Notifies when the powered state of the central manager changed.
+  delegate_->TryStartDiscovery();
+}
+
+@end
+
+BluetoothLowEnergyDiscoveryManagerMac::
+    ~BluetoothLowEnergyDiscoveryManagerMac() {
+  ClearDevices();
+}
+
+bool BluetoothLowEnergyDiscoveryManagerMac::IsDiscovering() const {
+  return discovering_;
+}
+
+void BluetoothLowEnergyDiscoveryManagerMac::StartDiscovery(
+    BluetoothDevice::UUIDList services_uuids) {
+  ClearDevices();
+  discovering_ = true;
+  pending_ = true;
+  services_uuids_ = services_uuids;
+  TryStartDiscovery();
+}
+
+void BluetoothLowEnergyDiscoveryManagerMac::TryStartDiscovery() {
+  if (!discovering_) {
+    return;
+  }
+
+  if (!pending_) {
+    return;
+  }
+
+  // Can only start if the bluetooth power is turned on.
+  if ([manager_ state] != CBCentralManagerStatePoweredOn) {
+    return;
+  }
+
+  // Converts the services UUIDs to a CoreBluetooth data structure.
+  NSMutableArray* services = nil;
+  if (!services_uuids_.empty()) {
+    services = [NSMutableArray array];
+    for (unsigned int i = 0; i < services_uuids_.size(); i++) {

[Avi (use Gerrit), 2015/01/29 05:25:03]

for (auto& uuid : services_uuids_) ?

[dvh, 2015/01/30 22:45:46]

Done.

+      NSString* uuidString = [NSString
+          stringWithUTF8String:services_uuids_[i].canonical_value().c_str()];

[Avi (use Gerrit), 2015/01/29 05:25:03]

SysUTF8ToNSString

[dvh, 2015/01/30 22:45:46]

Done.

+      CBUUID* uuid = [CBUUID UUIDWithString:uuidString];
+      [services addObject:uuid];
+    }
+  }
+
+  [manager_ scanForPeripheralsWithServices:services options:nil];
+  pending_ = false;
+}
+
+void BluetoothLowEnergyDiscoveryManagerMac::StopDiscovery() {
+  if (discovering_ && !pending_) {
+    [manager_ stopScan];
+  }
+  discovering_ = false;
+}
+
+void BluetoothLowEnergyDiscoveryManagerMac::DiscoveredPeripheral(
+    CBPeripheral* peripheral,
+    NSDictionary* advertisementData,
+    int rssi) {
+  BluetoothLowEnergyDeviceMac* device =
+      new BluetoothLowEnergyDeviceMac(peripheral, advertisementData, rssi);
+
+  // Look for existing device.
+  std::map<const std::string, BluetoothLowEnergyDeviceMac*>::iterator iter =

[Avi (use Gerrit), 2015/01/29 05:25:03]

auto

[dvh, 2015/01/30 22:45:46]

Done.

+      devices_.find(device->GetIdentifier());
+  if (iter == devices_.end()) {
+    // A device has been added.
+    devices_.insert(devices_.begin(),
+                    std::pair<const std::string, BluetoothLowEnergyDeviceMac*>(

[Avi (use Gerrit), 2015/01/29 05:25:02]

make_pair

[dvh, 2015/01/30 22:45:46]

Done.

+                        device->GetIdentifier(), device));
+    observer_->DeviceFound(device);
+    return;
+  }
+
+  // A device has an update.
+  delete device;

[Avi (use Gerrit), 2015/01/29 05:25:03]

NEVER DELETE. Use scoped_ptr instead.

[dvh, 2015/01/30 22:45:46]

Acknowledged.

+  BluetoothLowEnergyDeviceMac* old_device = iter->second;
+  old_device->Update(peripheral, advertisementData, rssi);
+  observer_->DeviceUpdated(old_device);
+}
+
+BluetoothLowEnergyDiscoveryManagerMac*
+BluetoothLowEnergyDiscoveryManagerMac::Create(Observer* observer) {
+  return new BluetoothLowEnergyDiscoveryManagerMac(observer);

[Avi (use Gerrit), 2015/01/29 05:25:03]

If this returns a new object, it might make sense to make it return a
scoped_ptr.

[dvh, 2015/01/30 22:45:46]

see BluetoothDiscoveryManagerMac::CreateClassic().

+}
+
+BluetoothLowEnergyDiscoveryManagerMac::BluetoothLowEnergyDiscoveryManagerMac(
+    Observer* observer)
+    : observer_(observer) {
+  bridge_.reset([[BluetoothLowEnergyDiscoveryManagerMacBridge alloc]
+      initWithManager:this]);
+  // Since CoreBluetooth is only available on OS X 10.7 or later, we
+  // instantiate CBCentralManager only for OS X >= 10.7.
+  if (base::mac::IsOSLionOrLater()) {
+    manager_.reset(
+        [[CBCentralManager alloc] initWithDelegate:bridge_

[Avi (use Gerrit), 2015/01/29 05:25:03]

You _will_ need to add this to base/mac/sdk_forward_declarations.*. Chrome
builds all the way back to the 10.6 SDK.

[dvh, 2015/01/30 22:45:46]

Done.

+                                             queue:dispatch_get_main_queue()]);
+  }
+  discovering_ = false;
+}
+
+void BluetoothLowEnergyDiscoveryManagerMac::ClearDevices() {
+  for (
+      std::map<const std::string, BluetoothLowEnergyDeviceMac*>::iterator iter =
+          devices_.begin();
+      iter != devices_.end(); ++iter) {
+    delete iter->second;
+  }
+  devices_.clear();

[Avi (use Gerrit), 2015/01/29 05:25:03]

Look in stl_util.h and replace the entire contents of this function with
STLDeleteValues.

[dvh, 2015/01/30 22:45:46]

Done.

+}