mac: Refactor tab strip layout logic.

chrome/browser/ui/cocoa/browser_window_layout.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/browser_window_layout.h"
 
+#include <string.h>
+
 #include "base/logging.h"
+#import "chrome/browser/ui/cocoa/tabs/tab_strip_controller.h"
 
 namespace chrome {
 
 const CGFloat kTabStripHeight = 37;
 
 }  // namespace chrome
 
 namespace {
 
 // Insets for the location bar, used when the full toolbar is hidden.
 // TODO(viettrungluu): We can argue about the "correct" insetting; I like the
 // following best, though arguably 0 inset is better/more correct.
 const CGFloat kLocBarLeftRightInset = 1;
 const CGFloat kLocBarTopInset = 0;
 const CGFloat kLocBarBottomInset = 1;
 
+// Space between the incognito badge and the right edge of the window.
+const CGFloat kAvatarRightOffset = 4;
+
 }  // namespace
 
 @interface BrowserWindowLayout ()
 
 // Computes the y offset to use when laying out the tab strip in fullscreen
 // mode.
 - (void)computeFullscreenYOffset;
 
 // Computes the layout of the tab strip.
 - (void)computeTabStripLayout;
@@ skipping 40 matching lines @@
 }
 
 - (void)setFullscreenToolbarFraction:(CGFloat)toolbarFraction {
   parameters_.toolbarFraction = toolbarFraction;
 }
 
 - (void)setHasTabStrip:(BOOL)hasTabStrip {
   parameters_.hasTabStrip = hasTabStrip;
 }
 
