Fix BookmarkNode MetaInfoMap copypasting for Mac

components/bookmarks/browser/bookmark_pasteboard_helper_mac.mm

 // Copyright 2014 The Chromium Authors. All rights reserved.
 // Use of this source code is governed by a BSD-style license that can be
 // found in the LICENSE file.
 
 #include "components/bookmarks/browser/bookmark_pasteboard_helper_mac.h"
 
 #import <Cocoa/Cocoa.h>
 
 #include "base/files/file_path.h"
 #include "base/strings/sys_string_conversions.h"
@@ skipping 13 matching lines @@
 
 // Pasteboard type used to store profile path to determine which profile
 // a set of bookmarks came from.
 NSString* const kChromiumProfilePathPboardType =
     @"ChromiumProfilePathPboardType";
 
 // Internal bookmark ID for a bookmark node.  Used only when moving inside
 // of one profile.
 NSString* const kChromiumBookmarkId = @"ChromiumBookmarkId";
 
+// Internal bookmark meta info dictionary for a bookmark node.
+NSString* const kChromiumBookmarkMetaInfo = @"ChromiumBookmarkMetaInfo";
+
 // Mac WebKit uses this type, declared in
 // WebKit/mac/History/WebURLsWithTitles.h.
 NSString* const kCrWebURLsWithTitlesPboardType = @"WebURLsWithTitlesPboardType";
 
 // Keys for the type of node in BookmarkDictionaryListPboardType.
 NSString* const kWebBookmarkType = @"WebBookmarkType";
 
 NSString* const kWebBookmarkTypeList = @"WebBookmarkTypeList";
 
 NSString* const kWebBookmarkTypeLeaf = @"WebBookmarkTypeLeaf";
 
+BookmarkNode::MetaInfoMap MetaInfoMapFromDictionary(NSDictionary* dictionary) {
+  BookmarkNode::MetaInfoMap meta_info_map;
+
+  for (NSString* key in dictionary) {
+    NSString* value = dictionary[key];
+    meta_info_map[base::SysNSStringToUTF8(key)] =
+        base::SysNSStringToUTF8(value);
+  }
+
+  return meta_info_map;
+}
+
 void ConvertPlistToElements(NSArray* input,
                             std::vector<BookmarkNodeData::Element>& elements) {
   NSUInteger len = [input count];
   for (NSUInteger i = 0; i < len; ++i) {
     NSDictionary* pboardBookmark = [input objectAtIndex:i];
     scoped_ptr<BookmarkNode> new_node(new BookmarkNode(GURL()));
     int64 node_id =
         [[pboardBookmark objectForKey:kChromiumBookmarkId] longLongValue];
     new_node->set_id(node_id);
+
+    NSDictionary* metaInfoDictionary =
+        [pboardBookmark objectForKey:kChromiumBookmarkMetaInfo];
+    if (metaInfoDictionary)
+      new_node->SetMetaInfoMap(MetaInfoMapFromDictionary(metaInfoDictionary));
+
     BOOL is_folder = [[pboardBookmark objectForKey:kWebBookmarkType]
         isEqualToString:kWebBookmarkTypeList];
     if (is_folder) {
       new_node->set_type(BookmarkNode::FOLDER);
       NSString* title = [pboardBookmark objectForKey:@"Title"];
       new_node->SetTitle(base::SysNSStringToUTF16(title));
     } else {
       new_node->set_type(BookmarkNode::URL);
       NSDictionary* uriDictionary =
           [pboardBookmark objectForKey:@"URIDictionary"];
       NSString* title = [uriDictionary objectForKey:@"title"];
       NSString* urlString = [pboardBookmark objectForKey:@"URLString"];
       new_node->SetTitle(base::SysNSStringToUTF16(title));
       new_node->set_url(GURL(base::SysNSStringToUTF8(urlString)));
     }
     BookmarkNodeData::Element e = BookmarkNodeData::Element(new_node.get());
-    if(is_folder)
+    if (is_folder) {
       ConvertPlistToElements([pboardBookmark objectForKey:@"Children"],
                              e.children);
+    }
     elements.push_back(e);
   }
 }
 
 bool ReadBookmarkDictionaryListPboardType(
     NSPasteboard* pb,
     std::vector<BookmarkNodeData::Element>& elements) {
   NSArray* bookmarks =
       [pb propertyListForType:kBookmarkDictionaryListPboardType];
   if (!bookmarks)
@@ skipping 45 matching lines @@
     title = [pb stringForType:NSStringPboardType];
 
   BookmarkNodeData::Element element;
   element.is_url = true;
   element.url = GURL(urlString);
   element.title = base::SysNSStringToUTF16(title);
   elements.push_back(element);
   return true;
 }
 
