Mac: implement DnD of URLs onto Omnibox.

chrome/browser/cocoa/tab_strip_controller.mm

 // Copyright (c) 2009 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/cocoa/tab_strip_controller.h"
 
 #import <QuartzCore/QuartzCore.h>
 
 #include <limits>
 #include <string>
@@ skipping 102 matching lines @@
 - (void)layoutTabsWithAnimation:(BOOL)animate
              regenerateSubviews:(BOOL)doUpdate;
 - (void)animationDidStopForController:(TabController*)controller
                              finished:(BOOL)finished;
 - (NSInteger)indexFromModelIndex:(NSInteger)index;
 - (NSInteger)numberOfOpenTabs;
 - (NSInteger)numberOfOpenPinnedTabs;
 - (NSInteger)numberOfOpenUnpinnedTabs;
 - (void)mouseMoved:(NSEvent*)event;
 - (void)setTabTrackingAreasEnabled:(BOOL)enabled;
-- (void)droppingURLsAt:(NSPoint)location
+- (void)droppingURLsAt:(NSPoint)point
             givesIndex:(NSInteger*)index
            disposition:(WindowOpenDisposition*)disposition;
 @end
 
 // A simple view class that prevents the Window Server from dragging the area
 // behind tabs. Sometimes core animation confuses it. Unfortunately, it can also
 // falsely pick up clicks during rapid tab closure, so we have to account for
 // that.
 @interface TabStripControllerDragBlockingView : NSView {
   TabStripController* controller_;  // weak; owns us
@@ skipping 1295 matching lines @@
       [subviews addObject:tabView];
     }
   }
   if (selectedTabView) {
     [subviews addObject:selectedTabView];
   }
   [tabStripView_ setSubviews:subviews];
   [self setTabTrackingAreasEnabled:mouseInside_];
 }
 
