Move mojo/services/public/cpp TypeConverters to mojo/converters.

mojo/converters/BUILD.gn

+# Copyright 2014 The Chromium Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+# GYP version: mojo/mojo_converters.gypi:mojo_converters
+component("converters") {

[msw, 2014/10/09 19:23:09]

Should we have consistent naming between GYP's "mojo_converters[_unittests]" and
GN's "converters[_unittests]" targets? It seems like some other places follow
the inconsistent pattern I use here, like:
https://code.google.com/p/chromium/codesearch#chromium/src/mojo/common/BUILD....

Also, what's the "_lib" post-fix convention? Should that be used here?

[jamesr, 2014/10/09 19:30:54]

The unit test executable names all have mojo_ prefixes and the mojo test()
target's name should match the executable name.  Targets that are not actual
binary outputs (i.e. intermediate components and source_sets) should have names
that are natural which typically means omitting the mojo_ prefix.

In GYP, all target names have to be namespaced by convention because the targets
exist in a global namespace (there are generators that blow up if you repeat
things).  In GN, the path is part of the target label so you don't have to
repeat yourself.  I.e. in GYP you have to say 'mojo_common' to mean the things
in src/mojo/common, but in GN you can just say 'common' in
src/mojo/common/BUILD.gn since the full label is //mojo/common:common (or you
can just say //mojo/common since the default label is the directory name).
I'm not sure where it's used. It typically doesn't provide value.

[msw, 2014/10/10 00:28:58]

Thanks for the naming explanations, that makes sense! I reverted the gyp targets
to retain their _lib postfixes for now, but I can remove them [in a separate CL]
if you'd like.

+  public_deps = [
+    "//ui/gfx",
+  ]
+  deps = [
+    "//base",
+    "//cc",
+    "//cc/surfaces",
+    "//gpu",
+    "//skia",
+    "//ui/events",
+    "//ui/gfx/geometry",
+    "//mojo/environment:chromium",
+    "//mojo/public/c/system:for_component",
+    "//mojo/services/public/interfaces/geometry",
+    "//mojo/services/public/interfaces/input_events",
+    "//mojo/services/public/interfaces/surfaces:surface_id",
+    "//mojo/services/public/interfaces/surfaces",
+  ]
+
+  defines = [
+    "MOJO_CONVERTERS_IMPLEMENTATION",

[jamesr, 2014/10/09 19:30:54]

why put all converters in one component? seems like it'd be better to leave them
as independent components so folks can link in just what they want.

[msw, 2014/10/10 00:28:58]

Done, I misunderstood this as your intention, but should have asked.

+  ]
+
+  sources = [
+    "geometry_type_converters.cc",
+    "geometry_type_converters.h",
+    "input_event_names.h",
+    "input_events_type_converters.cc",
+    "input_events_type_converters.h",
+    "mojo_converters_export.h",
+    "mojo_extended_key_event_data.cc",
+    "mojo_extended_key_event_data.h",
+    "surfaces_type_converters.cc",
+    "surfaces_type_converters.h",
+    "surfaces_utils.cc",
+    "surfaces_utils.h",
+  ]
+}
+
+# GYP version: mojo/mojo_converters.gypi:mojo_converters_unittests
+test("converters_unittests") {

[msw, 2014/10/09 19:23:09]

Should I split the test target into it's own sub-directory and BUILD.gn?

+  deps = [
+    "//base",
+    "//base/test:test_support",
+    "//cc",
+    "//cc/surfaces",
+    "//gpu",
+    "//mojo/converters",
+    "//mojo/edk/test:run_all_unittests",
+    "//mojo/environment:chromium",
+    "//mojo/services/public/interfaces/geometry",
+    "//mojo/services/public/interfaces/surfaces",
+    "//skia",
+    "//testing/gtest",
+    "//ui/gfx",
+    "//ui/gfx/geometry",
+    "//ui/gfx:test_support",
+  ]
+
+  sources = [
+    "surface_unittest.cc"
+  ]
+}