Fix wifi_component build with 10.9+ SDK

components/wifi/wifi_service_mac.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "components/wifi/wifi_service.h"
 
 #import <netinet/in.h>
 #import <CoreWLAN/CoreWLAN.h>
 #import <SystemConfiguration/SystemConfiguration.h>
 
 #include "base/bind.h"
 #include "base/mac/foundation_util.h"
 #include "base/mac/scoped_cftyperef.h"
 #include "base/mac/scoped_nsobject.h"
 #include "base/mac/sdk_forward_declarations.h"
 #include "base/message_loop/message_loop.h"
 #include "base/strings/sys_string_conversions.h"
 #include "components/onc/onc_constants.h"
 #include "components/wifi/network_properties.h"
 
+// 10.6 SDK don't have CWSecurity while 10.9 SDK don't have CWSecurityMode, to
+// build with SDKs from 10.6 to 10.9 we need to forward declare both and do
+// runtime checks to ensure we use correct methods on different OS X versions.
+#if !defined(MAC_OS_X_VERSION_10_9) || \

[Robert Sesek, 2014/09/04 15:13:30]

Move these to base/mac/sdk_forward_declarations.h.

[Jiang Jiang, 2014/09/04 15:17:49]

Done.

+    MAC_OS_X_VERSION_MAX_ALLOWED < MAC_OS_X_VERSION_10_9
+
+enum {
+   kCWSecurityNone = 0,
+   kCWSecurityWEP = 1,
+   kCWSecurityWPAPersonal = 2,
+   kCWSecurityWPAPersonalMixed = 3,
+   kCWSecurityWPA2Personal = 4,
+   kCWSecurityPersonal = 5,
+   kCWSecurityDynamicWEP = 6,
+   kCWSecurityWPAEnterprise = 7,
+   kCWSecurityWPAEnterpriseMixed = 8,
+   kCWSecurityWPA2Enterprise = 9,
+   kCWSecurityEnterprise = 10,
+   kCWSecurityUnknown = NSIntegerMax,
+};
+
+typedef NSInteger CWSecurity;
+
+@interface CWNetwork (ForwardDeclarations)
+@property(readonly) NSInteger rssiValue;
+-(BOOL)supportsSecurity:(CWSecurity)security;

[Robert Sesek, 2014/09/04 15:13:30]

