MinSFI: Add loader

tests/minsfi/nacl.scons

+# Copyright (c) 2014 The Native Client Authors. All rights reserved.
+# Use of this source code is governed by a BSD-style license that can be
+# found in the LICENSE file.
+
+Import('env')
+
+if 'TRUSTED_ENV' not in env:
+  Return()
+trusted_env = env['TRUSTED_ENV']
+
+if not env.Bit('bitcode') or not env.Bit('minsfi') or \
+   not trusted_env.Bit('build_x86') or trusted_env.Bit('windows'):
+  Return()
+
+def CompileSandbox(test_name, sandbox_name, ptrsize=0):
+  bc_env = env.Clone()
+  bc_env.Replace(CCFLAGS=[], LINKFLAGS=[])
+
+  name_trusted = 'test_%s_trusted' % test_name
+  name_untrusted = 'test_%s_untrusted' % test_name
+  name_untrusted_obj = '%s.o' % name_untrusted
+  srcs_trusted = [ 'test_%s.c' % test_name ]
+  srcs_untrusted = [ 'sandbox_%s.c' % sandbox_name ]

[jvoung (off chromium), 2014/09/08 23:18:47]

Might be better to just have |sandbox_name| be the name of the full source. That
way it's more greppable what's referencing the files (if someone wants to rename
the file).

[dbrazdil, 2014/09/09 00:57:53]

Done.

+
+  if ptrsize == 0:
+    ptrsize = 24 if trusted_env.Bit('build_x86_32') else 32
+
+  test_file = bc_env.ComponentObject(name_untrusted_obj, srcs_untrusted)

[jvoung (off chromium), 2014/09/08 23:18:47]

Do you need this separate ComponentObject() invocation?

Could you just pass srcs_untrusted to ComponentProgram?

[dbrazdil, 2014/09/09 00:57:53]

I do need it, actually. If I gave it straight to ComponentProgram,
the object would be given a default name (e.g. "sandbox_dummy.bc")
and that would prevent me from reusing that source file, like I do
in these tests (SCons would complain that the .bc file has multiple
definitions).

+  test_pexe = bc_env.ComponentProgram(name_untrusted, [ test_file ])
+
+  opt_ptrsize = '-minsfi-ptrsize=%d ' % ptrsize
+  opt_result = env.Command(
+      test_name + '.minsfi.bc', [test_pexe],
+      '${PNACLOPT} '
+      '-strip-debug '
+      '-minsfi-strip-tls '
+      '-pnacl-abi-simplify-preopt '
+      '-pnacl-abi-simplify-postopt '
+      '-minsfi '
+      + opt_ptrsize +
+      '${SOURCES} -o ${TARGET}')
+
+  llc_result = env.Command(
+      test_name + '.minsfi.o', [opt_result],
+      '${LLC} '
+      '${SOURCES} -o ${TARGET}')
+
+  main = trusted_env.ComponentObject(name_trusted, srcs_trusted)
+  prog = trusted_env.ComponentProgram(test_name , [llc_result, main],

[jvoung (off chromium), 2014/09/08 23:18:47]

same, might be able to just pass srcs_trusted + llc_result to ComponentProgram

[dbrazdil, 2014/09/09 00:57:53]

Done. Here's it's okay because it doesn't make sense to reuse
the same exerciser in multiple tests.

+                                      LIBS=['minsfi_runtime'])
+
+  node = env.CommandTest('%s.out' % test_name, [prog])
+  env.AddNodeToTestSuite(node,
+                         ['small_tests', 'toolchain_tests', 'minsfi_tests'],
+                         'run_minsfi_' + test_name + '_test')
+
+CompileSandbox('memory_layout', 'dummy')
+CompileSandbox('initializer', 'dummy')