+- (void)setFullscreenButtonFrame:(NSRect)frame {
+  parameters_.fullscreenButtonFrame = frame;
+}
+
+- (void)setShouldShowAvatar:(BOOL)shouldShowAvatar {
+  parameters_.shouldShowAvatar = shouldShowAvatar;
+}
+
+- (void)setShouldUseNewAvatar:(BOOL)shouldUseNewAvatar {
+  parameters_.shouldUseNewAvatar = shouldUseNewAvatar;
+}
+
+- (void)setAvatarSize:(NSSize)avatarSize {
+  parameters_.avatarSize = avatarSize;
+}
+
+- (void)setAvatarLineWidth:(BOOL)avatarLineWidth {
+  parameters_.avatarLineWidth = avatarLineWidth;
+}
+
 - (void)setHasToolbar:(BOOL)hasToolbar {
   parameters_.hasToolbar = hasToolbar;
 }
 
 - (void)setHasLocationBar:(BOOL)hasLocationBar {
   parameters_.hasLocationBar = hasLocationBar;
 }
 
 - (void)setToolbarHeight:(CGFloat)toolbarHeight {
   parameters_.toolbarHeight = toolbarHeight;
@@ skipping 39 matching lines @@
         // the floating bar and the extra offset needed to dodge the menu bar.
         yOffset += std::floor((1 - parameters_.toolbarFraction) *
                               [self fullscreenBackingBarHeight]);
         break;
     }
   }
   fullscreenYOffset_ = yOffset;
 }
 
 - (void)computeTabStripLayout {
-  if (parameters_.hasTabStrip) {
-    maxY_ = parameters_.windowSize.height + fullscreenYOffset_;
-    CGFloat width = parameters_.contentViewSize.width;
-    output_.tabStripFrame = NSMakeRect(
-        0, maxY_ - chrome::kTabStripHeight, width, chrome::kTabStripHeight);
-    maxY_ = NSMinY(output_.tabStripFrame);
-  } else {
+  if (!parameters_.hasTabStrip) {
     maxY_ = parameters_.contentViewSize.height + fullscreenYOffset_;
+    return;
   }
+
+  // Temporary variable to hold the output.
+  chrome::TabStripLayout layout = {};
+
+  // Lay out the tab strip.
+  maxY_ = parameters_.windowSize.height + fullscreenYOffset_;
+  CGFloat width = parameters_.contentViewSize.width;
+  layout.frame = NSMakeRect(
+      0, maxY_ - chrome::kTabStripHeight, width, chrome::kTabStripHeight);
+  maxY_ = NSMinY(layout.frame);
+
+  // In Yosemite fullscreen, manually add the traffic light buttons to the tab
+  // strip.
+  layout.addCustomWindowControls =
+      parameters_.inAnyFullscreen && base::mac::IsOSYosemiteOrLater();
+
+  // Set left indentation based on fullscreen mode status.
+  if (!parameters_.inAnyFullscreen || layout.addCustomWindowControls)
+    layout.leftIndent = [TabStripController defaultLeftIndentForControls];
+
+  // Lay out the icognito/avatar badge because calculating the indentation on
+  // the right depends on it.
+  if (parameters_.shouldShowAvatar) {
+    CGFloat badgeXOffset = -kAvatarRightOffset;
+    CGFloat badgeYOffset = 0;
+    CGFloat buttonHeight = parameters_.avatarSize.height;
+
+    if (parameters_.shouldUseNewAvatar) {
+      // The fullscreen icon is displayed to the right of the avatar button.
+      if (!parameters_.inAnyFullscreen &&
+          !NSIsEmptyRect(parameters_.fullscreenButtonFrame)) {
+        badgeXOffset -= width - NSMinX(parameters_.fullscreenButtonFrame);
+      }
+      // Center the button vertically on the tabstrip.
+      badgeYOffset = (chrome::kTabStripHeight - buttonHeight) / 2;
+    } else {
+      // Actually place the badge *above* |maxY|, by +2 to miss the divider.
+      badgeYOffset = 2 * parameters_.avatarLineWidth;
+    }
+
+    NSSize size = NSMakeSize(parameters_.avatarSize.width,
+                             std::min(buttonHeight, chrome::kTabStripHeight));
+    NSPoint origin =
+        NSMakePoint(width - parameters_.avatarSize.width + badgeXOffset,
+                    maxY_ + badgeYOffset);
+    layout.avatarFrame =
+        NSMakeRect(origin.x, origin.y, size.width, size.height);
+  }
+
+  // Calculate the right indentation. The default indentation built into the
+  // tabstrip leaves enough room for the fullscreen button on Lion (10.7) to
+  // Mavericks (10.9). On 10.6 and >=10.10, the right indent needs to be
+  // adjusted to make room for the new tab button when an avatar is present.
+  CGFloat rightIndent = 0;
+  if (!parameters_.inAnyFullscreen &&
+      !NSIsEmptyRect(parameters_.fullscreenButtonFrame)) {
+    rightIndent = width - NSMinX(parameters_.fullscreenButtonFrame);
+
+    if (parameters_.shouldUseNewAvatar) {
+      // The new avatar button is to the left of the fullscreen button.
+      // (The old avatar button is to the right).
+      rightIndent += parameters_.avatarSize.width + kAvatarRightOffset;
+    }
+  } else if (parameters_.shouldShowAvatar) {
+    rightIndent += parameters_.avatarSize.width + kAvatarRightOffset;
+  }
+  layout.rightIndent = rightIndent;
+
+  output_.tabStripLayout = layout;
 }
 
 - (void)computeContentViewLayout {
   chrome::LayoutParameters parameters = parameters_;
   CGFloat maxY = maxY_;
 
   // Sanity-check |maxY|.
   DCHECK_GE(maxY, 0);
   DCHECK_LE(maxY, parameters_.contentViewSize.height + fullscreenYOffset_);
 
@@ skipping 77 matching lines @@
     minY = NSMaxY(output_.downloadShelfFrame);
   }
 
   if (parameters_.inAnyFullscreen &&
       parameters_.slidingStyle == fullscreen_mac::OMNIBOX_TABS_PRESENT) {
     // If in Canonical Fullscreen, content should be shifted down by an amount
     // equal to all the widgets and views at the top of the window. It should
     // not be further shifted by the appearance/disappearance of the AppKit
     // menu bar.
     maxY = parameters_.windowSize.height;
-    maxY -= NSHeight(output_.toolbarFrame) + NSHeight(output_.tabStripFrame) +
+    maxY -= NSHeight(output_.toolbarFrame) +
+            NSHeight(output_.tabStripLayout.frame) +
             NSHeight(output_.bookmarkFrame) + parameters.infoBarHeight;
   }
 
   // All the remaining space becomes the frame of the content area.
   output_.contentAreaFrame = NSMakeRect(0, minY, width, maxY - minY);
 }
 
 - (CGFloat)fullscreenBackingBarHeight {
   if (!parameters_.inAnyFullscreen)
     return 0;
@@ skipping 10 matching lines @@
   }
 
   if (!parameters_.bookmarkBarHidden &&
       !parameters_.placeBookmarkBarBelowInfoBar)
     totalHeight += parameters_.bookmarkBarHeight;
 
   return totalHeight;
 }
 
 @end