Disable the create button when the "Application folder" option is unchecked on Mac

chrome/browser/web_applications/web_app_mac.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/web_applications/web_app_mac.h"
 
 #import <Carbon/Carbon.h>
 #import <Cocoa/Cocoa.h>
 
 #include "base/command_line.h"
@@ skipping 536 matching lines @@
     };
     [document_types addObject:type_dictionary];
   }
 
   [plist setObject:document_types
             forKey:app_mode::kCFBundleDocumentTypesKey];
 }
 
 }  // namespace
 
+@interface CrCreateAppShortcutCheckboxObserver : NSObject {
+ @private
+  NSButton* checkbox_;
+  NSButton* continueButton_;
+}
+
+- (id)initWithCheckbox:(NSButton*)checkbox
+    withContinueButton:(NSButton*)continueButton;

[tapted, 2014/09/07 23:54:06]

nit: withContinueButton -> continueButton

+- (void)startObserving;
+- (void)stopObserving;
+@end
+
+@implementation CrCreateAppShortcutCheckboxObserver
+
+- (id)initWithCheckbox:(NSButton*)checkbox
+    withContinueButton:(NSButton*)continueButton {
+  if ((self = [super init])) {
+    checkbox_ = checkbox;
+    continueButton_ = continueButton;
+  }
+  return self;
+}
+
+- (void)startObserving {
+  [checkbox_ addObserver:self
+              forKeyPath:@"cell.state"
+                 options:0
+                 context:nil];
+}
+
+- (void)stopObserving {
+  [checkbox_ removeObserver:self
+                 forKeyPath:@"cell.state"];
+}
+
+- (void)observeValueForKeyPath:(NSString*)keyPath
+                      ofObject:(id)object
+                        change:(NSDictionary*)change
+                       context:(void*)context {
+  [continueButton_ setEnabled:([checkbox_ state] == NSOnState)];
+}
+
+@end // @implementation CrCreateAppShortcutCheckboxObserver

[tapted, 2014/09/07 23:54:06]

nit: remove comment - it's not typical to add it for new ObjC code

+
 namespace web_app {
 
 WebAppShortcutCreator::WebAppShortcutCreator(
     const base::FilePath& app_data_dir,
     const ShortcutInfo& shortcut_info,
     const extensions::FileHandlersInfo& file_handlers_info)
     : app_data_dir_(app_data_dir),
       info_(shortcut_info),
       file_handlers_info_(file_handlers_info) {}
 
@@ skipping 411 matching lines @@
   [alert setMessageText:l10n_util::GetNSString(IDS_CREATE_SHORTCUTS_LABEL)];
   [alert setAlertStyle:NSInformationalAlertStyle];
 
   base::scoped_nsobject<NSButton> application_folder_checkbox(
       [[NSButton alloc] initWithFrame:NSZeroRect]);
   [application_folder_checkbox setButtonType:NSSwitchButton];
   [application_folder_checkbox
       setTitle:l10n_util::GetNSString(IDS_CREATE_SHORTCUTS_APP_FOLDER_CHKBOX)];
   [application_folder_checkbox setState:NSOnState];
   [application_folder_checkbox sizeToFit];
+
+  base::scoped_nsobject<CrCreateAppShortcutCheckboxObserver> checkbox_observer(
+      [[CrCreateAppShortcutCheckboxObserver alloc]
+          initWithCheckbox:application_folder_checkbox
+        withContinueButton:continue_button]);
+  [checkbox_observer startObserving];
+
   [alert setAccessoryView:application_folder_checkbox];
 
   const int kIconPreviewSizePixels = 128;
   const int kIconPreviewTargetSize = 64;
   const gfx::Image* icon = shortcut_info.favicon.GetBest(
       kIconPreviewSizePixels, kIconPreviewSizePixels);
 
   if (icon && !icon->IsEmpty()) {
     NSImage* icon_image = icon->ToNSImage();
     [icon_image
         setSize:NSMakeSize(kIconPreviewTargetSize, kIconPreviewTargetSize)];
     [alert setIcon:icon_image];
   }
 
   bool dialog_accepted = false;
   if ([alert runModal] == NSAlertFirstButtonReturn &&
       [application_folder_checkbox state] == NSOnState) {
     dialog_accepted = true;
     CreateShortcuts(
         SHORTCUT_CREATION_BY_USER, ShortcutLocations(), profile, app);
   }
 
+  [checkbox_observer stopObserving];
+
   if (!close_callback.is_null())
     close_callback.Run(dialog_accepted);
 }
 
 void UpdateShortcutsForAllApps(Profile* profile,
                                const base::Closure& callback) {
   DCHECK_CURRENTLY_ON(content::BrowserThread::UI);
 
   extensions::ExtensionRegistry* registry =
       extensions::ExtensionRegistry::Get(profile);
@@ skipping 82 matching lines @@
   web_app::GetShortcutInfoForApp(
       app,
       profile,
       base::Bind(&web_app::CreateAppShortcutInfoLoaded,
                  profile,
                  app,
                  close_callback));
 }
 
 }  // namespace chrome