Fix some infobar problems.

chrome/browser/ui/cocoa/browser_window_controller_browsertest.mm

 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #import "chrome/browser/ui/cocoa/browser_window_controller.h"
 
 #import "base/mac/mac_util.h"
 #include "base/mac/sdk_forward_declarations.h"
 #include "base/run_loop.h"
 #include "base/strings/utf_string_conversions.h"
+#include "chrome/app/chrome_command_ids.h"
 #include "chrome/browser/browser_process.h"
 #include "chrome/browser/devtools/devtools_window_testing.h"
 #include "chrome/browser/infobars/infobar_service.h"
 #include "chrome/browser/infobars/simple_alert_infobar_delegate.h"
 #include "chrome/browser/profiles/profile.h"
 #include "chrome/browser/profiles/profile_manager.h"
 #include "chrome/browser/ui/bookmarks/bookmark_utils.h"
 #include "chrome/browser/ui/browser.h"
 #include "chrome/browser/ui/browser_commands.h"
 #include "chrome/browser/ui/browser_list.h"
 #include "chrome/browser/ui/browser_window.h"
 #include "chrome/browser/ui/cocoa/browser_window_cocoa.h"
 #import "chrome/browser/ui/cocoa/browser_window_controller_private.h"
 #import "chrome/browser/ui/cocoa/fast_resize_view.h"
 #import "chrome/browser/ui/cocoa/history_overlay_controller.h"
 #import "chrome/browser/ui/cocoa/infobars/infobar_cocoa.h"
 #import "chrome/browser/ui/cocoa/infobars/infobar_container_controller.h"
+#import "chrome/browser/ui/cocoa/infobars/infobar_controller.h"
+#import "chrome/browser/ui/cocoa/location_bar/location_bar_view_mac.h"
 #import "chrome/browser/ui/cocoa/nsview_additions.h"
 #import "chrome/browser/ui/cocoa/profiles/avatar_base_controller.h"
 #import "chrome/browser/ui/cocoa/tab_contents/overlayable_contents_controller.h"
 #include "chrome/browser/ui/extensions/application_launch.h"
 #include "chrome/browser/ui/find_bar/find_bar_controller.h"
 #include "chrome/browser/ui/find_bar/find_bar.h"
 #include "chrome/browser/ui/tabs/tab_strip_model.h"
 #include "chrome/test/base/in_process_browser_test.h"
 #include "chrome/test/base/testing_profile.h"
 #include "content/public/browser/web_contents.h"
+#include "content/public/test/test_utils.h"
 #import "testing/gtest_mac.h"
+#include "ui/gfx/animation/slide_animation.h"
 
 namespace {
 
 void CreateProfileCallback(const base::Closure& quit_closure,
                            Profile* profile,
                            Profile::CreateStatus status) {
   EXPECT_TRUE(profile);
   EXPECT_NE(Profile::CREATE_STATUS_LOCAL_FAIL, status);
   EXPECT_NE(Profile::CREATE_STATUS_REMOTE_FAIL, status);
   // This will be called multiple times. Wait until the profile is initialized
   // fully to quit the loop.
   if (status == Profile::CREATE_STATUS_INITIALIZED)
     quit_closure.Run();
 }
 
 enum ViewID {
   VIEW_ID_TOOLBAR,
   VIEW_ID_BOOKMARK_BAR,
   VIEW_ID_INFO_BAR,
   VIEW_ID_FIND_BAR,
   VIEW_ID_DOWNLOAD_SHELF,
   VIEW_ID_TAB_CONTENT_AREA,
   VIEW_ID_FULLSCREEN_FLOATING_BAR,
   VIEW_ID_COUNT,
 };
 
 }  // namespace
 
