DOM Level 3 .code and .key value enumerations.

ui/events/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/ui.gni")
 
 static_library("dom4_keycode_converter") {
   sources = [
     "keycodes/dom4/keycode_converter.cc",
     "keycodes/dom4/keycode_converter.h",
     "keycodes/dom4/keycode_converter_data.h",
   ]
 
-  deps = [ "//base" ]
+  deps = [
+    "//base",
+    ":generate_dom4_keycodes",
+  ]
 }
 
 component("events_base") {
   sources = [
     "device_data_manager.cc",
     "device_data_manager.h",
     "device_hotplug_event_observer.h",
     "event_constants.h",
     "event_switches.cc",
     "event_switches.h",
@@ skipping 239 matching lines @@
 
   if (use_x11) {
     sources += [
       "test/events_test_utils_x11.cc",
       "test/events_test_utils_x11.h",
     ]
     deps += [ "//ui/gfx/x" ]
   }
 }
 
+# GYP version: ui/events/events.gyp:generate_dom4_keycodes
+action("generate_dom4_keycodes") {
+  visibility = [ ":*" ]  # Only targets in this file can depend on this.
+
+  script = "keycodes/dom4/generate_dom_values.py"
+
+  dom_values = "keycodes/dom4/dom_values.txt"
+  native_values = "keycodes/dom4/native_codes.txt"
+
+  domcode_declaration_h_file = "$target_gen_dir/keycodes/dom4/domcode.h"
+  domcode_string_h_file = "$target_gen_dir/keycodes/dom4/domcode_string.h"
+  domcode_table_h_file = "$target_gen_dir/keycodes/dom4/domcode_table.h"
+  domkey_declaration_h_file = "$target_gen_dir/keycodes/dom4/domkey.h"
+  domkey_string_h_file = "$target_gen_dir/keycodes/dom4/domkey_string.h"
+  domkey_table_h_file = "$target_gen_dir/keycodes/dom4/domkey_table.h"
+  native_code_data_h_file = "$target_gen_dir/keycodes/dom4/native_code_data.h"
+
+  sources = [
+    dom_values,
+    native_values,
+  ]
+
+  outputs = [
+    domcode_declaration_h_file,
+    domcode_string_h_file,
+    domcode_table_h_file,
+    domkey_declaration_h_file,
+    domkey_string_h_file,
+    domkey_table_h_file,
+    native_code_data_h_file,
+  ]
+
+  args = [
+    "--input_dom=" + rebase_path(dom_values, root_build_dir),
+    "--input_native=" + rebase_path(native_values, root_build_dir),
+    "--output_dom_code_declaration=" +
+        rebase_path(domcode_declaration_h_file, root_build_dir),
+    "--output_dom_code_string=" +
+        rebase_path(domcode_string_h_file, root_build_dir),
+    "--output_dom_code_table=" +
+        rebase_path(domcode_table_h_file, root_build_dir),
+    "--output_dom_key_declaration=" +
+        rebase_path(domkey_declaration_h_file, root_build_dir),
+    "--output_dom_key_string=" +
+        rebase_path(domkey_string_h_file, root_build_dir),
+    "--output_dom_key_table=" +
+        rebase_path(domkey_table_h_file, root_build_dir),
+    "--output_native=" + rebase_path(native_code_data_h_file, root_build_dir),
+  ]
+}
+
 test("events_unittests") {
   sources = [
     "cocoa/events_mac_unittest.mm",
     "event_dispatcher_unittest.cc",
     "event_processor_unittest.cc",
     "event_rewriter_unittest.cc",
     "event_unittest.cc",
     "gesture_detection/bitset_32_unittest.cc",
     "gesture_detection/gesture_event_data_packet_unittest.cc",
     "gesture_detection/gesture_provider_unittest.cc",
@@ skipping 37 matching lines @@
       "ozone/evdev/touch_event_converter_evdev_unittest.cc",
     ]
   }
 
   if (use_aura) {
     sources += [
       "gestures/gesture_provider_aura_unittest.cc",
     ]
   }
 }