IDL: Generate union type containers

Source/bindings/scripts/scripts.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//third_party/WebKit/Source/bindings/core/v8/generated.gni")
 import("//third_party/WebKit/Source/bindings/modules/idl.gni")
 import("//third_party/WebKit/Source/bindings/modules/modules.gni")
 
 bindings_scripts_dir = get_path_info(".", "abspath")
 bindings_scripts_output_dir = "$root_gen_dir/blink/bindings/scripts"
 
 # Replacing <(DEPTH) with "/" makes paths like "<(DEPTH)/foo" absolute.
 _gypi = exec_script(
     "//build/gypi_to_gn.py",
     [ rebase_path("scripts.gypi"),
       "--replace=<(DEPTH)=/" ],
     "scope",
     [ "scripts.gypi" ])
 
 jinja_module_files = get_path_info(_gypi.jinja_module_files, "abspath")
 idl_lexer_parser_files = get_path_info(_gypi.idl_lexer_parser_files, "abspath")
 idl_compiler_files = get_path_info(_gypi.idl_compiler_files, "abspath")
 
 # Calls the compute_interfaces_info_individual script.
 #
 # Parameters:
 #   sources_static = list of IDL files to pass as inputs
 #   sources_generated = list of generated IDL files to pass as inputs
 #   component_dir = name if subdirectory (one word, no slashes) of component.
-#   output_file = pickle file to write
+#   interfaces_info_file = output pickle file for interfaces info.
+#   component_wide_info_file = output pickle file for component wide info.
 #   deps = dependencies
 #
 # FIXME: Note the static/generated split is for consistency with GYP. This
 # split is not necessary in the GN build and could be combined into a single
 # "sources".
 template("compute_interfaces_info_individual") {
   action(target_name) {
     script = "$bindings_scripts_dir/compute_interfaces_info_individual.py"
     if (defined(invoker.visibility)) {
       visibility = invoker.visibility
     }
 
     # Save static list to temp file to avoid blowing out command-line length
     # limit.
     file_list = "$target_gen_dir/${target_name}_file_list.txt"
     write_file(file_list, rebase_path(invoker.sources_static, root_build_dir))
 
     inputs = [
       "$bindings_scripts_dir/utilities.py",
       file_list,
     ] + invoker.sources_static + invoker.sources_generated
 
     outputs = [
-      invoker.output_file
+      invoker.interfaces_info_file,
+      invoker.component_wide_info_file,
     ]
 
     args = [
       "--cache-directory",
       rebase_path(bindings_scripts_output_dir, root_build_dir),
       "--idl-files-list", rebase_path(file_list, root_build_dir),
       "--interfaces-info-file",
-      rebase_path(invoker.output_file, root_build_dir),
+      rebase_path(invoker.interfaces_info_file, root_build_dir),
+      "--component-wide-info-file",
+      rebase_path(invoker.component_wide_info_file, root_build_dir),
       "--write-file-only-if-changed=1",
       "--",
     ] + rebase_path(invoker.sources_generated, root_build_dir)
 
     deps = [
       "//third_party/WebKit/Source/bindings/scripts:cached_lex_yacc_tables",
     ] + invoker.deps
   }
 }
 
@@ skipping 99 matching lines @@
       # http://crbug.com/358074
       "//third_party/WebKit/Source/bindings/modules:interfaces_info",
 
       "//third_party/WebKit/Source/bindings/scripts:cached_lex_yacc_tables",
       "//third_party/WebKit/Source/bindings/scripts:cached_jinja_templates",
       "//third_party/WebKit/Source/core:generated_testing_idls",
     ]
   }
 }
 
-# Runs the idl_compiler to generate IDL dictionary impl files.
+# Runs the idl_compiler to generate IDL dictionary and union impl files.
 #
 # Parameters:
 #   sources = a list of IDL files to process
 #   outputs = a list of files to write to
-template("idl_dictionary") {
-  output_dir = "$root_gen_dir/blink/"
+#   output_dir = the directory to put the output files
+#   component_wide_info = a filename of pickle file which contains component
+#     wide information
+#   target_component = component to generate code for
+template("idl_impl") {
+  dictionary_impl_output_dir = "$root_gen_dir/blink/"
 
   action(target_name) {
     script = "//third_party/WebKit/Source/bindings/scripts/idl_compiler.py"
     idl_files_list = "$target_gen_dir/${target_name}_file_list.tmp"
     write_file(idl_files_list, rebase_path(invoker.sources, root_build_dir))
 
     inputs = [ idl_files_list ] + invoker.sources
     outputs = invoker.outputs
 
     args = [
       "--cache-dir",
       rebase_path(bindings_scripts_output_dir, root_build_dir),
       "--output-dir",
-      rebase_path(output_dir, root_build_dir),
+      rebase_path(invoker.output_dir, root_build_dir),
+      "--dictionary-impl-output-dir",
+      rebase_path(dictionary_impl_output_dir, root_build_dir),
       "--interfaces-info",
       rebase_path("$bindings_modules_output_dir/InterfacesInfoModules.pickle",
                   root_build_dir),
+      "--component-wide-info",
+      rebase_path(invoker.component_wide_info, root_build_dir),
+      "--target-component",
+      invoker.target_component,
       "--write-file-only-if-changed=1",
-      "--generate-dictionary-impl",
+      "--generate-impl",
       rebase_path(idl_files_list, root_build_dir),
     ]
 
     deps = [
       # FIXME: should be interfaces_info_core (w/o modules)
       # http://crbug.com/358074
+      "//third_party/WebKit/Source/bindings/core:interfaces_info_individual_core",
       "//third_party/WebKit/Source/bindings/modules:interfaces_info",
+      "//third_party/WebKit/Source/bindings/modules:interfaces_info_individual_modules",
       "//third_party/WebKit/Source/bindings/scripts:cached_lex_yacc_tables",
       "//third_party/WebKit/Source/bindings/scripts:cached_jinja_templates",
     ]
   }
 }
 
 # Calls the aggregate_generated_bindings script.
 #
 # Parameters:
 #   sources = a list of source IDL files.
@@ skipping 106 matching lines @@
       output_header_files += [
         "$output_dir/${interface}${component}Constructors.h"
       ]
     }
 
     outputs = output_idl_files + output_header_files
     deps = invoker.deps
   }
 }