Add chrome sync tests to the GN build.

chrome/test/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/features.gni")
 import("//build/config/ui.gni")
 
+gypi_values = exec_script(
+    "//build/gypi_to_gn.py",
+    [ rebase_path("../chrome_tests.gypi") ],
+    "scope",
+    [ "../chrome_tests.gypi" ])
+
 # This target exists to reference other test executables to bring these files
 # into the build.
 group("test") {
   testonly = true
   deps = [
     "//chrome/test/perf",
   ]
 }
 
 # GYP version: chrome/chrome_tests_unit.gypi:test_support_common
@@ skipping 186 matching lines @@
     ":test_support",
     "//base",
     "//chrome:resources",
     "//chrome:strings",
     "//chrome/browser",
     "//chrome/common",
     "//mojo/edk/system",
     "//mojo/environment:chromium",
   ]
 }
+
+source_set("sync_integration_test_support") {
+  testonly = true
+
+  sources = rebase_path(gypi_values.test_support_sync_integration_sources,
+                        ".", "//chrome")
+  deps = [
+    ":test_support",
+    "//base",
+    "//chrome",
+    "//chrome/browser",
+    "//components/invalidation",
+    "//components/invalidation:test_support",
+    "//net",
+    "//skia",
+    "//sync",
+    "//sync:test_support_sync_testserver",
+    "//sync:test_support_sync_fake_server",
+    "//ui/app_list:test_support",
+  ]
+
+  if (is_mac) {
+    sources -= [
+      "../browser/sync/test/integration/dictionary_helper.cc",
+      "../browser/sync/test/integration/dictionary_helper.h",
+      "../browser/sync/test/integration/dictionary_load_observer.cc",
+      "../browser/sync/test/integration/dictionary_load_observer.h",
+    ]
+  }
+  if (!enable_app_list) {
+    sources -= [
+      "../browser/sync/test/integration/sync_app_list_helper.cc",
+      "../browser/sync/test/integration/sync_app_list_helper.h",
+    ]
+  }
+}
+
+test("sync_integration_tests") {
+  sources = rebase_path(gypi_values.sync_integration_tests_sources,
+                        ".", "//chrome")
+
+  # TODO(phajdan.jr): Only temporary, to make transition easier.
+  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
+
+  deps = [
+    ":sync_integration_test_support",
+    ":test_support",
+    "//base/allocator",
+    "//chrome:packed_extra_resources",
+    "//chrome:packed_resources",
+    "//chrome:resources",
+    "//chrome:strings",
+    "//chrome/common",
+    "//chrome/renderer",
+    "//crypto:platform",
+    "//sync",
+    "//testing/gmock",
+    "//testing/gtest",
+    "//third_party/icu",
+    "//third_party/leveldatabase",
+    "//third_party/npapi",
+    "//third_party/WebKit/public:blink",
+  ]
+
+  if (cld_version == 0 || cld_version == 2) {
+    # Language detection is irrelevant to sync, so it can depend on any
+    # implementation for CLD2. Dynamic is smaller, so go with dynamic.
+    deps += [ "//third_party/cld_2:cld2_dynamic" ]
+  }
+  if (is_mac) {
+    # Dictionary sync is disabled on Mac.
+    sources -= [
+      "../browser/sync/test/integration/multiple_client_dictionary_sync_test.cc",

[scottmg, 2014/11/19 20:15:47]

the ../ is kind of weird, do you think it's better in the subdir like this?

[brettw, 2014/11/19 20:22:36]

I think there is value in keeping the toplevel Chrome BUILD file smaller. It's
already >600 lines with no file lists and no test targets.

It's not that weird to have "../" here because all the other ones e.g. in
browser/BUILD.gn have to do the same thing.

I think if I was designing this from scratch, the subdirectories like
chrome/browser would each define source tests of targets related to them that
would get linked into various larger test targets in chrome/test.

+      "../browser/sync/test/integration/single_client_dictionary_sync_test.cc",
+      "../browser/sync/test/integration/two_client_dictionary_sync_test.cc",
+    ]
+ 
+    # The sync_integration_tests do not run on mac without this flag.
+    # Search for comments about "xcode_settings" elsewhere in this file.
+    ldflags = [ "-Wl,-ObjC" ]
+  }
+  if (is_win) {
+    # TODO(GYP) figure out what these should map to.
+    #sources += [
+    #  '<(SHARED_INTERMEDIATE_DIR)/chrome_version/other_version.rc',
+    #  '<(SHARED_INTERMEDIATE_DIR)/ui/resources/ui_unscaled_resources.rc',
+    #]
+    deps += [
+      "//third_party/wtl",
+      #'chrome_version_resources',  TODO(GYP)
+    ]
+
+    # TODO(GYP)
+    #'Debug': { 'msvs_settings': { 'VCLinkerTool': {
+    #   'LinkIncremental': '<(msvs_debug_link_nonincremental)',
+  } else {
+    sources -= [
+      "../app/chrome_version.rc.version",
+    ]
+  }
+
+  if (toolkit_views) {
+    deps += [ "//ui/views" ]
+  }
+  if (enable_basic_printing || enable_print_preview) {
+    deps += [ "//printing" ]
+  }
+  if (!enable_app_list) {
+    sources -= [
+      "../browser/sync/test/integration/single_client_app_list_sync_test.cc",
+      "../browser/sync/test/integration/two_client_app_list_sync_test.cc",
+    ]
+  }
+  if (!enable_managed_users) {
+    sources -= [
+      "../browser/sync/test/integration/single_client_supervised_user_settings_sync_test.cc",
+    ]
+  }
+}
+
+test("sync_performance_tests") {
+  sources = rebase_path(gypi_values.sync_performance_tests_sources,
+                        ".", "//chrome")
+
+  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
+
+  deps = [
+    ":sync_integration_test_support",
+    "//base/allocator",
+    "//crypto:platform",
+    "//sync",
+    "//testing/gmock",
+    "//testing/gtest",
+  ]
+
+  if (cld_version == 0 || cld_version == 2) {
+    # Language detection is irrelevant to sync, so it can depend on any
+    # implementation for CLD2. Dynamic is smaller, so go with dynamic.
+    deps += [ "//third_party/cld_2:cld2_dynamic" ]
+  }
+
+  if (is_mac) {
+    # Dictionary sync is disabled on Mac.
+    sources -= [
+      "../browser/sync/test/integration/performance/dictionary_sync_perf_test.cc",
+    ]
+
+    # The sync_performance_tests do not run on mac without this flag.
+    # Search for comments about "xcode_settings" elsewhere in this file.
+    ldflags = [ "-Wl,-ObjC" ]
+  }
+  if (is_win) {
+    # TODO(GYP) figure out what these should map to.
+    #sources += [
+    #  '<(SHARED_INTERMEDIATE_DIR)/chrome_version/other_version.rc',
+    #  '<(SHARED_INTERMEDIATE_DIR)/ui/resources/ui_unscaled_resources.rc',
+    #]
+    deps += [
+      "//third_party/wtl",
+      #'chrome_version_resources',  TODO(GYP)
+    ]
+
+    # TODO(GYP)

[scottmg, 2014/11/19 20:15:46]

just delete this

+    #'Debug': { 'msvs_settings': { 'VCLinkerTool': {
+    #   'LinkIncremental': '<(msvs_debug_link_nonincremental)',
+  } else {
+    sources -= [
+      "../app/chrome_version.rc.version",
+    ]
+  }
+
+  if (toolkit_views) {
+    deps += [ "//ui/views" ]
+  }
+}