Add support for Android aidl and support for gyp's java_in_dir

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//tools/grit/grit_rule.gni")
 
 assert(is_android)
 
@@ skipping 201 matching lines @@
     include_path = invoker.include_path + ""
   } else {
     include_path = "//"
   }
 
   action_foreach("${target_name}__apply_gcc") {
     script = "//build/android/gyp/gcc_preprocess.py"
     if (defined(invoker.inputs)) {
       inputs = invoker.inputs + []
     }
-    depfile = "${target_gen_dir}/${target_name}.d"
+    depfile = "${target_gen_dir}/${target_name}_{{source_name_part}}.d"

[cjhopman, 2014/08/27 18:37:59]

This path has to be unique for each source file.

 
     sources = invoker.sources
 
     gen_dir = "${target_gen_dir}/${target_name}/java_cpp_template/${package_name}"
     gcc_template_output_pattern = "${gen_dir}/{{source_name_part}}.java"
 
     outputs = [
       depfile,
       gcc_template_output_pattern
     ]
@@ skipping 165 matching lines @@
 # This target creates an Android library containing java code and Android
 # resources.
 #
 # Variables
 #   deps: Specifies the dependencies of this target. Java targets in this list
 #     will be added to the javac classpath. Android resources in dependencies
 #     will be used when building this library.
 #   java_files: List of .java files included in this library.
 #   srcjar_deps: List of srcjar dependencies. The .java files in the srcjars
 #     will be added to java_files and be included in this library.
-#   chromium_code: If true, extra static analysis warning/errors will be enabled.
+#   chromium_code: If true, extra analysis warning/errors will be enabled.
 #   jar_excluded_patterns: List of patterns of .class files to exclude from the
 #     final jar.
 #   proguard_preprocess: If true, proguard preprocessing will be run. This can
 #     be used to remove unwanted parts of the library.
 #   proguard_config: Path to the proguard config for preprocessing.
 #
+#   DEPRECATED_java_in_dir: Directory containing java files. All .java files in
+#     this directory will be included in the library. This is only supported to
+#     ease the gyp->gn conversion and will be removed in the future.
+#
 # Example
 #   android_library("foo_java") {
 #     java_files = [
 #       "android/org/chromium/foo/Foo.java",
 #       "android/org/chromium/foo/FooInterface.java",
 #       "android/org/chromium/foo/FooService.java",
 #     ]
 #     deps = [
 #       ":bar_java"
 #     ]
 #     srcjar_deps = [
 #       ":foo_generated_enum"
 #     ]
 #     jar_excluded_patterns = [
 #       "*/FooService.class", "*/FooService##*.class"
 #     ]
 #   }
 template("android_library") {
-  assert(defined(invoker.java_files))
-  base_path = "$target_gen_dir/$target_name"
-  build_config = base_path + ".build_config"
-  jar_path = base_path + ".jar"
-  dex_path = base_path + ".dex.jar"
+  assert(defined(invoker.java_files) || defined(invoker.DEPRECATED_java_in_dir))
+  _base_path = "$target_gen_dir/$target_name"
+  _build_config = _base_path + ".build_config"
+  _jar_path = _base_path + ".jar"
+  _dex_path = _base_path + ".dex.jar"
 
   write_build_config("${target_name}__build_config") {
     type = "android_library"
 
     deps = []
     if (defined(invoker.deps)) {
       deps += invoker.deps
     }
 
-    # base_path
+    build_config = _build_config
+    jar_path = _jar_path
+    dex_path = _dex_path
   }
 
   _chromium_code = true
   if (defined(invoker.chromium_code)) {
     _chromium_code = invoker.chromium_code
   }
 
   android_java_library(target_name) {
     chromium_code = _chromium_code
-    java_files = invoker.java_files
-    build_config = build_config
+    if (defined(invoker.java_files)) {
+      java_files = invoker.java_files
+    } else {
+      DEPRECATED_java_in_dir = invoker.DEPRECATED_java_in_dir
+    }
+    build_config = _build_config
+    jar_path = _jar_path
+    dex_path = _dex_path
 
     if (defined(invoker.proguard_preprocess) && invoker.proguard_preprocess) {
       proguard_preprocess = true
       proguard_config = invoker.proguard_config
     }
 
     if (defined(invoker.jar_excluded_patterns)) {
       jar_excluded_patterns = invoker.jar_excluded_patterns
     }
 
@@ skipping 85 matching lines @@
 #   java_files: List of .java files to include in the apk.
 #   srcjar_deps: List of srcjar dependencies. The .java files in the srcjars
 #      will be added to java_files and be included in this apk.
 #   apk_name: Name for final apk.
 #   final_apk_path: Path to final built apk. Default is
 #     $root_out_dir/apks/$apk_name.apk. Setting this will override apk_name.
 #   native_libs: List paths of native libraries to include in this apk. If these
 #     libraries depend on other shared_library targets, those dependencies will
 #     also be included in the apk.
 #
+#   DEPRECATED_java_in_dir: Directory containing java files. All .java files in
+#     this directory will be included in the library. This is only supported to
+#     ease the gyp->gn conversion and will be removed in the future.
+#
 # Example
 #   android_apk("foo_apk") {
 #     android_manifest = "AndroidManifest.xml"
 #     java_files = [
 #       "android/org/chromium/foo/FooApplication.java",
 #       "android/org/chromium/foo/FooActivity.java",
 #     ]
 #     deps = [
 #       ":foo_support_java"
 #       ":foo_resources"
@@ skipping 95 matching lines @@
       defines += ["ENABLE_CHROMIUM_LINKER_TESTS"]
     }
   }
   _srcjar_deps += [ ":${target_name}__native_libraries_java" ]
 
   rebased_build_config = rebase_path(build_config, root_build_dir)
 
   final_deps += [":${target_name}__java"]
   android_java_library("${target_name}__java") {
     android_manifest = invoker.android_manifest
-    java_files = invoker.java_files
+    if (defined(invoker.java_files)) {
+      java_files = invoker.java_files
+    } else {
+      DEPRECATED_java_in_dir = invoker.DEPRECATED_java_in_dir
+    }
     srcjar_deps = _srcjar_deps
     dex_path = base_path + ".dex.jar"
   }
 
   final_deps += [":${target_name}__final_dex"]
   dex("${target_name}__final_dex") {
     sources = [jar_path]
     inputs = [build_config]
     output = final_dex_path
     dex_arg_key = "${rebased_build_config}:apk_dex:dependency_dex_files"
@@ skipping 29 matching lines @@
     keystore_password = _keystore_password
 
     if (_native_libs != []) {
       native_libs_dir = _native_libs_dir
       deps = [":${_template_name}__prepare_native"]
     }
   }
 
   group(target_name) {
     deps = final_deps
+    if (defined(invoker.datadeps)) {

[newt (away), 2014/08/27 20:05:29]

where are these datadeps coming from?

[cjhopman, 2014/08/27 21:05:22]

The invoker. I added documentation above (this is a standard gn target variable,
but needs to be implemented separately for each template definition that wants
to support it).

+      datadeps = invoker.datadeps
+    }
   }
 }
 
 
 # Declare an Android gtest apk
 #
 # This target creates an Android apk for running gtest-based unittests.
 #
 # Variables
 #   deps: Specifies the dependencies of this target. These will be passed to
