[rAc OSX] Factor out AutofillHeader class to contain dialog header elements.

chrome/browser/ui/cocoa/autofill/autofill_header.mm

+// Copyright 2013 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#import "chrome/browser/ui/cocoa/autofill/autofill_header.h"
+
+#import "chrome/browser/ui/cocoa/autofill/autofill_account_chooser.h"
+#include "base/strings/sys_string_conversions.h"
+#include "chrome/browser/ui/autofill/autofill_dialog_view_delegate.h"
+#include "chrome/browser/ui/chrome_style.h"
+#include "chrome/browser/ui/cocoa/autofill/autofill_dialog_constants.h"
+
+namespace {
+
+// Height of the account chooser.
+const CGFloat kAccountChooserHeight = 20.0;
+
+}  // namespace
+
+@implementation AutofillHeader
+
+- (id)initWithDelegate:(autofill::AutofillDialogViewDelegate*)delegate {
+  if (self = [super initWithFrame:NSZeroRect]) {
+    delegate_ = delegate;
+
+    accountChooser_.reset(
+        [[AutofillAccountChooser alloc] initWithFrame:NSZeroRect
+                                             delegate:delegate]);
+
+    // Set dialog title.
+    title_.reset([[NSTextField alloc] initWithFrame:NSZeroRect]);
+    [title_ setEditable:NO];
+    [title_ setBordered:NO];
+    [title_ setDrawsBackground:NO];
+    [title_ setFont:[NSFont systemFontOfSize:15.0]];
+    [title_ setStringValue:base::SysUTF16ToNSString(delegate_->DialogTitle())];
+    [title_ sizeToFit];
+
+    [self setSubviews:@[accountChooser_, title_]];
+  }
+  return self;
+}
+
+- (BOOL)isFlipped {
+  return YES;
+}

[groby-ooo-7-16, 2013/11/22 14:51:38]

Does this really need to be flipped?

[Ilya Sherman, 2013/11/23 00:23:54]

Done.

+
+- (NSView*)anchorView {
+  return [[accountChooser_ subviews] objectAtIndex:1];
+}
+
+- (void)update {
+  [accountChooser_ update];
+
+  [title_ setStringValue:base::SysUTF16ToNSString(delegate_->DialogTitle())];
+  [title_ sizeToFit];
+}
+
+- (CGFloat)heightForWidth:(int)width {
+  return chrome_style::kTitleTopPadding +
+         kAccountChooserHeight +
+         autofill::kDetailVerticalPadding;
+}
+
+- (NSSize)preferredSize {
+  NOTREACHED();  // Only implemented as part of AutofillLayout protocol.
+  return NSZeroSize;
+}
+
+- (void)performLayout {
+  NSRect bounds = [self bounds];
+
+  // Align baseline of title with bottom of accountChooser.
+  base::scoped_nsobject<NSLayoutManager> layout_manager(
+      [[NSLayoutManager alloc] init]);
+  NSRect titleFrame = [title_ frame];
+  titleFrame.origin.x = chrome_style::kHorizontalPadding;
+  titleFrame.origin.y =
+      chrome_style::kTitleTopPadding + NSHeight(titleFrame) -
+      [layout_manager defaultBaselineOffsetForFont:[title_ font]];
+  [title_ setFrameOrigin:titleFrame.origin];
+
+  CGFloat accountChooserLeftX =
+      NSMaxX(titleFrame) + chrome_style::kHorizontalPadding;
+  CGFloat accountChooserWidth =
+      NSMaxX(bounds) - chrome_style::kHorizontalPadding - accountChooserLeftX;
+  NSRect accountChooserFrame =
+      NSMakeRect(accountChooserLeftX, chrome_style::kTitleTopPadding,
+                 accountChooserWidth, kAccountChooserHeight);
+  [accountChooser_ setFrame:accountChooserFrame];
+  [accountChooser_ performLayout];
+}
+
+@end