nit: space before (

[Jiang Jiang, 2014/09/04 15:17:49]

Done.

+@end
+
+#else
+
+typedef enum {
+   kCWSecurityModeOpen = 0,
+   kCWSecurityModeWEP,
+   kCWSecurityModeWPA_PSK,
+   kCWSecurityModeWPA2_PSK,
+   kCWSecurityModeWPA_Enterprise,
+   kCWSecurityModeWPA2_Enterprise,
+   kCWSecurityModeWPS,
+   kCWSecurityModeDynamicWEP
+} CWSecurityMode;
+
+@interface CWNetwork (ForwardDeclarations)
+@property(readonly) NSNumber* rssi;
+@property(readonly) NSNumber* securityMode;
+@end
+
+#endif
+
 namespace wifi {
 
 // Implementation of WiFiService for Mac OS X.
 class WiFiServiceMac : public WiFiService {
  public:
   WiFiServiceMac();
   virtual ~WiFiServiceMac();
 
   // WiFiService interface implementation.
   virtual void Initialize(
@@ skipping 62 matching lines @@
     return base::SysNSStringToUTF8(ssid);
   }
 
   // Populates |properties| from |network|.
   void NetworkPropertiesFromCWNetwork(const CWNetwork* network,
                                       NetworkProperties* properties) const;
 
   // Converts |CWSecurityMode| into onc::wifi::k{WPA|WEP}* security constant.
   std::string SecurityFromCWSecurityMode(CWSecurityMode security) const;
 
+  // Converts |CWSecurity| into onc::wifi::k{WPA|WEP}* security constant.
+  std::string SecurityFromCWNetwork(const CWNetwork* network) const;
+
   // Converts |CWChannelBand| into Frequency constant.
   Frequency FrequencyFromCWChannelBand(CWChannelBand band) const;
 
   // Gets current |onc::connection_state| for given |network_guid|.
   std::string GetNetworkConnectionState(const std::string& network_guid) const;
 
   // Updates |networks_| with the list of visible wireless networks.
   void UpdateNetworks();
 
   // Find network by |network_guid| and return iterator to its entry in
@@ skipping 281 matching lines @@
     void (^ns_observer) (NSNotification* notification) =
         ^(NSNotification* notification) {
             DVLOG(1) << "Received CWSSIDDidChangeNotification";
             task_runner_->PostTask(
                 FROM_HERE,
                 base::Bind(&WiFiServiceMac::OnWlanObserverNotification,
                            base::Unretained(this)));
     };
 
     wlan_observer_ = [[NSNotificationCenter defaultCenter]
-        addObserverForName:kCWSSIDDidChangeNotification
+        addObserverForName:CWSSIDDidChangeNotification
                     object:nil
                      queue:nil
                 usingBlock:ns_observer];
   }
 }
 
 void WiFiServiceMac::RequestConnectedNetworkUpdate() {
   OnWlanObserverNotification();
 }
 
@@ skipping 83 matching lines @@
   properties->connection_state = GetNetworkConnectionState(network_guid);
   properties->ssid = base::SysNSStringToUTF8([network ssid]);
   properties->name = properties->ssid;
   properties->guid = network_guid;
   properties->type = onc::network_type::kWiFi;
 
   properties->bssid = base::SysNSStringToUTF8([network bssid]);
   properties->frequency = FrequencyFromCWChannelBand(
       static_cast<CWChannelBand>([[network wlanChannel] channelBand]));
   properties->frequency_set.insert(properties->frequency);
-  properties->security = SecurityFromCWSecurityMode(
-      static_cast<CWSecurityMode>([[network securityMode] intValue]));
 
-  properties->signal_strength = [[network rssi] intValue];
+  if ([network respondsToSelector:@selector(supportsSecurity:)])

[Robert Sesek, 2014/09/04 15:13:30]

nit: since the else has curly braces, the if body needs them too.

[Jiang Jiang, 2014/09/04 15:17:49]

Done.

+    properties->security = SecurityFromCWNetwork(network);
+  else {
+    properties->security = SecurityFromCWSecurityMode(
+        static_cast<CWSecurityMode>([[network securityMode] intValue]));
+  }
+
+  if ([network respondsToSelector:@selector(rssiValue:)])
+    properties->signal_strength = [network rssiValue];
+  else
+    properties->signal_strength = [[network rssi] intValue];
 }
 
 std::string WiFiServiceMac::SecurityFromCWSecurityMode(
     CWSecurityMode security) const {
   switch (security) {
     case kCWSecurityModeWPA_Enterprise:
     case kCWSecurityModeWPA2_Enterprise:
       return onc::wifi::kWPA_EAP;
     case kCWSecurityModeWPA_PSK:
     case kCWSecurityModeWPA2_PSK:
       return onc::wifi::kWPA_PSK;
     case kCWSecurityModeWEP:
       return onc::wifi::kWEP_PSK;
     case kCWSecurityModeOpen:
       return onc::wifi::kSecurityNone;
     // TODO(mef): Figure out correct mapping.
     case kCWSecurityModeWPS:
     case kCWSecurityModeDynamicWEP:
       return onc::wifi::kWPA_EAP;
   }
   return onc::wifi::kWPA_EAP;
 }
 
+std::string WiFiServiceMac::SecurityFromCWNetwork(
+    const CWNetwork* network) const {
+  if ([network supportsSecurity:kCWSecurityWPAEnterprise] ||
+      [network supportsSecurity:kCWSecurityWPA2Enterprise])

[Robert Sesek, 2014/09/04 15:13:30]

nit: braces needed since condition is multi-line, same on line 600

[Jiang Jiang, 2014/09/04 15:17:49]

Done.

+    return onc::wifi::kWPA_EAP;
+
+  if ([network supportsSecurity:kCWSecurityWPAPersonal] ||
+      [network supportsSecurity:kCWSecurityWPA2Personal])
+    return onc::wifi::kWPA_PSK;
+
+  if ([network supportsSecurity:kCWSecurityWEP])
+    return onc::wifi::kWEP_PSK;
+
+  if ([network supportsSecurity:kCWSecurityNone])
+    return onc::wifi::kSecurityNone;
+
+  // TODO(mef): Figure out correct mapping.
+  if ([network supportsSecurity:kCWSecurityDynamicWEP])
+    return onc::wifi::kWPA_EAP;
+
+  return onc::wifi::kWPA_EAP;
+}
+
 Frequency WiFiServiceMac::FrequencyFromCWChannelBand(CWChannelBand band) const {
   return band == kCWChannelBand2GHz ? kFrequency2400 : kFrequency5000;
 }
 
 NetworkList::iterator WiFiServiceMac::FindNetwork(
     const std::string& network_guid) {
   for (NetworkList::iterator it = networks_.begin();
        it != networks_.end();
        ++it) {
     if (it->guid == network_guid)
@@ skipping 55 matching lines @@
   NetworkGuidList changed_networks(1, network_guid);
   message_loop_proxy_->PostTask(
       FROM_HERE,
       base::Bind(networks_changed_observer_, changed_networks));
 }
 
 // static
 WiFiService* WiFiService::Create() { return new WiFiServiceMac(); }
 
 }  // namespace wifi