+@interface InfoBarContainerController(TestingAPI)
+- (BOOL)isTopInfoBarAnimationRunning;
+@end
+
+@implementation InfoBarContainerController(TestingAPI)
+- (BOOL)isTopInfoBarAnimationRunning {
+  InfoBarController* infoBarController = [infobarControllers_ objectAtIndex:0];
+  if (infoBarController) {
+    const gfx::SlideAnimation& infobarAnimation =
+        const_cast<const InfoBarCocoa*>(infoBarController.infobar)->animation();

[Robert Sesek, 2014/08/26 16:26:18]

Why do you need this const cast?

[Malcolm, 2014/08/27 06:29:21]

Class InfoBar has two methods named "animation()", one is public, the other is
protected. Here, const cast it in order to call the public&const "animation()".

[Peter Kasting, 2014/08/27 06:59:51]

If you're adding const, use static_cast rather than const_cast.  Just use
const_cast for removing const; static_cast is safer in general.

[Malcolm, 2014/08/27 09:06:36]

Oh, should be static_cast here, very careful, thanks!

+    return infobarAnimation.is_animating();
+  }
+  return NO;
+}
+@end
+
 class BrowserWindowControllerTest : public InProcessBrowserTest {
  public:
   BrowserWindowControllerTest() : InProcessBrowserTest() {
   }
 
   virtual void SetUpOnMainThread() OVERRIDE {
     [[controller() bookmarkBarController] setStateAnimationsEnabled:NO];
     [[controller() bookmarkBarController] setInnerContentAnimationsEnabled:NO];
   }
 
@@ skipping 50 matching lines @@
 
   CGFloat GetViewHeight(ViewID viewID) const {
     CGFloat height = NSHeight([GetViewWithID(viewID) frame]);
     if (viewID == VIEW_ID_INFO_BAR) {
       height -= [[controller() infoBarContainerController]
           overlappingTipHeight];
     }
     return height;
   }
 
+  static void CheckTopInfoBarAnimation(
+      InfoBarContainerController* infoBarContainerController,
+      const base::Closure& quit_task) {
+    if (![infoBarContainerController isTopInfoBarAnimationRunning])
+      quit_task.Run();
+  }
+
+  static void CheckBookmarkBarAnimation(
+      BookmarkBarController* bookmarkBarController,
+      const base::Closure& quit_task) {
+    if (![bookmarkBarController isAnimationRunning])
+      quit_task.Run();
+  }
+
+  void WaitForTopInfoBarAnimationToFinish() {
+    scoped_refptr<content::MessageLoopRunner> runner =
+        new content::MessageLoopRunner;
+
+    base::Timer timer(false, true);
+    timer.Start(
+        FROM_HERE,
+        base::TimeDelta::FromMilliseconds(15),
+        base::Bind(&CheckTopInfoBarAnimation,
+                   [controller() infoBarContainerController],
+                   runner->QuitClosure()));
+    runner->Run();
+  }
+
+  void WaitForBookmarkBarAnimationToFinish() {
+    scoped_refptr<content::MessageLoopRunner> runner =
+        new content::MessageLoopRunner;
+
+    base::Timer timer(false, true);
+    timer.Start(
+        FROM_HERE,
+        base::TimeDelta::FromMilliseconds(15),
+        base::Bind(&CheckBookmarkBarAnimation,
+                   [controller() bookmarkBarController],
+                   runner->QuitClosure()));
+    runner->Run();
+  }
+
+  NSInteger GetExpectedTopInfoBarTipHeight() {
+    InfoBarContainerController* infoBarContainerController =
+        [controller() infoBarContainerController];
+    CGFloat overlappingTipHeight =

[Robert Sesek, 2014/08/26 16:26:18]

naming: overlapping_tip_height

+        [infoBarContainerController overlappingTipHeight];
+    LocationBarViewMac* locationBarView = [controller() locationBarBridge];

[Robert Sesek, 2014/08/26 16:26:18]

naming: location_bar_view

+    NSPoint iconBottom = locationBarView->GetPageInfoBubblePoint();

[Robert Sesek, 2014/08/26 16:26:18]

naming: icon_bottom

+
+    NSPoint infoBarTop = NSMakePoint(0,

[Robert Sesek, 2014/08/26 16:26:18]

naming: info_bar_top

+        NSHeight([infoBarContainerController view].frame) -
+        overlappingTipHeight);
+    infoBarTop = [[infoBarContainerController view] convertPoint:infoBarTop
+                                                          toView:nil];
+    return iconBottom.y - infoBarTop.y;
+  }
+
  private:
   DISALLOW_COPY_AND_ASSIGN(BrowserWindowControllerTest);
 };
 
 // Tests that adding the first profile moves the Lion fullscreen button over
 // correctly.
 // DISABLED_ because it regularly times out: http://crbug.com/159002.
 IN_PROC_BROWSER_TEST_F(BrowserWindowControllerTest,
                        DISABLED_ProfileAvatarFullscreenButton) {
   if (base::mac::IsOSSnowLeopard())
@@ skipping 200 matching lines @@
   DevToolsWindow* devtools_window =
       DevToolsWindowTesting::OpenDevToolsWindowSync(browser(), true);
   DevToolsWindowTesting::Get(devtools_window)->SetInspectedPageBounds(
       gfx::Rect(10, 10, 100, 100));
 
   NSPoint originWithDevTools = [controller() statusBubbleBaseFrame].origin;
   EXPECT_FALSE(NSEqualPoints(origin, originWithDevTools));
 
   DevToolsWindowTesting::CloseDevToolsWindowSync(devtools_window);
 }
+
+// Tests that top infobar tip is streched when bookmark bar becomes SHOWN/HIDDEN
+IN_PROC_BROWSER_TEST_F(BrowserWindowControllerTest,
+                       InfoBarTipStrechedWhenBookmarkBarStatusChanged) {
+  EXPECT_FALSE([controller() isBookmarkBarVisible]);
+  ShowInfoBar(browser());
+  // The infobar tip is animated during the infobar is being added, wait until
+  // it completes.
+  WaitForTopInfoBarAnimationToFinish();
+
+  EXPECT_FALSE([[controller() infoBarContainerController]
+      shouldSuppressTopInfoBarTip]);
+
+  NSInteger maxTipHeight = infobars::InfoBar::kMaximumArrowTargetHeight +

[Robert Sesek, 2014/08/26 16:26:18]

naming: In C++ functions (which tests are), use under_score naming, e.g.
max_tip_height.

+      infobars::InfoBar::kSeparatorLineHeight;
+
+  chrome::ExecuteCommand(browser(), IDC_SHOW_BOOKMARK_BAR);
+  WaitForBookmarkBarAnimationToFinish();
+  EXPECT_TRUE([controller() isBookmarkBarVisible]);
+  EXPECT_EQ(std::min(GetExpectedTopInfoBarTipHeight(), maxTipHeight),
+            [[controller() infoBarContainerController] overlappingTipHeight]);
+
+  chrome::ExecuteCommand(browser(), IDC_SHOW_BOOKMARK_BAR);
+  WaitForBookmarkBarAnimationToFinish();
+  EXPECT_FALSE([controller() isBookmarkBarVisible]);
+  EXPECT_EQ(std::min(GetExpectedTopInfoBarTipHeight(), maxTipHeight),
+            [[controller() infoBarContainerController] overlappingTipHeight]);
+}