ui/gfx/color_profile: implement GetDisplayColorProfile on mac

ui/gfx/color_profile_mac.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "ui/gfx/color_profile.h"
 
 #include "base/mac/mac_util.h"
+#include "base/mac/sdk_forward_declarations.h"
+#include "ui/gfx/mac/coordinate_conversion.h"
+
+namespace {
+
+NSScreen* GetNSScreenFromBounds(const gfx::Rect& bounds) {
+  NSScreen* screen = NULL;
+  int overlap = 0;
+
+  for (NSScreen* monitor in [NSScreen screens]) {
+    gfx::Rect monitor_rect = gfx::ScreenRectFromNSRect([monitor frame]);
+    gfx::Rect overlap_rect = gfx::IntersectRects(monitor_rect, bounds);
+    int overlap_size = overlap_rect.width() * overlap_rect.height();
+    if (overlap_size > overlap) {
+      overlap = overlap_size;
+      screen = monitor;
+    }
+  }
+
+  return screen;
+}
+
+}  // namespace
 
 namespace gfx {
 
 bool GetDisplayColorProfile(const gfx::Rect& bounds,
                             std::vector<char>* profile) {
-  if (bounds.IsEmpty())
+  DCHECK(profile->empty());
+
+  NSScreen* screen = GetNSScreenFromBounds(bounds);
+  if (!screen || bounds.IsEmpty())
     return false;
-  // TODO(noel): implement.
-  return false;
+  NSColorSpace* color_space = [screen colorSpace];
+  if (!color_space)
+    return false;
+
+  if ([color_space isEqual:[NSColorSpace sRGBColorSpace]])
+    return true;

[Robert Sesek, 2014/10/06 17:56:00]

Why do this and not assign the profile data?

[Noel Gordon, 2014/10/07 01:57:43]

The sRGB profile is common, and renderers can interpolate one without assistance
from the browser. To save sending sRGB profiles to all renderers, it is
communicated to them with an empty color profile, see:

https://code.google.com/p/chromium/codesearch#chromium/src/content/common/vie...

[Robert Sesek, 2014/10/07 14:20:10]

That's kind of an odd thing to bake into this API, but it looks like it's what
the Windows implementation does too. This should definitely be documented in the
header.

+  NSData* profile_data = [color_space ICCProfileData];
+  if (const char* data = (char *)[profile_data bytes])

[Robert Sesek, 2014/10/06 17:56:00]

C-style casts are banned.

http://google-styleguide.googlecode.com/svn/trunk/cppguide.html#Casting

[Noel Gordon, 2014/10/07 01:57:43]

Done.

+    profile->assign(data, data + [profile_data length]);
+  size_t length = profile->size();
+  if (gfx::InvalidColorProfileLength(length))

[Robert Sesek, 2014/10/06 17:56:00]

Why not check the length before assigning into the vector?

[Noel Gordon, 2014/10/07 01:57:43]

Done.

+    profile->clear();
+  return true;
 }
 
 void ReadColorProfile(std::vector<char>* profile) {
   CGColorSpaceRef monitor_color_space(base::mac::GetSystemColorSpace());
   base::ScopedCFTypeRef<CFDataRef> icc_profile(
       CGColorSpaceCopyICCProfile(monitor_color_space));
   if (!icc_profile)
     return;
   size_t length = CFDataGetLength(icc_profile);
   if (gfx::InvalidColorProfileLength(length))
     return;
   const unsigned char* data = CFDataGetBytePtr(icc_profile);
   profile->assign(data, data + length);
 }
 
 }  // namespace gfx