Add metrics for the number of attached displays.

chrome/browser/metrics/chrome_browser_main_extra_parts_metrics_mac.mm

Index: chrome/browser/metrics/chrome_browser_main_extra_parts_metrics_mac.mm
diff --git a/chrome/browser/metrics/chrome_browser_main_extra_parts_metrics_mac.mm b/chrome/browser/metrics/chrome_browser_main_extra_parts_metrics_mac.mm
new file mode 100644
index 0000000000000000000000000000000000000000..aaf91d664aeaa68d52bb3cc2dc21c182ee14a874
--- /dev/null
+++ b/chrome/browser/metrics/chrome_browser_main_extra_parts_metrics_mac.mm
@@ -0,0 +1,65 @@
+// Copyright 2014 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "chrome/browser/metrics/chrome_browser_main_extra_parts_metrics_mac.h"
+
+#include <Cocoa/Cocoa.h>
+
+#include "base/metrics/histogram.h"
+
+namespace {
+
+// The maximum number of screens to record in UMA.
+NSUInteger kMaxScreens = 10;
+
+}  // namespace
+
+@interface MetricsBridge : NSObject {
+  NSUInteger screenCount_;
+}
+@end
+
+@implementation MetricsBridge

[Robert Sesek, 2014/10/08 19:25:20]

Could you instead use gfx::Screen::AddObserver(gfx::DisplayObserver*) ? Though
that uses CGDisplayRegisterReconfigurationCallback instead of this notification.

[erikchen, 2014/10/08 22:49:19]

I went with your suggestion and also switched to GetNumDisplays(), which has a
slightly different behavior. I updated the summaries in histograms.xml to
indicate this change.

+- (instancetype)init {
+  self = [super init];
+  if (self) {
+    screenCount_ = [[NSScreen screens] count];
+    [[NSNotificationCenter defaultCenter]
+        addObserver:self
+           selector:@selector(didChangeScreenParameters:)
+               name:NSApplicationDidChangeScreenParametersNotification
+             object:nil];
+
+    UMA_HISTOGRAM_ENUMERATION("OSX.DisplayCount.StartUp",
+                              std::min(kMaxScreens, screenCount_),
+                              kMaxScreens + 1);
+  }
+  return self;
+}
+
+- (void)dealloc {
+  [[NSNotificationCenter defaultCenter] removeObserver:self];
+  [super dealloc];
+}
+
+- (void)didChangeScreenParameters:(NSNotification*)notification {
+  NSUInteger screenCount = [[NSScreen screens] count];
+  if (screenCount != screenCount_) {
+    screenCount_ = screenCount;
+    UMA_HISTOGRAM_ENUMERATION("OSX.DisplayCount.Changed",

[Robert Sesek, 2014/10/08 19:25:20]

This seems like a _COUNTS instead of an _ENUMERATION.

[erikchen, 2014/10/08 22:49:19]

_COUNTS uses an exponential histogram (even _COUNTS_100). I want a linear
histogram to make sure that I can distinguish the low numbers (1, 2, 3), so I
have to use _ENUMERATION.

+                              std::min(kMaxScreens, screenCount_),
+                              kMaxScreens + 1);
+  }
+}
+
+@end
+
+ChromeBrowserMainExtraPartsMetricsMac::ChromeBrowserMainExtraPartsMetricsMac() {
+  metrics_bridge_ = static_cast<void*>([[MetricsBridge alloc] init]);
+}
+
+ChromeBrowserMainExtraPartsMetricsMac::
+    ~ChromeBrowserMainExtraPartsMetricsMac() {
+  [static_cast<NSObject*>(metrics_bridge_) release];
+}