patch for global error bubbles (view/gtk)

chrome/browser/ui/cocoa/global_error_bubble_controller.mm

+// Copyright (c) 2011 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "chrome/browser/ui/cocoa/global_error_bubble_controller.h"
+
+#include "base/logging.h"
+#include "base/sys_string_conversions.h"
+#include "base/utf_string_conversions.h"
+#include "chrome/browser/search_engines/util.h"
+#import "chrome/browser/ui/browser.h"
+#import "chrome/browser/ui/browser_window.h"
+#import "chrome/browser/ui/cocoa/browser_window_controller.h"
+#import "chrome/browser/ui/cocoa/l10n_util.h"
+#import "chrome/browser/ui/cocoa/info_bubble_view.h"
+#import "chrome/browser/ui/cocoa/toolbar/toolbar_controller.h"
+#import "chrome/browser/ui/global_error_bubble_view.h"
+#import "chrome/browser/ui/global_error_delegate.h"
+#include "grit/generated_resources.h"
+#include "ui/base/l10n/l10n_util.h"
+#include "ui/base/resource/resource_bundle.h"
+#include "ui/gfx/image/image.h"
+
+@implementation GlobalErrorBubbleController
+
+- (id)initWithDelegate:(GlobalErrorDelegate*)delegate
+          parentWindow:(NSWindow*)parentWindow
+            anchoredAt:(NSPoint)anchoredAt {
+  if ((self = [super initWithWindowNibPath:@"GlobalErrorBubble"
+                                parentWindow:parentWindow
+                                anchoredAt:anchoredAt])) {
+    delegate_ = delegate;
+  }
+  return self;
+}
+
+- (void)awakeFromNib {
+  [super awakeFromNib];
+
+  DCHECK(delegate_);
+
+  ResourceBundle& rb = ResourceBundle::GetSharedInstance();
+  [iconView_ setImage:
+      rb.GetImageNamed(delegate_->GetBubbleViewIconResourceID()).ToNSImage()];
+
+  [title_ setStringValue:SysUTF16ToNSString(delegate_->GetBubbleViewTitle())];
+  [message_ setStringValue:SysUTF16ToNSString(
+      delegate_->GetBubbleViewMessage())];
+  [acceptButton_ setTitle:
+      SysUTF16ToNSString(delegate_->GetBubbleViewAcceptButtonLabel())];
+  string16 cancelLabel = delegate_->GetBubbleViewCancelButtonLabel();
+  if (cancelLabel.empty())
+    [cancelButton_ setHidden:YES];
+  else
+    [cancelButton_ setTitle:SysUTF16ToNSString(cancelLabel)];
+
+  // Adapt window size to bottom buttons. Do this before all other layouting.
+  NSArray *views = [NSArray arrayWithObjects:
+      title_, message_, [acceptButton_ superview], nil];
+  CGFloat dy = cocoa_l10n_util::VerticallyReflowGroup(views);
+  NSSize ds = NSMakeSize(0, dy);
+  ds = [[self bubble] convertSize:ds toView:nil];
+
+  NSRect frame = [[self window] frame];
+  frame.origin.y -= ds.height;
+  frame.size.height += ds.height;
+  [[self window] setFrame:frame display:YES];
+}
+
+- (void)showWindow:(id)sender {
+  BrowserWindowController* bwc = [BrowserWindowController
+      browserWindowControllerForWindow:[self parentWindow]];
+  [bwc lockBarVisibilityForOwner:self withAnimation:NO delay:NO];
+  [super showWindow:sender];
+}
+
+- (void)close {
+  BrowserWindowController* bwc = [BrowserWindowController
+      browserWindowControllerForWindow:[self parentWindow]];
+  [bwc releaseBarVisibilityForOwner:self withAnimation:YES delay:NO];
+  [super close];
+}
+
+
+
+@end
+
+void GlobalErrorBubbleView::Show(GlobalErrorDelegate* delegate,
+                                 Browser* browser,
+                                 const gfx::Rect& position_relative_to) {
+  NSWindow* parentWindow = browser->window()->GetNativeHandle();
+  BrowserWindowController* bwc = [BrowserWindowController
+      browserWindowControllerForWindow:parentWindow];
+  NSPoint anchoredAt = [[bwc toolbarController] wrenchButtonBubblePoint];
+  anchoredAt = [parentWindow convertBaseToScreen:anchoredAt];
+
+  // The controller will be automatically deleted when the bubble is closed.
+  GlobalErrorBubbleController* controller = [[GlobalErrorBubbleController alloc]
+      initWithDelegate:delegate
+          parentWindow:parentWindow
+            anchoredAt:anchoredAt];
+  [controller showWindow:nil];
+}