New C++ -> Java enum build rule + parser/generator.

build/config/android/rules.gni

 # Copyright 2014 The Chromium Authors. All rights reserved.
 # Use of this source code is governed by a BSD-style license that can be
 # found in the LICENSE file.
 
 import("//build/config/android/config.gni")
 import("//build/config/android/internal_rules.gni")
 import("//tools/grit/grit_rule.gni")
 
 assert(is_android)
 
@@ skipping 244 matching lines @@
     base_dir = base_gen_dir
   }
 
   group(target_name) {
     deps = [
       ":${target_name}__zip_srcjar"
     ]
   }
 }
 
+# Declare a target for generating Java classes from C++ enums.
+#
+# This target generates Java files from C++ enums using a script.
+#
+# This target will create a single .srcjar. Adding this target to an
+# android_library target's srcjar_deps will make the generated java files be
+# included in that library's final outputs.
+#
+# Variables
+#   sources: list of files to be processed by the script. For each annotated
+#     enum contained in the sources files the script will generate a .java
+#     file with the same name as the name of the enum.
+#
+#   outputs: list of outputs, relative to the target_gen_dir. These paths are
+#     verified at build time by the script. To get the list programatically run:
+#       python build/android/gyp/java_cpp_enum.py --output_dir=. \
+#         --print_output_only path/to/header/file.h
+#
+# Example
+#   java_cpp_enum("foo_generated_enum") {
+#     sources = [
+#       "src/native_foo_header.h",
+#     ]
+#     outputs = [
+#       "org/chromium/FooEnum.java",
+#     ]
+#   }
+template("java_cpp_enum") {
+  assert(defined(invoker.sources))
+  assert(defined(invoker.outputs))
+
+  action("${target_name}__generate_enum") {
+    sources = rebase_path(invoker.sources, root_build_dir)
+    script = "//build/android/gyp/java_cpp_enum.py"
+    gen_dir = "${target_gen_dir}/${target_name}/enums"
+    outputs = []
+    foreach(output, invoker.outputs) {
+      outputs += [gen_dir + "/" + output]

[mkosiba (inactive), 2014/09/03 16:27:23]

I couldn't figure out how to make rebase_path work here. I kept getting errors
like:

[brettw, 2014/09/03 21:23:38]

The thing that reads the outputs variable will interpret the paths to be
relative to the current directory. You can do that or make them absolute. I'd
do:

  rebase_path(invoker.outputs, ".", target_gen_dir)

which takes a file relative to target_gen_dir (which is what your docs say this
is) to be relative to ".". 

[mkosiba (inactive), 2014/09/04 11:31:22]

That just changes the error to:

  The given file should be in the output directory. Normally you would specify
  "$target_out_dir/foo" or "$target_gen_dir/foo". I interpreted this as
 
"../../out/Debug/gen/ui/android/window_open_disposition_srcjar__generate_enum/enums/org/chromium/ui/WindowOpenDisposition.java"

[brettw, 2014/09/08 19:56:15]

Oh, sorry. The checker doesn't know about relative paths. I made a note to fix
this.

You can wrap that call to get_path_info(rebase_path(....call from above...),
"abspath") to convert them to be absolute.

[mkosiba (inactive), 2014/09/09 09:00:12]

Ok, this seems to work although I could have sworn I'd tried that before and it
didn't....

+    }
+
+    args = [
+      "--output_dir", rebase_path(gen_dir, root_build_dir),
+    ]
+    foreach(output, invoker.outputs) {
+      args += ["--assert_file", rebase_path(output, root_build_dir, gen_dir)]
+    }
+    args += sources
+  }
+
+  generate_enum_outputs = get_target_outputs(":${target_name}__generate_enum")
+  base_gen_dir = get_label_info(":${target_name}__generate_enum",
+                                "target_gen_dir")
+
+  srcjar_path = "${target_gen_dir}/${target_name}.srcjar"
+  zip("${target_name}__zip_srcjar") {
+    inputs = generate_enum_outputs
+    output = srcjar_path
+    base_dir = base_gen_dir
+  }
+
+  group(target_name) {
+    deps = [
+      ":${target_name}__zip_srcjar"
+    ]
+  }
+}
+
 
 # Declare an Android resources target
 #
 # This creates a resources zip file that will be used when building an Android
 # library or apk and included into a final apk.
 #
 # To include these resources in a library/apk, this target should be listed in
 # the library's deps. A library/apk will also include any resources used by its
 # own dependencies.
 #
@@ skipping 495 matching lines @@
       "//testing/android/java/src/org/chromium/native_test/ChromeNativeTestActivity.java"
     ]
     android_manifest = "//testing/android/java/AndroidManifest.xml"
     unittests_outputs = [ unittests_binary ]
     native_libs = [unittests_outputs[0]]
     if (defined(invoker.deps)) {
       deps = invoker.deps
     }
   }
 }