Make gn check //mojo/public/* pass

mojo/public/c/system/BUILD.gn

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
-source_set("system") {
+# Depend on this target to use the types etc defined in the system without
+# linking against a specific implementation of the system. To link against a
+# particular implementation, use the :for_component or
+# :for_shared_library targets, depending on the type of target you are.
+source_set("headers") {
   sources = [
-    "../../platform/native/system_thunks.cc",
     "../../platform/native/system_thunks.h",
     "buffer.h",
     "core.h",
     "data_pipe.h",
     "functions.h",
     "macros.h",
     "message_pipe.h",
     "system_export.h",
     "types.h",
   ]
-  defines = [ "MOJO_SYSTEM_IMPLEMENTATION" ]
-
-  # The GYP target analogous to this one builds this code into a
-  # static library.  When building for Android, both the GYP and GN
-  # builds add --exclude-libs=ALL globally, which means that all
-  # symbols in static libraries are excluded from export.  That's a
-  # problem, as code outside this target needs to be able to call
-  # MojoSetSystemThunks(). Therefore, the GYP target needs to specifiy
-  # that all dependent targets remove that link flag. Since GN uses a
-  # source_set here, this flag change is not needed.
 }
 
 # In an is_component_build build, everything can link against //mojo/system
 # because it is built as a shared library. However, in a static build,
 # //mojo/system is linked into an executable (e.g., mojo_shell), and must be
 # injected into other shared libraries (i.e., Mojo Apps) that need the mojo
 # system API.
 #
 # For component targets, add //mojo/public/c/system:for_component to your deps
 # section.
 #
 # For shared_library targets (e.g., a Mojo App), add
 # //mojo/public/c/system:for_shared_library to your deps
 
 group("for_shared_library") {
+  public_deps = [ ":headers" ]
   if (is_component_build) {
     deps = [ "//mojo/system" ]
   } else {
     deps = [ ":system" ]
   }
 }
 
 group("for_component") {
+  public_deps = [ ":headers" ]
   if (is_component_build) {
     deps = [ "//mojo/system" ]
   }
 }
+
+source_set("system") {

[viettrungluu, 2014/09/25 00:36:21]

Maybe it'd be more consistent (with the pattern for the other directories) to
keep "headers" as "system", and call this something else?

(E.g., a NaCl app would want to depend on the headers, but not this.)

+  visibility = [ ":for_component", ":for_shared_library", "//mojo/public" ]
+
+  sources = [
+    "../../platform/native/system_thunks.cc",
+  ]
+  defines = [ "MOJO_SYSTEM_IMPLEMENTATION" ]
+  deps = [ ":headers" ]
+
+  # The GYP target analogous to this one builds this code into a
+  # static library.  When building for Android, both the GYP and GN
+  # builds add --exclude-libs=ALL globally, which means that all
+  # symbols in static libraries are excluded from export.  That's a
+  # problem, as code outside this target needs to be able to call
+  # MojoSetSystemThunks(). Therefore, the GYP target needs to specifiy
+  # that all dependent targets remove that link flag. Since GN uses a
+  # source_set here, this flag change is not needed.
+}
+
+