Build standalone network service on Android.

mojo/services/network/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//mojo/public/mojo_application.gni")
 
-mojo_native_application("network") {
-  output_name = "network_service"
-  sources = [
-    "main.cc",
-  ]
-  deps = [
-    ":lib",
-    "//base",
-    "//mojo/application",
-    "//mojo/public/cpp/bindings:bindings",
-    "//mojo/services/public/cpp/network",
-    "//mojo/services/public/interfaces/network",
-  ]
+if (is_android) {
+  import("//build/config/android/rules.gni")
+
+  java_library_path = "$target_out_dir/java_library.dex.jar"

[qsr, 2014/12/05 15:31:16]

Could you add a blank line between this and next line. It is kind of hard to
spot the main target otherwise.

[ppi, 2014/12/05 17:17:43]

Done.

+  mojo_android_application("network") {
+    output_name = "network_service"
+    input_so = "$root_out_dir/lib.stripped/libnetwork_service.so"
+    input_dex_jar = java_library_path
+  }
+
+  shared_library("native_library") {
+    output_name = "network_service"
+
+    deps = [
+      ":sources",
+    ]
+
+    sources = [

[qsr, 2014/12/05 15:31:16]

sources before deps -> https://code.google.com/p/chromium/wiki/GNStyleGuide

Also, could you run gn format, will sort all of this for you.

[ppi, 2014/12/05 17:17:43]

Done.

+      "android_hooks.cc",
+    ]
+  }
+
+  android_standalone_library("java_library") {
+    deps = [

[qsr, 2014/12/05 15:31:16]

Same thing, deps is the last thing there.

[ppi, 2014/12/05 17:17:43]

Done.

+      "//net/android:net_java",
+    ]
+
+    standalone_dex_path = java_library_path
+  }
+} else {
+  mojo_native_application("network") {
+    output_name = "network_service"
+    deps = [
+      ":sources",
+    ]
+  }
 }
 
 source_set("lib") {
   sources = [
     "cookie_store_impl.cc",
     "cookie_store_impl.h",
     "net_adapters.cc",
     "net_adapters.h",
     "net_address_type_converters.cc",
     "net_address_type_converters.h",
@@ skipping 21 matching lines @@
     "//mojo/common",
     "//mojo/environment:chromium",
     "//mojo/public/cpp/bindings",
     "//mojo/services/public/cpp/network",
     "//mojo/services/public/interfaces/network",
     "//net",
     "//url",
   ]
 }
 
+source_set("sources") {
+  visibility = [ ":*" ]

[qsr, 2014/12/05 15:31:16]

Do you need to use this because gn will complain if you reference something that
doesn't exist? If not, please just enumerate the 2 targets.

[ppi, 2014/12/05 17:17:43]

ERROR at //mojo/public/mojo_application.gni:30:3: Dependency not allowed.
  shared_library(library_target_name) {
  ^------------------------------------
The item //mojo/services/network:network_service_library
can not depend on //mojo/services/network:sources
because it is not in //mojo/services/network:sources's visibility list: [
  //mojo/services/network:native_library
  //mojo/services/network:network
]
***************

gn complains because (on Linux) it's a generated target that the dependency on
":sources" will be carried to. Naming of this generated target is an impl.
detail of the template, so it feels weird to mention it explicitly here. Wdyt?

[qsr, 2014/12/08 14:27:07]

 That doesn't feel right. There might be something missing in the
mojo_native_application template so that private target can depend on thing that
the main target can depend on. On the other end, :* is defined in gn help
visibility, so I guess this is OK.

+
+  sources = [
+    "main.cc",
+  ]
+
+  deps = [
+    ":lib",
+    "//base",
+    "//mojo/application",
+    "//mojo/public/c/system:for_shared_library",
+    "//mojo/public/cpp/bindings:bindings",
+    "//mojo/services/public/cpp/network",
+    "//mojo/services/public/interfaces/network",
+  ]
+}
+
 mojo_native_application("apptests") {
   output_name = "network_service_apptests"
   testonly = true
 
   sources = [
     "udp_socket_apptest.cc",
   ]
 
   deps = [
     ":network",
     "//base",
     "//mojo/application",
     "//mojo/application:test_support",
     "//mojo/public/cpp/bindings",
     "//mojo/public/cpp/bindings:callback",
     "//mojo/services/public/cpp/network",
     "//mojo/services/public/interfaces/network",
     "//net",
     "//testing/gtest",
   ]
 }