Update bindings gn files for binding modularization.

Source/bindings/core/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//third_party/WebKit/Source/bindings/core/core.gni")
 import("//third_party/WebKit/Source/bindings/core/idl.gni")
 import("//third_party/WebKit/Source/bindings/scripts/scripts.gni")
 
 visibility = [ "//third_party/WebKit/*" ]
 
+core_idl_files_list = "$target_gen_dir/core_idl_files.tmp"
+write_file(core_idl_files_list,
+           rebase_path(core_idl_files, root_build_dir))
+
 # GYP version: Source/bindings/core/generated.gyp:interfaces_info_individual_core
 compute_interfaces_info_individual("interfaces_info_individual_core") {
   sources_static = core_static_idl_files
   sources_generated = core_generated_idl_files
   output_file =
     "$bindings_core_output_dir/InterfacesInfoCoreIndividual.pickle"
+  deps = [
+    "//third_party/WebKit/Source/bindings/core:core_global_constructors_idls",
+  ]
 }
+
+# GYP version: Source/bindings/core/generated.gyp:core_global_objects
+action("core_global_objects") {
+  script = "../scripts/compute_global_objects.py"
+
+  inputs = [
+    "../scripts/utilities.py",
+    core_idl_files_list,
+  ] + core_idl_files
+
+  outputs = [
+    "$bindings_core_output_dir/GlobalObjectsCore.pickle",
+  ]
+
+  args = [
+    "--idl-files-list",
+    rebase_path(core_idl_files_list, root_build_dir),
+    "--write-file-only-if-changed=1",  # Always true for Ninja. FIXME: remove
+                                       # when everything switched to GN.
+    "--",
+    rebase_path("$bindings_core_output_dir/GlobalObjectsCore.pickle", root_build_dir),
+  ]
+}
+
+# GYP version: Source/bindings/core/generated.gyp:core_global_constructors_idls
+action("core_global_constructors_idls") {
+  script = "../scripts/generate_global_constructors.py"
+
+  inputs = [
+    "../scripts/generate_global_constructors.py",
+    "../scripts/utilities.py",
+    "$bindings_core_output_dir/GlobalObjectsCore.pickle",
+    # Only includes main IDL files (exclude dependencies and testing,
+    # which should not appear on global objects).
+    core_idl_files_list,
+  ] + core_idl_files
+
+  outputs = core_global_constructors_generated_idl_files +
+    core_global_constructors_generated_header_files
+
+  args = [
+    "--idl-files-list",
+    rebase_path(core_idl_files_list, root_build_dir),
+    "--global-objects-file",
+    rebase_path("$bindings_core_output_dir/GlobalObjectsCore.pickle", root_build_dir),
+    "--write-file-only-if-changed=1",  # Always true for Ninja.
+    "--",
+    "Window",
+    rebase_path("$blink_core_output_dir/WindowCoreConstructors.idl", root_build_dir),
+    "SharedWorkerGlobalScope",
+    rebase_path("$blink_core_output_dir/SharedWorkerGlobalScopeCoreConstructors.idl",
+                root_build_dir),
+    "DedicatedWorkerGlobalScope",
+    rebase_path("$blink_core_output_dir/DedicatedWorkerGlobalScopeCoreConstructors.idl",
+                root_build_dir),
+  ]
+
+  deps = [ ":core_global_objects" ]
+}