Mac global keybindings

chrome/browser/extensions/global_shortcut_listener_mac.mm

+// Copyright (c) 2013 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+#include "chrome/browser/extensions/global_shortcut_listener_mac.h"
+
+#include <ApplicationServices/ApplicationServices.h>
+#import <Cocoa/Cocoa.h>
+#include <IOKit/hidsystem/ev_keymap.h>
+
+#include "content/public/browser/browser_thread.h"
+#include "ui/base/accelerators/accelerator.h"
+#include "ui/events/event.h"
+#import "ui/events/keycodes/keyboard_code_conversion_mac.h"
+
+using content::BrowserThread;
+using extensions::GlobalShortcutListenerMac;
+
+namespace {
+
+// The media keys subtype.
+const int SYSTEM_DEFINED_EVENT_MEDIA_KEYS = 8;

[Robert Sesek, 2013/11/21 16:29:56]

naming: kSystemDefinedEventMediaKeys

[smus, 2013/11/22 02:06:38]

Done.

+
+// Processed events should propagate if they aren't handled by any listeners.
+// For events that don't matter, this handler should return as quickly as
+// possible.
+// Returning event causes the event to propagate to other applications.
+// Returning NULL prevents the event from propagating.
+CGEventRef EventTapCallback(
+    CGEventTapProxy proxy, CGEventType type, CGEventRef event, void* refcon) {
+  NSAutoreleasePool* pool = [NSAutoreleasePool new];

[Robert Sesek, 2013/11/21 16:29:56]

You don't need to provide an autorelease pool here. And then I think you can
remove out_event, too, and just return |event|.

[smus, 2013/11/22 02:06:38]

Done.

+  CGEventRef out_event = event;
+
+  GlobalShortcutListenerMac* shortcut_listener =
+      static_cast<GlobalShortcutListenerMac*>(refcon);
+
+  // Handle the timeout case by re-enabling the tap.
+  if (type == kCGEventTapDisabledByTimeout) {
+    LOG(INFO) << "Event tap was disabled by a timeout.";
+    shortcut_listener->EnableTap();
+    return out_event;
+  }
+
+  // TODO(smus): do some error handling since eventWithCGEvent can fail.
+  NSEvent* ns_event = [NSEvent eventWithCGEvent:event];
+
+  // Ignore events that are not system defined media keys.
+  if (type != NX_SYSDEFINED ||
+      [ns_event subtype] != SYSTEM_DEFINED_EVENT_MEDIA_KEYS) {
+    return out_event;
+  }
+
+  int data1 = [ns_event data1];

[Robert Sesek, 2013/11/21 16:29:56]

-data1 returns NSInteger, not int. They are different sizes on 64-bit.

[smus, 2013/11/22 02:06:38]

Done.

+  // Ignore media keys that aren't previous, next and play/pause.
+  int key_code = ((data1 & 0xFFFF0000) >> 16);
+  if (key_code != NX_KEYTYPE_PLAY && key_code != NX_KEYTYPE_NEXT &&
+      key_code != NX_KEYTYPE_PREVIOUS && key_code != NX_KEYTYPE_FAST &&
+      key_code != NX_KEYTYPE_REWIND) {
+    return out_event;
+  }
+
+  int key_flags = (data1 & 0x0000FFFF);
+  bool is_key_pressed = (((key_flags & 0xFF00) >> 8)) == 0xA;
+
+  // If the key wasn't pressed (eg. was released), ignore this event.
+  if (!is_key_pressed)
+    return out_event;
+
+  // Now we have a media key that we care about. Send it to the caller.
+  bool was_handled = shortcut_listener->OnMediaKeyEvent(key_code);
+  // Prevent event from proagating to other apps if handled by Chrome.
+  if (was_handled)
+    out_event = NULL;
+
+  [pool drain];
+  // By default, pass the event through.
+  return out_event;
+}
+
+OSStatus HotKeyHandler(
+    EventHandlerCallRef next_handler, EventRef event, void* user_data) {
+  VLOG(0) << "HotKeyHandler fired with event: " << event;
+  // Extract the hotkey from the event.
+  EventHotKeyID hotkey_id;
+  int result = GetEventParameter(event, kEventParamDirectObject,
+      typeEventHotKeyID, NULL, sizeof(hotkey_id), NULL, &hotkey_id);
+  if (result != noErr)
+    return result;
+
+  // Callback to the parent class.

[Robert Sesek, 2013/11/21 16:29:56]

This comment isn't useful, remove.

[smus, 2013/11/22 02:06:38]

Done.

+  GlobalShortcutListenerMac* shortcut_listener =
+      static_cast<GlobalShortcutListenerMac*>(user_data);
+  shortcut_listener->OnKeyEvent(hotkey_id);
+  return noErr;
+}
+
+static base::LazyInstance<extensions::GlobalShortcutListenerMac> g_instance =
+    LAZY_INSTANCE_INITIALIZER;
+
+} // namespace
+
+namespace extensions {
+
+// static
+GlobalShortcutListener* GlobalShortcutListener::GetInstance() {
+  CHECK(BrowserThread::CurrentlyOn(BrowserThread::UI));
+  return g_instance.Pointer();
+}
+
+GlobalShortcutListenerMac::GlobalShortcutListenerMac()
+    : is_listening_(false) {
+  CHECK(BrowserThread::CurrentlyOn(BrowserThread::UI));
+}
+
+GlobalShortcutListenerMac::~GlobalShortcutListenerMac() {

[Robert Sesek, 2013/11/21 16:29:56]

What about calling StopWatchingMediaKeys()?

[smus, 2013/11/22 02:06:38]

Done.

+  if (is_listening_)
+    StopListening();
+}
+
+void GlobalShortcutListenerMac::StartListening() {
+  DCHECK(!is_listening_);  // Don't start twice.
+  DCHECK(!hotkey_ids_.empty());  // Don't start if no hotkey registered.
+  DCHECK(!id_hotkeys_.empty());
+  is_listening_ = true;
+}
+
+void GlobalShortcutListenerMac::StopListening() {
+  DCHECK(is_listening_);  // No point if we are not already listening.
+  DCHECK(hotkey_ids_.empty());  // Make sure the set is clean.
+  DCHECK(id_hotkeys_.empty());
+  is_listening_ = false;
+}
+
+void GlobalShortcutListenerMac::RegisterAccelerator(
+    const ui::Accelerator& accelerator,
+    GlobalShortcutListener::Observer* observer) {
+  VLOG(0) << "Registered keyCode: " << accelerator.key_code()
+      << ", modifiers: " << accelerator.modifiers();
+
+  // If this is the first media key registered, start the event tap.
+  if (IsMediaKey(accelerator) && !AreMediaKeysRegistered()) {
+    VLOG(0) << "Registered the first media key, so starting event tap.";
+    StartWatchingMediaKeys();
+    //[tap_ startWatchingMediaKeys];

[Robert Sesek, 2013/11/21 16:29:56]

Don't check-in dead code.

[smus, 2013/11/22 02:06:38]

Done.

+  }
+
+  // Register hotkey if they are non-media keyboard shortcuts.
+  if (!IsMediaKey(accelerator))
+    RegisterHotKey(accelerator);
+
+  // Store the hotkey-ID mappings we will need for lookup later.
+  id_hotkeys_[hotkey_id_] = accelerator;
+  hotkey_ids_[accelerator] = hotkey_id_;
+  hotkey_id_ += 1;

[Robert Sesek, 2013/11/21 16:29:56]

++hotkey_id_;

[smus, 2013/11/22 02:06:38]

Done.

+  GlobalShortcutListener::RegisterAccelerator(accelerator, observer);
+}
+
+void GlobalShortcutListenerMac::UnregisterAccelerator(
+    const ui::Accelerator& accelerator,
+    GlobalShortcutListener::Observer* observer) {
+  // Unregister the hotkey if it's a keyboard shortcut.
+  if (!IsMediaKey(accelerator))
+    UnregisterHotKey(accelerator);
+
+  // Remove hotkey from the mappings.
+  int id = hotkey_ids_[accelerator];
+  id_hotkeys_.erase(id);
+  hotkey_ids_.erase(accelerator);
+  GlobalShortcutListener::UnregisterAccelerator(accelerator, observer);
+
+  // Now if no media keys are registered, stop the media key tap.
+  if (!AreMediaKeysRegistered()) {
+    VLOG(0) << "Unregistered the last media key, stopping event tap.";
+    //[tap_ stopWatchingMediaKeys];
+    StopWatchingMediaKeys();
+  }
+}
+
+// TODO(smus): switch over to the cross-platform version of this method.
+bool GlobalShortcutListenerMac::IsMediaKey(const ui::Accelerator& accelerator) {

[Robert Sesek, 2013/11/21 16:29:56]

Implementation order should match header order.

[smus, 2013/11/22 02:06:38]

Done.

+  // Assume all keys are hot keys unless they have a modifier.
+  return accelerator.modifiers() == 0;
+}
+
+bool GlobalShortcutListenerMac::AreMediaKeysRegistered() {
+  // Iterate through registered accelerators, looking for media keys.
+  HotKeyIdMap::iterator iter;
+  for (iter = hotkey_ids_.begin(); iter != hotkey_ids_.end(); ++iter) {
+    if (IsMediaKey(iter->first))
+      return true;
+  }
+  return false;
+}
+
+bool GlobalShortcutListenerMac::OnKeyEvent(EventHotKeyID hotKeyID) {

[Robert Sesek, 2013/11/21 16:29:56]

naming: hotkey_id

Or should it really be hot_key_id? The capitalized version is HotKey, which
should translate to underscores as hot_key_X, but throughout this file it's been
written as hotkey_X.

[smus, 2013/11/22 02:06:38]

The capitalized version comes from the Carbon call RegisterEventHotKey, but
writing out all of the underscores everywhere is, I think, too verbose.  Fixed
in this instance.

[Robert Sesek, 2013/11/22 16:49:59]

If you want to write hotkey_X and not hot_key_X, then your methods should be
HotkeyX not HotKeyX. That way at least your names are consistent, and the only
inconsistency will be at the Carbon callsite.

[smus, 2013/11/22 20:48:09]

OK, moved to hot_key since HotKey is used generously in the Carbon API.

+  // Look up the accelerator based on this hot key ID.
+  VLOG(0) << "OnKeyEvent! hotKeyID: " << hotKeyID.id;
+  ui::Accelerator accelerator = id_hotkeys_[hotKeyID.id];
+  VLOG(0) << "Key code: " << accelerator.key_code() <<
+      " modifiers: " << accelerator.modifiers();

[Robert Sesek, 2013/11/21 16:29:56]

nit: stream formatting rules state that the << should be on this line and align
with the previous line's <<

http://www.chromium.org/developers/coding-style#Code_Formatting

[smus, 2013/11/22 02:06:38]

Done.

+  NotifyKeyPressed(accelerator);
+  return true;
+}
+
+bool GlobalShortcutListenerMac::OnMediaKeyEvent(int mediaKeyCode) {

[Robert Sesek, 2013/11/21 16:29:56]

naming: media_key_code

[smus, 2013/11/22 02:06:38]

Done.

+  ui::KeyboardCode keyCode = MediaKeyCodeToKeyboardCode(mediaKeyCode);

[Robert Sesek, 2013/11/21 16:29:56]

naming: keyCode

[smus, 2013/11/22 02:06:38]

Done.

+  VLOG(0) << "OnMediaKeyEvent! keyCode: " << keyCode;
+  // Create an accelerator corresponding to the keyCode.
+  ui::Accelerator accelerator(keyCode, 0);
+  // Look for a match with a bound hotkey.
+  if (hotkey_ids_.find(accelerator) != hotkey_ids_.end()) {
+    // If matched, callback to the event handling system.
+    NotifyKeyPressed(accelerator);
+    return true;
+  }
+  return false;
+}
+
+void GlobalShortcutListenerMac::EnableTap() {
+  CGEventTapEnable(event_tap_, TRUE);
+}
+
+void GlobalShortcutListenerMac::RegisterHotKey(
+    const ui::Accelerator& accelerator) {
+  VLOG(0) << "Registering hotkey. Windows keycode: " << accelerator.key_code();
+  EventHotKeyRef hotkey_ref;
+  EventHotKeyID event_hotkey_id;
+  EventHandlerUPP hotkey_function = NewEventHandlerUPP(HotKeyHandler);
+
+  EventTypeSpec event_type;
+  event_type.eventClass = kEventClassKeyboard;
+  event_type.eventKind = kEventHotKeyPressed;
+  InstallApplicationEventHandler(hotkey_function, 1, &event_type, this, NULL);
+
+  // Signature uniquely identifies the application that owns this hotkey.
+  event_hotkey_id.signature = 'chro';

[Robert Sesek, 2013/11/21 16:29:56]

You should use rimZ:

https://code.google.com/p/chromium/codesearch#chromium/src/chrome/chrome.gyp&...

[smus, 2013/11/22 02:06:38]

Done.

+  event_hotkey_id.id = hotkey_id_;
+
+  // Translate ui::Accelerator modifiers to cmdKey, altKey, etc.
+  int modifiers = 0;
+  modifiers += (accelerator.IsShiftDown() ? shiftKey : 0);
+  modifiers += (accelerator.IsCtrlDown() ? controlKey : 0);
+  modifiers += (accelerator.IsAltDown() ? optionKey : 0);
+  modifiers += (accelerator.IsCmdDown() ? cmdKey : 0);
+
+  unichar character;
+  unichar character_nomods;
+  int key_code = ui::MacKeyCodeForWindowsKeyCode(accelerator.key_code(), 0,
+      &character, &character_nomods);
+  VLOG(0) << "RegisterHotKey. Code: " << key_code << " modifier: " << modifiers;
+
+  // Register the event hot key.
+  RegisterEventHotKey(key_code, modifiers, event_hotkey_id,
+      GetApplicationEventTarget(), 0, &hotkey_ref);
+
+  // Note: hotkey_id_ will be incremented in the caller (RegisterAccelerator).
+  id_hotkey_refs_[hotkey_id_] = hotkey_ref;
+}
+
+void GlobalShortcutListenerMac::UnregisterHotKey(
+    const ui::Accelerator& accelerator) {
+  // Get the ref corresponding to this accelerator.
+  int id = hotkey_ids_[accelerator];
+  EventHotKeyRef ref = id_hotkey_refs_[id];
+  // Unregister the event hot key.
+  UnregisterEventHotKey(ref);
+
+  // Remove the event from the mapping.
+  id_hotkey_refs_.erase(id);
+}
+
+void GlobalShortcutListenerMac::StartWatchingMediaKeys() {
+  VLOG(0) << "StartWatchingMediaKeys";
+  // Make sure there's no existing event tap.
+  DCHECK(event_tap_ == NULL);
+
+  // Add an event tap to intercept the system defined media key events.
+  event_tap_ = CGEventTapCreate(kCGSessionEventTap,
+      kCGHeadInsertEventTap,
+      kCGEventTapOptionDefault,
+      CGEventMaskBit(NX_SYSDEFINED),
+      EventTapCallback,
+      this);
+  if (event_tap_ == NULL) {
+    LOG(ERROR) << "Error: failed to create event tap.";
+    return;
+  }
+
+  event_tap_source_ = CFMachPortCreateRunLoopSource(kCFAllocatorSystemDefault,
+      event_tap_, 0);
+  if (event_tap_source_ == NULL) {
+    LOG(ERROR) << "Error: failed to create new run loop source.";
+    return;
+  }
+
+  CFRunLoopAddSource(CFRunLoopGetCurrent(), event_tap_source_,
+      kCFRunLoopCommonModes);
+}
+
+void GlobalShortcutListenerMac::StopWatchingMediaKeys() {
+  VLOG(0) << "StopWatchingMediaKeys";
+  // Invalidate the event tap.
+  DCHECK(event_tap_ != NULL);
+  CFMachPortInvalidate(event_tap_);
+  CFRelease(event_tap_);
+  event_tap_ = NULL;
+
+  // Release the event tap source.
+  DCHECK(event_tap_source_ != NULL);
+  CFRelease(event_tap_source_);
+  event_tap_source_ = NULL;
+}
+

[Robert Sesek, 2013/11/21 16:29:56]

nit: double blank line

[smus, 2013/11/22 02:06:38]

Done.

+
+ui::KeyboardCode GlobalShortcutListenerMac::MediaKeyCodeToKeyboardCode(
+    int keyCode) {
+  switch (keyCode) {
+    case NX_KEYTYPE_PLAY:
+      return ui::VKEY_MEDIA_PLAY_PAUSE;
+    case NX_KEYTYPE_PREVIOUS:
+    case NX_KEYTYPE_REWIND:
+      return ui::VKEY_MEDIA_PREV_TRACK;
+    case NX_KEYTYPE_NEXT:
+    case NX_KEYTYPE_FAST:
+      return ui::VKEY_MEDIA_NEXT_TRACK;
+  }
+  return ui::VKEY_UNKNOWN;
+}
+
+}  // namespace extensions