+NSDictionary* DictionaryFromBookmarkMetaInfo(

[sky, 2014/07/30 17:17:48]

I'm surprised we don't have some general function that takes a
std::map<string,string> and does this for you already. Similarly for
MetaInfoMapFromDictionary.

[Jiang Jiang, 2014/07/31 10:05:56]

Can't find anything in base at least.

+    const BookmarkNode::MetaInfoMap& meta_info_map) {
+  NSMutableDictionary* dictionary =
+      [[NSMutableDictionary alloc] initWithCapacity:meta_info_map.size()];

[Avi (use Gerrit), 2014/07/30 17:45:10]

You can do

NSMutableDictionary* dictionary = [NSMutableDictionary dictionary];

(like line 176 below) and avoid autoreleasing manually on line 171. A bit
cleaner.

[Jiang Jiang, 2014/07/31 10:05:56]

Done.

+
+  for (BookmarkNode::MetaInfoMap::const_iterator it = meta_info_map.begin();
+      it != meta_info_map.end(); ++it) {
+    dictionary[base::SysUTF8ToNSString(it->first)] =
+        base::SysUTF8ToNSString(it->second);
+  }
+
+  return [dictionary autorelease];
+}
+
 NSArray* GetPlistForBookmarkList(
     const std::vector<BookmarkNodeData::Element>& elements) {
   NSMutableArray* plist = [NSMutableArray array];
   for (size_t i = 0; i < elements.size(); ++i) {
     BookmarkNodeData::Element element = elements[i];
+    NSDictionary* metaInfoDictionary =
+        DictionaryFromBookmarkMetaInfo(element.meta_info_map);
     if (element.is_url) {
       NSString* title = base::SysUTF16ToNSString(element.title);
       NSString* url = base::SysUTF8ToNSString(element.url.spec());
       int64 elementId = element.id();
       NSNumber* idNum = [NSNumber numberWithLongLong:elementId];
       NSDictionary* uriDictionary = [NSDictionary dictionaryWithObjectsAndKeys:
               title, @"title", nil];
       NSDictionary* object = [NSDictionary dictionaryWithObjectsAndKeys:
           uriDictionary, @"URIDictionary",
           url, @"URLString",
           kWebBookmarkTypeLeaf, kWebBookmarkType,
           idNum, kChromiumBookmarkId,
+          metaInfoDictionary, kChromiumBookmarkMetaInfo,
           nil];
       [plist addObject:object];
     } else {
       NSString* title = base::SysUTF16ToNSString(element.title);
       NSArray* children = GetPlistForBookmarkList(element.children);
       int64 elementId = element.id();
       NSNumber* idNum = [NSNumber numberWithLongLong:elementId];
       NSDictionary* object = [NSDictionary dictionaryWithObjectsAndKeys:
           title, @"Title",
           children, @"Children",
           kWebBookmarkTypeList, kWebBookmarkType,
           idNum, kChromiumBookmarkId,
+          metaInfoDictionary, kChromiumBookmarkMetaInfo,
           nil];
       [plist addObject:object];
     }
   }
   return plist;
 }
 
 void WriteBookmarkDictionaryListPboardType(
     NSPasteboard* pb,
     const std::vector<BookmarkNodeData::Element>& elements) {
@@ skipping 103 matching lines @@
 bool PasteboardContainsBookmarks(ui::ClipboardType type) {
   NSPasteboard* pb = PasteboardFromType(type);
 
   NSArray* availableTypes =
       [NSArray arrayWithObjects:kBookmarkDictionaryListPboardType,
                                 kCrWebURLsWithTitlesPboardType,
                                 NSURLPboardType,
                                 nil];
   return [pb availableTypeFromArray:availableTypes] != nil;
 }