Update bindings gn files for binding modularization.

Source/bindings/modules/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//third_party/WebKit/Source/modules/modules.gni")
 import("//third_party/WebKit/Source/bindings/core/core.gni")
 import("//third_party/WebKit/Source/bindings/modules/modules.gni")
 import("//third_party/WebKit/Source/bindings/scripts/scripts.gni")
 import("//third_party/WebKit/Source/build/scripts/scripts.gni")
 
 visibility = [ "//third_party/WebKit/*" ]
 
+core_idl_files_list = "$target_gen_dir/core_idl_files.tmp"
+write_file(core_idl_files_list,
+           rebase_path(core_idl_files, root_build_dir))
+
+modules_idl_files_list = "$target_gen_dir/modules_idl_files.tmp"
+write_file(modules_idl_files_list,
+           rebase_path(modules_idl_files, root_build_dir))
+
 # GYP version: Source/bindings/modules/generated.gyp:bindings_modules_generated
 group("bindings_modules_generated") {
   deps = [
     ":modules_bindings_generated_event_interfaces",
     ":bindings_modules_generated_event_modules_factory",
     ":bindings_modules_generated_event_modules_names",
     ":bindings_modules_generated_event_target_modules_names",
   ]
 }
 
@@ skipping 39 matching lines @@
 
 # ------------------------------------------------------------------------------
 
 # GYP version: Source/bindings/modules/generated.gyp:interfaces_info_individual_modules
 compute_interfaces_info_individual("interfaces_info_individual_modules") {
   sources_static = modules_static_idl_files
   # No generated files currently, will add with constructors
   sources_generated = []
   output_file =
     "$bindings_modules_output_dir/InterfacesInfoModulesIndividual.pickle"
+  deps = [ ":modules_global_constructors_idls", ]
 }
 
 # GYP version: Source/bindings/modules/generated.gyp:interfaces_info
 action("interfaces_info") {
-  script = "$bindings_scripts_dir/compute_interfaces_info_overall.py"
+  script = "../scripts/compute_interfaces_info_overall.py"
 
   inputs = [
     "$bindings_core_output_dir/InterfacesInfoCoreIndividual.pickle",
     "$bindings_modules_output_dir/InterfacesInfoModulesIndividual.pickle",
   ]
   outputs = [
     "$bindings_modules_output_dir/InterfacesInfoModules.pickle",
   ]
 
   args = [
     "--write-file-only-if-changed=1",
     "--",
     rebase_path(
         "$bindings_core_output_dir/InterfacesInfoCoreIndividual.pickle",
         root_build_dir),
     rebase_path(
         "$bindings_modules_output_dir/InterfacesInfoModulesIndividual.pickle",
         root_build_dir),
     rebase_path(
         "$bindings_modules_output_dir/InterfacesInfoModules.pickle",
         root_build_dir),
   ]
 
   deps = [
     ":interfaces_info_individual_modules",
     "//third_party/WebKit/Source/bindings/core:interfaces_info_individual_core",
   ]
 }
+
+action("modules_global_objects") {

[brettw, 2014/10/07 16:44:08]

These script invocations are duplicated in the two files. Usually if a script is
called more than once, it's best to write a template that knows how to invoke
that script and to provide a nice interface for it.

See Source/bindings/scripts/scripts.gni for some examples (this is probably
where you'd put the template for these two scripts as well). You can see this
separates the complexity of rebasing paths and all the args and so the callsite
can be just a couple of lines that is much easier to follow.

Let me know if you need more pointers.

[tasak, 2014/10/08 03:29:49]

I see.
I added 2 new templates: compute_global_objects and
generate_global_constructors.

+  script = "../scripts/compute_global_objects.py"
+
+  inputs = [
+    "../scripts/utilities.py",
+    "$bindings_core_output_dir/GlobalObjectsCore.pickle",
+    modules_idl_files_list,
+  ] + modules_idl_files
+
+  outputs = [
+    "$bindings_modules_output_dir/GlobalObjectsModules.pickle",
+  ]
+
+  args = [
+    "--idl-files-list",
+    rebase_path(modules_idl_files_list, root_build_dir),
+    "--write-file-only-if-changed=1",  # Always true for Ninja. FIXME: remove
+                                       # when everything switched to GN.
+    "--",
+    rebase_path("$bindings_core_output_dir/GlobalObjectsCore.pickle", root_build_dir),
+    rebase_path("$bindings_modules_output_dir/GlobalObjectsModules.pickle", root_build_dir),
+  ]
+}
+
+# GYP version: Source/bindings/modules/generated.gyp:modules_core_global_constructors_idls
+action("modules_core_global_constructors_idls") {
+  script = "../scripts/generate_global_constructors.py"
+
+  inputs = [
+    "../scripts/generate_global_constructors.py",
+    "../scripts/utilities.py",
+    "$bindings_modules_output_dir/GlobalObjectsModules.pickle",
+    core_idl_files_list,
+  ] + core_idl_files
+
+  outputs = modules_core_global_constructors_generated_idl_files
+    + modules_core_global_constructors_generated_header_files
+
+  args = [
+    "--idl-files-list",
+    rebase_path(core_idl_files_list, root_build_dir),
+    "--global-objects-file",
+    rebase_path("$bindings_modules_output_dir/GlobalObjectsModules.pickle", root_build_dir),
+    "--write-file-only-if-changed=1",  # Always true for Ninja.
+    "--",
+    "ServiceWorkerGlobalScope",
+    rebase_path("$blink_modules_output_dir/ServiceWorkerGlobalScopeCoreConstructors.idl", root_build_dir),
+  ]
+
+  deps = [ ":modules_global_objects" ]
+}
+
+# GYP version: Source/bindings/modules/generated.gyp:modules_global_constructors_idls
+action("modules_global_constructors_idls") {
+  script = "../scripts/generate_global_constructors.py"
+
+  inputs = [
+    "../scripts/generate_global_constructors.py",
+    "../scripts/utilities.py",
+    "$bindings_modules_output_dir/GlobalObjectsModules.pickle",
+    modules_idl_files_list,
+  ] + modules_idl_files
+
+  outputs = modules_global_constructors_generated_idl_files
+    + modules_global_constructors_generated_header_files
+
+  args = [
+    "--idl-files-list",
+    rebase_path(modules_idl_files_list, root_build_dir),
+    "--global-objects-file",
+    rebase_path("$bindings_modules_output_dir/GlobalObjectsModules.pickle", root_build_dir),
+    "--write-file-only-if-changed=1",  # Always true for Ninja.
+    "--",
+    "Window",
+    rebase_path("$blink_modules_output_dir/WindowModulesConstructors.idl", root_build_dir),
+    "SharedWorkerGlobalScope",
+    rebase_path("$blink_modules_output_dir/SharedWorkerGlobalScopeModulesConstructors.idl",
+                root_build_dir),
+    "DedicatedWorkerGlobalScope",
+    rebase_path("$blink_modules_output_dir/DedicatedWorkerGlobalScopeModulesConstructors.idl",
+                root_build_dir),
+    "ServiceWorkerGlobalScope",
+    rebase_path("$blink_modules_output_dir/ServiceWorkerGlobalScopeModulesConstructors.idl",
+                root_build_dir),
+  ]
+
+  deps = [ ":modules_global_objects" ]
+}