Fix wifi_component build with 10.9+ SDK

components/wifi/wifi_service_mac.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "components/wifi/wifi_service.h"
 
+#include <dlfcn.h>
 #import <netinet/in.h>
 #import <CoreWLAN/CoreWLAN.h>
 #import <SystemConfiguration/SystemConfiguration.h>
 
 #include "base/bind.h"
 #include "base/mac/foundation_util.h"
 #include "base/mac/scoped_cftyperef.h"
 #include "base/mac/scoped_nsobject.h"
 #include "base/mac/sdk_forward_declarations.h"
 #include "base/message_loop/message_loop.h"
@@ skipping 76 matching lines @@
     return base::SysNSStringToUTF8(ssid);
   }
 
   // Populates |properties| from |network|.
   void NetworkPropertiesFromCWNetwork(const CWNetwork* network,
                                       NetworkProperties* properties) const;
 
   // Converts |CWSecurityMode| into onc::wifi::k{WPA|WEP}* security constant.
   std::string SecurityFromCWSecurityMode(CWSecurityMode security) const;
 
+  // Returns onc::wifi::k{WPA|WEP}* security constant supported by the
+  // |CWNetwork|.
+  std::string SecurityFromCWNetwork(const CWNetwork* network) const;
+
   // Converts |CWChannelBand| into Frequency constant.
   Frequency FrequencyFromCWChannelBand(CWChannelBand band) const;
 
   // Gets current |onc::connection_state| for given |network_guid|.
   std::string GetNetworkConnectionState(const std::string& network_guid) const;
 
   // Updates |networks_| with the list of visible wireless networks.
   void UpdateNetworks();
 
   // Find network by |network_guid| and return iterator to its entry in
@@ skipping 280 matching lines @@
   if (!networks_changed_observer_.is_null()) {
     void (^ns_observer) (NSNotification* notification) =
         ^(NSNotification* notification) {
             DVLOG(1) << "Received CWSSIDDidChangeNotification";
             task_runner_->PostTask(
                 FROM_HERE,
                 base::Bind(&WiFiServiceMac::OnWlanObserverNotification,
                            base::Unretained(this)));
     };
 
+    NSBundle* bundle = [NSBundle

[mef, 2014/09/05 17:56:22]

If anything I'd move this out into separate method, but I'd defer to rsesek in
hope for better solution.

+        bundleWithPath:@"/System/Library/Frameworks/CoreWLAN.framework"];
+    const char* path = [[bundle executablePath] fileSystemRepresentation];
+    CHECK(path);
+    void* library_handle = dlopen(path, RTLD_LAZY | RTLD_LOCAL);
+    CHECK(library_handle) << dlerror();
+
+    // Try out the symbol name for 10.7+ first, if not found use the one from
+    // 10.6 SDK.
+    void* symbol = dlsym(library_handle, "CWSSIDDidChangeNotification");
+    if (!symbol)
+      symbol = dlsym(library_handle, "kCWSSIDDidChangeNotification");

[mef, 2014/09/05 17:56:23]

Is kCWSSIDDidChangeNotification actually causing issues on 10.7+?

+    CHECK(symbol) << dlerror();
+    NSString* notification_name = *reinterpret_cast<NSString**>(symbol);
+
     wlan_observer_ = [[NSNotificationCenter defaultCenter]
-        addObserverForName:kCWSSIDDidChangeNotification
+        addObserverForName:notification_name
                     object:nil
                      queue:nil
                 usingBlock:ns_observer];
   }
 }
 
 void WiFiServiceMac::RequestConnectedNetworkUpdate() {
   OnWlanObserverNotification();
 }
 
@@ skipping 83 matching lines @@
   properties->connection_state = GetNetworkConnectionState(network_guid);
   properties->ssid = base::SysNSStringToUTF8([network ssid]);
   properties->name = properties->ssid;
   properties->guid = network_guid;
   properties->type = onc::network_type::kWiFi;
 
   properties->bssid = base::SysNSStringToUTF8([network bssid]);
   properties->frequency = FrequencyFromCWChannelBand(
       static_cast<CWChannelBand>([[network wlanChannel] channelBand]));
   properties->frequency_set.insert(properties->frequency);
-  properties->security = SecurityFromCWSecurityMode(
-      static_cast<CWSecurityMode>([[network securityMode] intValue]));
 
-  properties->signal_strength = [[network rssi] intValue];
+  if ([network respondsToSelector:@selector(supportsSecurity:)]) {
+    properties->security = SecurityFromCWNetwork(network);
+  } else {
+    properties->security = SecurityFromCWSecurityMode(
+        static_cast<CWSecurityMode>([[network securityMode] intValue]));
+  }
+
+  if ([network respondsToSelector:@selector(rssiValue:)])
+    properties->signal_strength = [network rssiValue];
+  else
+    properties->signal_strength = [[network rssi] intValue];
 }
 
 std::string WiFiServiceMac::SecurityFromCWSecurityMode(
     CWSecurityMode security) const {
   switch (security) {
     case kCWSecurityModeWPA_Enterprise:
     case kCWSecurityModeWPA2_Enterprise:
       return onc::wifi::kWPA_EAP;
     case kCWSecurityModeWPA_PSK:
     case kCWSecurityModeWPA2_PSK:
       return onc::wifi::kWPA_PSK;
     case kCWSecurityModeWEP:
       return onc::wifi::kWEP_PSK;
     case kCWSecurityModeOpen:
       return onc::wifi::kSecurityNone;
     // TODO(mef): Figure out correct mapping.
     case kCWSecurityModeWPS:
     case kCWSecurityModeDynamicWEP:
       return onc::wifi::kWPA_EAP;
   }
   return onc::wifi::kWPA_EAP;
 }
 
+std::string WiFiServiceMac::SecurityFromCWNetwork(
+    const CWNetwork* network) const {
+  if ([network supportsSecurity:kCWSecurityWPAEnterprise] ||
+      [network supportsSecurity:kCWSecurityWPA2Enterprise]) {
+    return onc::wifi::kWPA_EAP;
+  }
+
+  if ([network supportsSecurity:kCWSecurityWPAPersonal] ||
+      [network supportsSecurity:kCWSecurityWPA2Personal]) {
+    return onc::wifi::kWPA_PSK;
+  }
+
+  if ([network supportsSecurity:kCWSecurityWEP])
+    return onc::wifi::kWEP_PSK;
+
+  if ([network supportsSecurity:kCWSecurityNone])
+    return onc::wifi::kSecurityNone;
+
+  // TODO(mef): Figure out correct mapping.
+  if ([network supportsSecurity:kCWSecurityDynamicWEP])
+    return onc::wifi::kWPA_EAP;
+
+  return onc::wifi::kWPA_EAP;
+}
+
 Frequency WiFiServiceMac::FrequencyFromCWChannelBand(CWChannelBand band) const {
   return band == kCWChannelBand2GHz ? kFrequency2400 : kFrequency5000;
 }
 
 NetworkList::iterator WiFiServiceMac::FindNetwork(
     const std::string& network_guid) {
   for (NetworkList::iterator it = networks_.begin();
        it != networks_.end();
        ++it) {
     if (it->guid == network_guid)
@@ skipping 55 matching lines @@
   NetworkGuidList changed_networks(1, network_guid);
   message_loop_proxy_->PostTask(
       FROM_HERE,
       base::Bind(networks_changed_observer_, changed_networks));
 }
 
 // static
 WiFiService* WiFiService::Create() { return new WiFiServiceMac(); }
 
 }  // namespace wifi