-// Get the index and disposition for a potential URL(s) drop given a location
-// (in window base coordinates). It considers x coordinate of the given
-// location. If it's in the "middle" of a tab, it drops on that tab. If it's to
-// the left, it inserts to the left, and similarly for the right.
-- (void)droppingURLsAt:(NSPoint)location
+// Get the index and disposition for a potential URL(s) drop given a point (in
+// the |TabStripView|'s coordinates). It considers only the x-coordinate of the
+// given point. If it's in the "middle" of a tab, it drops on that tab. If it's
+// to the left, it inserts to the left, and similarly for the right.
+- (void)droppingURLsAt:(NSPoint)point
             givesIndex:(NSInteger*)index
            disposition:(WindowOpenDisposition*)disposition {
   // Proportion of the tab which is considered the "middle" (and causes things
   // to drop on that tab).
   const double kMiddleProportion = 0.5;
   const double kLRProportion = (1.0 - kMiddleProportion) / 2.0;
 
   DCHECK(index && disposition);
   NSInteger i = 0;
   for (TabController* tab in tabArray_.get()) {
     NSView* view = [tab view];
     DCHECK([view isKindOfClass:[TabView class]]);
 
     // Recall that |-[NSView frame]| is in its superview's coordinates, so a
-    // |TabView|'s frame is in the coordinates of the |TabStripView|.
-    NSRect frame = [tabStripView_ convertRectToBase:[view frame]];
+    // |TabView|'s frame is in the coordinates of the |TabStripView| (which
+    // matches the coordinate system of |point|).
+    NSRect frame = [view frame];
 
     // Modify the frame to make it "unoverlapped".
     frame.origin.x += kTabOverlap / 2.0;
     frame.size.width -= kTabOverlap;
     if (frame.size.width < 1.0)
       frame.size.width = 1.0;  // try to avoid complete failure
 
     // Drop in a new tab to the left of tab |i|?
-    if (location.x < (frame.origin.x + kLRProportion * frame.size.width)) {
+    if (point.x < (frame.origin.x + kLRProportion * frame.size.width)) {
       *index = i;
       *disposition = NEW_FOREGROUND_TAB;
       return;
     }
 
     // Drop on tab |i|?
-    if (location.x <= (frame.origin.x +
+    if (point.x <= (frame.origin.x +
                        (1.0 - kLRProportion) * frame.size.width)) {
       *index = i;
       *disposition = CURRENT_TAB;
       return;
     }
 
     // (Dropping in a new tab to the right of tab |i| will be taken care of in
     // the next iteration.)
     i++;
   }
 
   // If we've made it here, we want to append a new tab to the end.
   *index = -1;
   *disposition = NEW_FOREGROUND_TAB;
 }
 
-// Drop URLs at the given location.
-- (void)dropURLs:(NSArray*)urls at:(NSPoint)location {
+// (URLDropTargetController protocol)
+- (void)dropURLs:(NSArray*)urls inView:(NSView*)view at:(NSPoint)point {
+  DCHECK_EQ(view, tabStripView_.get());
+
   if ([urls count] < 1) {
     NOTREACHED();
     return;
   }
 
   //TODO(viettrungluu): dropping multiple URLs.
   if ([urls count] > 1)
     NOTIMPLEMENTED();
 
   // Get the first URL and fix it up.
   GURL url(URLFixerUpper::FixupURL(
       base::SysNSStringToUTF8([urls objectAtIndex:0]), std::string()));
 
   // Get the index and disposition.
   NSInteger index;
   WindowOpenDisposition disposition;
-  [self droppingURLsAt:location
+  [self droppingURLsAt:point
             givesIndex:&index
            disposition:&disposition];
 
   // Either insert a new tab or open in a current tab.
   switch (disposition) {
     case NEW_FOREGROUND_TAB:
       UserMetrics::RecordAction("Tab_DropURLBetweenTabs", browser_->profile());
       browser_->AddTabWithURL(url, GURL(), PageTransition::TYPED, true, index,
                               true, NULL);
       break;
     case CURRENT_TAB:
       UserMetrics::RecordAction("Tab_DropURLOnTab", browser_->profile());
       tabStripModel_->GetTabContentsAt(index)->OpenURL(url, GURL(), CURRENT_TAB,
                                                        PageTransition::TYPED);
       tabStripModel_->SelectTabContentsAt(index, true);
       break;
     default:
       NOTIMPLEMENTED();
   }
 }
 
-// Update (possibly showing) the indicator which indicates where an URL drop
-// would happen.
-- (void)indicateDropURLsAt:(NSPoint)location {
+// (URLDropTargetController protocol)
+- (void)indicateDropURLsInView:(NSView*)view at:(NSPoint)point {
+  DCHECK_EQ(view, tabStripView_.get());
+
   // The minimum y-coordinate at which one should consider place the arrow.
   const CGFloat arrowBaseY = 25;
 
   NSInteger index;
   WindowOpenDisposition disposition;
-  [self droppingURLsAt:location
+  [self droppingURLsAt:point
             givesIndex:&index
            disposition:&disposition];
 
   NSPoint arrowPos = NSMakePoint(0, arrowBaseY);
   if (index == -1) {
     // Append a tab at the end.
     DCHECK(disposition == NEW_FOREGROUND_TAB);
     NSInteger lastIndex = [tabArray_ count] - 1;
     NSRect overRect = [[[tabArray_ objectAtIndex:lastIndex] view] frame];
     arrowPos.x = overRect.origin.x + overRect.size.width - kTabOverlap / 2.0;
@@ skipping 11 matching lines @@
       default:
         NOTREACHED();
     }
   }
 
   [tabStripView_ setDropArrowPosition:arrowPos];
   [tabStripView_ setDropArrowShown:YES];
   [tabStripView_ setNeedsDisplay:YES];
 }
 
-// Hide the indicator which indicates where an URL drop would happen.
-- (void)hideDropURLsIndicator {
+// (URLDropTargetController protocol)
+- (void)hideDropURLsIndicatorInView:(NSView*)view {
+  DCHECK_EQ(view, tabStripView_.get());
+
   if ([tabStripView_ dropArrowShown]) {
     [tabStripView_ setDropArrowShown:NO];
     [tabStripView_ setNeedsDisplay:YES];
   }
 }
 
 - (GTMWindowSheetController*)sheetController {
   if (!sheetController_.get())
     sheetController_.reset([[GTMWindowSheetController alloc]
         initWithWindow:[switchView_ window] delegate:self]);
@@ skipping 88 matching lines @@
       // Show next sheet
       NSWindowController* controller = [[tab window] windowController];
       DCHECK([controller isKindOfClass:[BrowserWindowController class]]);
       windows.front()->Realize(
           static_cast<BrowserWindowController*>(controller));
     }
   }
 }
 
 @end