@@ skipping 31 matching lines @@
       "//testing/android/java/src/org/chromium/native_test/ChromeNativeTestActivity.java"
     ]
     android_manifest = "//testing/android/java/AndroidManifest.xml"
     unittests_outputs = [ unittests_binary ]
     native_libs = [unittests_outputs[0]]
     if (defined(invoker.deps)) {
       deps = invoker.deps
     }
   }
 }
+
+# Generate .java files from .aidl files.
+#
+# This target will store the .java files in a srcjar and should be included in
+# an android_library or android_apk's srcjar_deps.
+#
+# Variables

[newt (away), 2014/08/27 20:05:28]

what about interface_file?

[cjhopman, 2014/08/27 21:05:22]

Done.

+#   sources: Paths to .aidl files to compile.
+#   import_include: Paths to directories containing .java files imported by the

[newt (away), 2014/08/27 20:05:29]

s/Paths/Path ... right?

[cjhopman, 2014/08/27 21:05:22]

Done.

+#     .aidl files.
+#
+# Example
+#   android_aidl("foo_aidl") {
+#     import_include = "java/src"
+#     sources = [
+#       "java/src/com/foo/bar/FooBarService.aidl",
+#       "java/src/com/foo/bar/FooBarServiceCallback.aidl",
+#     ]
+#   }
+template("android_aidl") {
+  srcjar_path = "${target_gen_dir}/${target_name}.srcjar"
+  aidl_path = "${android_sdk_build_tools}/aidl"
+  framework_aidl = "$android_sdk/framework.aidl"
+
+  action(target_name) {
+    script = "//build/android/gyp/aidl.py"
+    sources = invoker.sources
+
+    imports = [ framework_aidl ]
+    if (defined(invoker.interface_file)) {
+      assert(invoker.interface_file != "")
+      imports += [ invoker.interface_file ]
+    }
+
+    inputs = [
+      aidl_path,
+    ] + imports
+
+    depfile = "${target_gen_dir}/${target_name}.d"
+    outputs = [
+      depfile,
+      srcjar_path
+    ]
+    rebased_imports = rebase_path(imports, root_build_dir)
+    args = [
+      "--depfile", rebase_path(depfile, root_build_dir),
+      "--aidl-path", rebase_path(aidl_path, root_build_dir),
+      "--imports=$rebased_imports",
+      "--srcjar", rebase_path(srcjar_path, root_build_dir),
+    ]
+    if (defined(invoker.import_include) && invoker.import_include != "") {
+      # TODO(cjhopman): aidl supports creating a depfile. We should be able to
+      # switch to constructing a depfile for the overall action from that
+      # instead of having all the .java files in the include paths as inputs.
+      rebased_import_includes = rebase_path(
+          [invoker.import_include], root_build_dir)
+      args += [ "--includes=$rebased_import_includes" ]
+
+      _java_files_build_rel = exec_script(
+          "//build/android/gyp/find.py",

[newt (away), 2014/08/27 20:05:29]

is the plan to get rid of this "find" after the gn switch?

[cjhopman, 2014/08/27 21:05:22]

It's complicated.

The TODO a couple lines up describes one way that we could get rid of this find.
The other option would be to make the caller explicitly specify which java files
are needed, in that case I would want to make sure that the build doesn't
actually use any unspecified java files (I have a couple thoughts on how to do
that).

The find can cause some subtle build issues (though no worse than what we have
in gyp).

+          rebase_path([invoker.import_include], root_build_dir),
+          "list lines"
+          )
+      _java_files = rebase_path(_java_files_build_rel, ".", root_build_dir)
+      inputs += _java_files
+    }
+    args += rebase_path(sources, root_build_dir)
+  }
+}