Implement the Oilpan pushAllRegisters on MIPS64

Source/platform/heap/asm/SaveRegisters_mips64.S

Index: Source/platform/heap/asm/SaveRegisters_mips64.S
diff --git a/Source/platform/heap/asm/SaveRegisters_mips64.S b/Source/platform/heap/asm/SaveRegisters_mips64.S
new file mode 100644
index 0000000000000000000000000000000000000000..3c9b02ee4c0a7f47373130081e5774ef3cfa20c1
--- /dev/null
+++ b/Source/platform/heap/asm/SaveRegisters_mips64.S
@@ -0,0 +1,41 @@
+// Copyright 2014 The Chromium Authors. All rights reserved.
+// Use of this source code is governed by a BSD-style license that can be
+// found in the LICENSE file.
+
+/*
+ * typedef void (*PushAllRegistersCallback)(SafePointBarrier*, ThreadState*, intptr_t*);
+ * extern "C" void pushAllRegisters(SafePointBarrier*, ThreadState*, PushAllRegistersCallback)
+ */
+
+.type pushAllRegisters, %function
+.global pushAllRegisters
+.hidden pushAllRegisters
+pushAllRegisters:
+        // Push all callee-saves registers to get them
+        // on the stack for conservative stack scanning.
+        // Reserve space for callee-saved registers and return address.

[Mads Ager (chromium), 2014/08/18 06:54:16]

Don't you need to reserve space for saving arguments passed in registers? If the
called function assumes that it has four words on the stack that it can use for
saving argument registers it might end up overwriting one of the value which we
have saved there and the GC would miss a pointer. The mips32 documentation that
I could find says that you have to allocate room for saving the four argument
register values. Is that not the case for mips64?  

Do you have a good link for the mips64 calling convention? Is it the same as the
32-bit one but with 64-bit value instead of 32-bit?

[petarj, 2014/08/18 13:05:18]

No, it is not. No reserved space is needed or expected on n64 abi.
"See MIPS Run" should hold information to start with.
The book seems to be available for download on a few places.

+        daddiu $sp,$sp,-80
+        // Save the callee-saved registers and the return address.
+        sd $s0,0($sp)
+        sd $s1,8($sp)
+        sd $s2,16($sp)
+        sd $s3,24($sp)
+        sd $s4,32($sp)
+        sd $s5,40($sp)
+        sd $s6,48($sp)
+        sd $s7,56($sp)
+        sd $ra,64($sp)
+        // Note: the callee-saved floating point registers do not need to be
+        // copied to the stack, because fp registers never hold heap pointers
+        // and so do not need to be kept visible to the garbage collector.
+        // Pass the two first arguments untouched in a0 and a1 and the
+        // stack pointer to the callback.
+        move $t9,$a2
+        move $a2,$sp
+        jal $t9
+        // Restore return address, adjust stack and return.
+        // Note: the copied registers do not need to be reloaded here,
+        // because they were preserved by the called routine.
+        ld $ra,64($sp)
+        daddiu $sp,$sp,80
+        jr $ra