mojom: Add associative arrays to the mojom language.

mojo/public/tools/bindings/mojom.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 # Generate C++ and JavaScript source files from mojom files. The output files
 # will go under the generated file directory tree with the same path as each
 # input file.
 #
 # Parameters:
 #
 #   sources (required)
 #       List of source .mojom files to compile.
 #
 #   deps (optional)
 #
 #   public_deps (optional)
 #
 #   testonly (optional)
 #
 #   visibility (optional)
+#
+#   generators (optional)
+#       List of languages to generate object files for.
 template("mojom") {
   assert(defined(invoker.sources),
          "\"sources\" must be defined for the $target_name template.")
 
   generator_root = "//mojo/public/tools/bindings"
   generator_script = "$generator_root/mojom_bindings_generator.py"
   generator_sources = [
     generator_script,
     "$generator_root/generators/cpp_templates/enum_declaration.tmpl",
     "$generator_root/generators/cpp_templates/interface_declaration.tmpl",
@@ skipping 49 matching lines @@
     "{{source_gen_dir}}/{{source_name_part}}_mojom.py",
   ]
 
   if (defined(invoker.visibility)) {
     # Need to save this because the the target_name is overwritten inside the
     # action to be that of the action itself. Only define this in the case the
     # var is used to avoid unused var error.
     target_visibility = [ ":$target_name" ]
   }
 
+  # Work around gn requiring all outputs to be used; there are some branches
+  # through the if branches below where these variables may otherwise be unused.
+  assert(generator_cpp_outputs != [])
+  assert(generator_js_outputs != [])
+  assert(generator_python_outputs != [])
+
   generator_target_name = target_name + "__generator"
   action_foreach(generator_target_name) {
     if (defined(invoker.visibility)) {
       visibility = target_visibility + invoker.visibility
     }
     script = generator_script
     inputs = generator_sources
     sources = invoker.sources
-    outputs = generator_cpp_outputs +
-              generator_js_outputs +
-              generator_python_outputs
+    outputs = []
+    generator_string = ""
+    if (defined(invoker.generators)) {
+      generator_string = "--generators="
+      first_item = true
+      foreach (item, invoker.generators) {
+        if (first_item) {
+          first_item = false
+        } else {
+          generator_string += ","
+        }
+
+        generator_string += item
+        if (item == "c++") {
+          outputs += generator_cpp_outputs
+        } else if (item == "javascript") {
+          outputs += generator_js_outputs
+        } else if (item == "python") {
+          outputs += generator_python_outputs
+        }
+      }
+    } else {
+      outputs = generator_cpp_outputs +
+                generator_js_outputs +
+                generator_python_outputs
+    }
+
     args = [
       "{{source}}",
+    ]
+
+    if (generator_string != "") {
+      args += [ generator_string ]
+    }
+
+    args += [
       "--use_chromium_bundled_pylibs",
       "-d", rebase_path("//", root_build_dir),
       "-I", rebase_path("//", root_build_dir),
       "-o", "{{source_gen_dir}}",
     ]
   }
 
   source_set(target_name) {
     if (defined(invoker.visibility)) {
       visibility = invoker.visibility
     }
     if (defined(invoker.testonly)) {
       testonly = invoker.testonly
     }
     sources = process_file_template(invoker.sources, generator_cpp_outputs)
     data = process_file_template(invoker.sources, generator_js_outputs)
     deps = [
       ":$generator_target_name",
       "//mojo/public/cpp/bindings",
     ]
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
     if (defined(invoker.public_deps)) {
       public_deps = invoker.public_deps
     }
   }
 }